Discussion :

[Graineur]

Bonjour à tous,

Aujourd'hui j'ai un petit problème qui possède une difficulté que je n'arrive pas à surmonter.

Le sujet est très simple, je voudrais lancer une macro de transformation de texte court comme suit :

MonTexteATransformer ======> MON_TEXTE_A_TRANSFORMER
Montexte ======> MONTEXTE

1/ Que la globalité du texte s'affiche en majuscule
2/ Que des underscores séparent le texte d'origine lorsqu'une majuscule est repéré.

C'est là la difficulté pour moi, dois je utiliser une macro qui compte le nombre de caractères ?
Comment faire pour qu'elle repère la majuscule dans le texte initial pour ajouter un "_" avant celle-ci dans le texte final ?

Merci à tous !

[Jean-Philippe André]

Salut,

pour parcourir les lettres une a une dans une chaine de caracteres, tu auras un code comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
dim strinput as string
dim i as integer
'exemple
strinput = "PiouPiou"
for i = 1 to Len(strinput)
MsgBox mid(strinput,i,1)
Next i

Pour tester si la lettre est en majuscule, tu auras le test suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If Mid(strinput,i,1) = UCase(Mid(strinput,i,1)) Then
Msgbox "Lettre en majuscule"
End if

Enfin, pour passer une lettre minuscule en majuscule tu utiliseras la fonction UCase()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
strinput = "pioupiou"
Msgbox UCase(strinput)

Je te laisse faire les joints entre les differents bouts de code, c'est la partie la plus simple

[Graineur]

Je comprends le principe, cependant je suis plus versé dans la macro word.

Le problème étant que je voudrais automatiser ce process dans une feuille Excel.

J'aurais une colonne A avec tout un tas de texte du type : MonTexteATransformer etc ...

Et une colonne B ou la transformé donnera MON_TEXTE_A_TRANSFORMER etc ...

Je dois sélectionner ma feuille, et faire partir la macro sur une certaine cellule, et donner le résultat dans la cellule adjacente (strinput = Cellule.B2)

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Macro1()
Dim LastLig As Long, i As Long
Dim j As Integer
Dim LeMot As String
 
With Sheets("Feuil1")
    LastLig = .Cells(Rows.Count, 1).End(xlUp).Row
    For i = 2 To LastLig
        LeMot = .Range("A" & i).Value
        If Len(LeMot) > 1 Then
            For j = Len(LeMot) To 2 Step -1
                If UCase(Mid(LeMot, j, 1)) = Mid(LeMot, j, 1) Then LeMot = Left(LeMot, j - 1) & "_" & Mid(LeMot, j)
            Next j
        End If
        .Range("B" & i).Value = UCase(LeMot)
    Next i
End With
End Sub

[Graineur]

Superbe,

Merci beaucoup

[babaothe]

salut mercatog

Personnellement, dans un tel cas, j'utiliserais toute la puissance de VB.
Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim chaine As String, eclate
  chaine = "MonTexteATransformer"
  eclate = Split(StrConv(chaine, vbUnicode), Chr(0))
  For I = 1 To UBound(eclate) - 1 ' et je ne démarre pas à 1 par hasard (je veux éviter de mettre un "_" avant le tout 1er caractère
    If eclate(I) = UCase(eclate(I)) Then eclate(I) = "_" & eclate(I)
  Next
  chaine = UCase(Join(eclate))
  MsgBox chaine

[Jean-Philippe André]

Je decouvre la fonction Join grace a toi
Par contre, j'ai des espaces superflus entre mes lettres

[fring]

Bonjour,

Je te laisse faire les joints entre les differents bouts de code, c'est la partie la plus simple

Bah...perso je ne trouve pas que passer de "MonTexteATransformer" à "Mon_Texte_A_Transformer" est si simple que ça pour quelqu'un qui n'exécute pas régulièrement des manipulations de chaînes de caractères.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
Dim Txt As String
 
Txt = "MonTexteATransformer"
 
For x = Len(Txt) To 2 Step -1
    Select Case Asc(Mid(Txt, x, 1))
        Case 65 To 90
            Txt = Left(Txt, x - 1) & "_" & Right(Txt, Len(Txt) - x + 1)
    End Select
Next
 
MsgBox UCase(Txt)
 
End Sub

Il ne te reste plus qu'à boucler sur ta colonne A, c'est la partie la plus simple