Discussion :

[setepenre]

Bonjour,

Je constitue un tableau récapitulatif, style tableau croisé, avec regroupement de lignes répondant à un même critère et création d'une ligne de sous-total.
Je souhaite que, lorsque le tableau s'affiche après avoir été rempli par toutes les données, les lignes "détail" soient masquées.
Ci-après les lignes de code qui réalisent cette merveille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
    'Groupement lignes par UI
    Range("B3").Select
    N_LigD = 3 'mémorise la première ligne du groupement
    Do Until IsEmpty(ActiveCell)
        If ActiveCell.Value = "Total" Then 'détecte la ligne du sous-total
            N_Lig = ActiveCell.Row + 1 'mémorise la première ligne du groupement suivant
            Range(Cells(N_LigD, 1), Cells(N_Lig - 2, 52)).Rows.Group ' crée le groupement
            ActiveCell.Rows.ShowDetail = False 'enroule les lignes détail
            N_LigD = N_Lig
        End If
        ActiveCell.Offset(1, 0).Select
    Loop

Tout se passe bien sauf pour le dernier groupement qui refuse obstinément de s'enrouler, comme si le processus n'avait pas le temps d'exécuter cette tâche avant de passer à la commande suivante.

Quelqu'un a-t-il une idée du pourquoi du comment ?

En pièce jointe le résultat des courses.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim Lastlig As Long, LigDeb As Long, i As Long
 
Application.ScreenUpdating = False
With Sheets("Récap")
    Lastlig = .Cells(.Rows.Count, "A").End(xlUp).Row
    .Rows(3 & ":" & Lastlig).ClearOutline
    LigDeb = 3
    For i = 3 To Lastlig
        If .Range("B" & i).Value = "Total" Then
            .Rows(LigDeb & ":" & i - 1).Group
            .Rows(i).ShowDetail = False
            LigDeb = i + 1
        End If
    Next i
End With

[setepenre]

OK, ça marche.

Merci beaucoup pour ton aide.


Setepenre