Discussion :

[guigui71]

Bonjour à tous :

j'ai un problème :

je dispose de 2 feuilles :

1 : données dédoublonnées
2 : toutes les données ( donc avec doublons)

lien entre les 2 feuilles : une référence

j'aimerai que lorsque je clique sur une référence de ma feuile 1, afficher dans une nouvelle feuille toutes les données de la feuille 2 qui correspondent.

soit en gros un tableaux dynamic liant les 2 feuilles.

Avez vous une idée ?

[wilfried_42]

Bonjour

Avec des formules matricielles ou par macro au choix, seulement un exemple de ton classeur est necessaire

@ te lire

[guigui71]

voilà

J'ai simplifié mon fichier mais je pense qu'avec ceci vous comprendrez mieux mon problème

[mercatog]

dans l'évènement Change de ta feuille sans doublons

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim LastLigSD As Long, LastLigAD
 
Application.ScreenUpdating = False
LastLigSD = Cells(Rows.Count, "D").End(xlUp).Row
If Not Intersect(Target, Range("D2:D" & LastLigSD)) Is Nothing Then
    With Sheets("BDD avec doublon")
        Sheets("Feuil3").UsedRange.Clear
        .AutoFilterMode = False
        LastLigAD = .Cells(Rows.Count, "D").End(xlUp).Row
        .Range("A1:G" & LastLigAD).AutoFilter field:=4, Criteria1:=Target.Cells(1, 1).Value
        .Range("A1:G" & LastLigAD).SpecialCells(xlCellTypeVisible).Copy Sheets("Feuil3").Range("A1")
        .AutoFilterMode = False
    End With
End If
End Sub

[wilfried_42]

Re:

J'ai bossé je poste lol, à placer dans le code VBA de la Feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Intersect(Target, Range("D2:D1000")) Is Nothing Then Exit Sub
    If Target = "" Then Exit Sub
    Sheets("Feuil3").Cells.Clear
    With Sheets("BDD avec doublon").Range("A:G")
        .AutoFilter field:=4, Criteria1:=Target.Value
        .SpecialCells(xlCellTypeVisible).Copy Destination:=Sheets("Feuil3").Range("A1")
        .AutoFilter
    End With
    Sheets("Feuil3").Select
End Sub

[guigui71]

bonjour mercatog,

J'ai testé votre code, il m'affiche uniquement l'entête des colonnes dans la feuil3

Je précise :

feuil 1 sans doublon : le critère ( référence) est à la colonne C
feuil 2 avec doublon : le critère (référence) est à la colonne M

peut être est-ce celà qui plante ?

[guigui71]

Merci à vous !

votre programme marche, j'ai juste ajusté en fonction de mes colonnes !

Je vous remercie