Discussion :

[mickisa]

bonjour voila j'aimerais comparez des données entre 2 feuilles ,si deux cellule sont identiques je dois mettre la ligne en couleur.

voici mon code.....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sheets("mag").Select
    Cells.Select
    Selection.Interior.ColorIndex = xlNone
    Sheets("bdt").Select
    Cells.Select
    Selection.Interior.ColorIndex = xlNone
Dim derlign As Long
Sheets("données").Select
derlign = [A65000].End(xlUp).Row
 
Sheets("mag").Select
Dim i As Integer
Dim d As Integer
Dim derlig As Long
d = 1
derlig = [A65000].End(xlUp).Row
For i = 1 To derlig
 For d = 1 To derlign
    If Sheets("données").Range("C" & d) = Sheets("Mag").Range("c" & i) Then
        If Sheets("données").Range("E" & d) = Sheets("Mag").Range("I" & i) Then
            Rows(i).Select
            Selection.Interior.ColorIndex = 3
        End If
    End If
 Next d
Next i

[casefayere]

bonjour,

n peu de soulagement de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub essai()
Dim i As Integer
Dim d As Integer
Dim derlig As Long
 
Sheets("mag").Cells.Interior.ColorIndex = xlNone
Sheets("bdt").Cells.Interior.ColorIndex = xlNone
Dim derlign As Long
With Sheets("données")
    derlign = .Range("A" & .Rows.Count).End(xlUp).Row
End With
With Sheets("mag")
    d = 1
    derlig = .Range("A" & .Rows.Count).End(xlUp).Row
    For i = 2 To derlig
        For d = 2 To derlign
            If Sheets("données").Range("C" & d) = .Range("c" & i) Then
                If Sheets("données").Range("E" & d) = .Range("I" & i) Then
                    .Rows(i).Interior.ColorIndex = 3
                End If
            End If
        Next d
    Next i
End With
End Sub

bonne journée

[OrDonc]

Salut

avec des listes importantes, il vaut mieux passer par des tableaux.
A essayer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Communes()
  Sheets("mag").Cells.Interior.ColorIndex = xlNone
  Dim D1 As Long, D2 As Long, I1 As Long, I2 As Long
  Dim T1, T2 'tableaux des colonnes C&E et C&I
  D1 = Sheets("données").Cells(Rows.Count, 1).End(xlUp).Row
  T1 = Sheets("données").Range("C1:E" & D1)
  With Sheets("mag")
    D2 = .Cells(Rows.Count, 1).End(xlUp).Row
    T2 = .Range("C1:I" & D2)
    For I1 = 1 To D1
      For I2 = 1 To D2
        '1 pour C, 3 por E et 7 pour I
        If T1(I1, 1) & T1(I1, 3) = T2(I2, 1) & T2(I2, 7) Then
          .Rows(I2).Interior.ColorIndex = 3
        End If
      Next
    Next
  End With
End Sub

[Qwazerty]

Salut
Je suis du même avis que OrDonc en ce qui concerne l'utilisation des tableaux.
Par contre attention avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If T1(I1, 1) & T1(I1, 3) = T2(I2, 1) & T2(I2, 7) Then

26&4 = 2&64 et pourtant 26<>2 et 4<>64

De plus si des doublon sont présent dans T1 on peut aussi rajouter un petit quelque chose pour éviter de re-parcourir le T2 pour rien, puisque les lignes qui le doivent sont déjà colorées.
En reprenant le code de OrDonc ça donne un truc comme ça (pas testé)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Communes()
  Sheets("mag").Cells.Interior.ColorIndex = xlNone
  Dim D1 As Long, D2 As Long, I1 As Long, I2 As Long
  Dim T1, T2 'tableaux des colonnes C&E et C&I
  D1 = Sheets("données").Cells(Rows.Count, 1).End(xlUp).Row
  T1 = Sheets("données").Range("C1:E" & D1)
  With Sheets("mag")
    D2 = .Cells(Rows.Count, 1).End(xlUp).Row
    T2 = .Range("C1:I" & D2)
    For I1 = 1 To D1
      For I2 = 1 To D2
 
        '1 pour C, 3 por E et 7 pour I
        If T1(I1, 1) = T2(I2, 1) Then
            If T1(I1, 3) = T2(I2, 7) Then
                If .Rows(I2).Interior.ColorIndex = 3 Then
                    Exit For 'Inutile de continuer, la valeur de T1 a déjà ete traitée (cas de doublon dans T1)
                Else
                    .Rows(I2).Interior.ColorIndex = 3
                End If
            End If
        End If
      Next
    Next
  End With
End Sub

++
Qwaz