Discussion :

[ThSPB]

Bonjour,

J'ai une feuille "Wsite". Dans la colonne D on doit trouver de la ligne 11 à 90 les valeurs 0, 1, X ou ?.
Normalement lors de la saisie pour les cellules ayant la valeur 0 ou ?, il doit être ajouté un commentaire de cellule.
Ce que je veux ;
Faire un balayage de chaque cellule l'une après l'autre
si la valeur contenue dans la cellule est 0 ou ? et qu'il n'y a pas de commentaire, la colorer en orange (Pour la recherche visuelle).
A la fin du balayage, en cas d'anomalie faire apparaître une MsgBox " Absence de commentaire dans la/ les cellules oranges"
Sinon terminer la macro.
J'espére que j'ai été assez clair, je suis entrain d'essayer d'adapter une macro déjà existante mais je patine sérieusement.
Merci de votre aide

[Theze]

Bonjour,

Teste ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Sub Commentaire()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Liste As String
 
    Set Plage = ActiveSheet.[D11:D90]
 
    For Each Cel In Plage
 
        'pour les cellules contenant des 0 et des ?
        If Cel = 0 Or Cel = "?" Then
 
            'si ces cellules non pas de commentaire
            If Cel.Comment Is Nothing Then
 
                'les colore en orange et mémorise leurs adresses
                Cel.Interior.ColorIndex = 46
                Liste = Liste & vbCrLf & Cel.Address(0, 0)
 
            End If
 
        End If
 
    Next Cel
 
    'affiche les adresses
    MsgBox "Absence de commentaire dans la/les cellule(s) : " & vbCrLf & Liste
 
End Sub

Hervé.

[ThSPB]

Merci beaucoup

Sitôt lu, sitôt copier/ coller
Résultat = bon du premier coup avec option en plus

Merci beaucoup