Discussion :

[cyberloux]

Bonjours,
J'aimerais ouvrir un pdf a un page précise, j'ai déja un bout de code mais celui ne fonction pas et je ne vois pas l'erreur!

voila celui-ci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub CommandButton1_Click()
Dim i As String
 
 i = "C:\Program Files\Adobe\Reader 9.0\Reader\Acrobat.exe" /A page=10=OpenActions "C:\doc.pdf"
 
 Call Shell(i, 1)
End Sub

merci et bonne soirée

[kiki29]

Salut, 2 exemples
le 1er en cochant sous VBE Outils/References Microsoft Internet Control

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Option Explicit
 
Sub Tst()
Dim Fichier As Variant
 
    ChDir ThisWorkbook.Path
 
    Fichier = Application.GetOpenFilename("Fichier PDF (*.pdf), *.pdf")
    If Fichier <> False Then
        OuvrirPDF Fichier, 4
    End If
End Sub
 
Private Sub OuvrirPDF(ByVal sFichier As String, NumPage As Long)
Dim oIE As InternetExplorer
 
    Set oIE = New InternetExplorer
    With oIE
        .Navigate sFichier & "#page=" & NumPage
        .Visible = True
    End With
 
    Set oIE = Nothing
End Sub

une autre possibilté sans cochage de références et qui correspond à ta demande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Option Explicit
 
Sub Tst3()
Dim Fichier As Variant
 
    ChDir ThisWorkbook.Path
 
    Fichier = Application.GetOpenFilename("Fichier PDF (*.pdf), *.pdf")
    If Fichier <> False Then
        OuvrirPDF2 Fichier, 7
    End If
End Sub
 
Private Sub OuvrirPDF2(ByVal sFichier As String, numPage As Long)
Dim WshShell As Object, PDFExec As Object
Dim CheminReader As String, CheminPDF As String
 
    CheminReader = "C:\Program Files\Adobe\Reader 9.0\Reader\acrord32.exe"
    CheminPDF = sFichier
 
    Set WshShell = CreateObject("WScript.Shell")
    Set PDFExec = WshShell.Exec(CheminReader & " /a page=" & numPage & "=OpenActions " & CheminPDF)
 
    Set PDFExec = Nothing
    Set WshShell = Nothing
 
End Sub

[cyberloux]

Merci pour cette réponse rapide, cependant, lorsque j'insère ce code dans un click button par exemple, j'obtient un message d'erreur de type: "erreur de compilation, la déclration de la ^procédure ne correspond pas à la description....)!

J'aurais aussi aimer savoir ce qui n'allait pas dans le code de mon premier message afin que je puisse corriger le tire les prochaines fois.

merci et bon dimanche

[kiki29]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub CommandButton1_Click()
Dim Fichier As Variant
 
    ChDir ThisWorkbook.Path
 
    Fichier = Application.GetOpenFilename("Fichier PDF (*.pdf), *.pdf")
    If Fichier <> False Then
        OuvrirPDF2 Fichier,7
    End If
End Sub

[cyberloux]

Il y a de l'amélioration car il n'y a plus de message d'erreur, cependant en clickant sur le bouton, une page s'affichant me demandant de selectionner un fichier alors que ce que j'aimerais, c'est qu'il m'ouvre un fichier pdf qui se situe "derriere" ce bouton.

J'ai fais un bout de code qui me permet d'ouvrir un PDF mais je ne vois pas où le modifié pour arrivé a une page voulue

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Aide_Click()
Dim Link As String
Link = "C:\DOC A OUVRIR.pdf"
On Error GoTo NePeutPas
ActiveWorkbook.FollowHyperlink Address:=Link, NewWindow:=True
Exit Sub
NePeutPas:
MsgBox "Impossible d'ouvrir " & Link
End Sub

merci

[cyberloux]

Finalement j'ai bien relu le bout de code que tu m'as donné et tout fonctionne à merveilles^^

Merci beaucou, bonne fin de week-end.