Discussion :

[tchoutchou69]

Bonjour à tous,

J'aimerai griser certaines cellules suivant certains criteres.
Par exemple, si sur la feuille "IndAn", j'ai le mot Trimestriel dans la colonne F et la ligne 9, je grise les cellules M9,N9,P9,Q9,S9,T9,V9 et W9.
Et ainsi de suite pour le mot annuelle, semetrielle.....et pour toute les lignes.

Je vous joins mon debut de code faux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Worksheet_SelectionChange
For I = 180 To 8 Step -1
If .Cells(I, 7) = "Trim*" Then
For J = 20 To 8 Step -3 then .Cells(i,j).ColorIndex=16
 
End Sub

Merci d'avance.

[Theze]

Bonjour,

Teste ce qui suit mais attention à l'évennement "Selection_Change" de vérifier si la proc doit se produire tout le temps (à chaque changement de sélection) ou seulement sur une plage donnée !
Ici la proc sera exécutée à chaque changement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
Private Sub Worksheet_SelectionChange()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Tbl
    Dim Adr As String
    Dim I As Integer
    Dim J As Integer
    Dim Adresse As String
 
    Tbl = Array("Trim", "Annu", "Seme")
 
    With Worksheets("IndAn")
        Set Plage = .Range(.[A1], [A65536].End(xlUp))
    End With
 
    For J = 0 To UBound(Tbl)
 
        Set Cel = Plage.Find(Tbl(J) & "*", , xlValues)
 
        If Not Cel Is Nothing Then
 
            Adr = Cel.Address
 
            Do
 
                I = Cel.Row
                Adresse = "M" & I & ":N" & I & _
                          ",P" & I & ":Q" & I & _
                          ",S" & I & ":T" & I & _
                          ",V" & I & ":W" & I
 
                Range(Adresse).Interior.ColorIndex = 15
 
                Set Cel = Plage.FindNext(Cel)
 
            Loop While Adr <> Cel.Address
 
        End If
 
    Next J
 
End Sub

Hervé.

[tchoutchou69]

J'ai modifier l'évennement "Selection_Change" en "CommandButton5_Click()" et j ai créé un bouton mais cela ne marche pas (rien ne se passe)....Je précise que je debute en VBA.
J'ai mis en page ce que j'aimerai obtenir sur le fichier excel que j'ai joins.
La selection se fait sur la colonne G et l'application sur la selection de M9 à X171

[Theze]

Bonsoir,

Désolé, je n'ai pas indiqué la bonne plage (colonne A pour mon test au lieu de colonne G :0(( ) donc, je reposte le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
Private Sub Coloriser()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Tbl
    Dim Adr As String
    Dim I As Integer
    Dim J As Integer
    Dim Adresse As String
 
    Tbl = Array("Trim", "Annu", "Seme")
 
    With Worksheets("IndAn")
        Set Plage = .Range(.[G1], .[G65536].End(xlUp))
    End With
 
    For J = 0 To UBound(Tbl)
 
        Set Cel = Plage.Find(Tbl(J) & "*", , xlValues)
 
        If Not Cel Is Nothing Then
 
            Adr = Cel.Address
 
            Do
 
                I = Cel.Row
                Adresse = "M" & I & ":N" & I & _
                          ",P" & I & ":Q" & I & _
                          ",S" & I & ":T" & I & _
                          ",V" & I & ":W" & I
 
                Range(Adresse).Interior.ColorIndex = 15
 
                Set Cel = Plage.FindNext(Cel)
 
            Loop While Adr <> Cel.Address
 
        End If
 
    Next J
 
End Sub
 
 
Private Sub CommandButton5_Click()
 
    Coloriser
 
End Sub

Hervé.

[tchoutchou69]

Merci Hervé pour ton aide précieuse. J ai adapté ton code et tout fonctionne à merveille. J'aurais pu voir le probleme de plage............

Encore Merci