Discussion :

[Jules.LT]

Bonjour,

Dans mon boulot, il m'arrive d'extraire pas mal de données mal formatées que je dois adapter pour pouvoir les exploiter sous excel. J'ai fait pour cela la macro ci-dessous, mais elle met énormément de temps à tourner.
Est-ce que des développeurs plus expérimentés pourraient m'indiquer comment faire la même chose en étant plus économe en ressources?

Merci!
Jules

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub convertir_en_nombre()
'
' convertir_en_nombre Macro
'
 
Selection.Replace What:=" ", Replacement:="", LookAt:=xlPart, _
    SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
    ReplaceFormat:=False
Selection.Replace What:="*", Replacement:="", LookAt:=xlPart, _
    SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
    ReplaceFormat:=False
Selection.Replace What:="€", Replacement:="", LookAt:=xlPart, _
    SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
    ReplaceFormat:=False
 
For Each Cellule In Selection
Cellule.Value = Val(Cellule.Value)
Next Cellule
 
Selection.NumberFormat = "#,##0_);[Red](#,##0);* - _)"
 
End Sub

[babaothe]

salut

ce sont probablement tes sélections successives qui sontr les responsables.
Préfère-leur la référence directe aux plages concernées.

[laetitia]

bonjour Jules.LT babaothe le forum .tu peus tester ce code relativement rapide!!! a adapter. pas le temps de tester toutes tes conditions.

pour une colonne A pour l'exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub essai()
Dim x As Variant, r As Long, c As Long
    With Application
    .Calculation = xlCalculationManual: .ScreenUpdating = False: .DisplayAlerts = False
    x = Range("a1", Cells(Rows.Count, "a").End(xlUp))
     For r = 1 To UBound(x, 1)
     For c = 1 To UBound(x, 2)
           x(r, c) = Replace(x(r, c), " ", "")
           x(r, c) = Replace(x(r, c), "€", "")
           x(r, c) = Replace(x(r, c), "*", "")
 
           x(r, c) = Val(x(r, c))
           'ou
           x(r, c) = x(r, c) * 1
   'pour le format idem   x(r, c) = format(x(r, c) ect...)
   Next c: Next r
   Range("a1", Cells(Rows.Count, "a").End(xlUp)) = x
  .Calculation = xlCalculationAutomatic: .ScreenUpdating = True: .DisplayAlerts = True
  End With
End Sub

pour une selection !!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub es()
Dim x As Variant, r As Long, c As Long
     With Application
    .Calculation = xlCalculationManual: .ScreenUpdating = False: .DisplayAlerts = False
    x = Selection
     For r = 1 To UBound(x, 1)
     For c = 1 To UBound(x, 2)
      x(r, c) = Replace(x(r, c), " ", "")
           x(r, c) = Replace(x(r, c), "€", "")
           x(r, c) = Replace(x(r, c), "*", "")
 
           x(r, c) = Val(x(r, c))
           'ou
           x(r, c) = x(r, c) * 1
     'pour le format idem    x(r, c) = format(x(r, c) ect...)
    Next c: Next r
   Selection = x
   .Calculation = xlCalculationAutomatic: .ScreenUpdating = True: .DisplayAlerts = True
   End With
End Sub

[pgz]

Bonjour à tous.

Tu devrais gagner beaucoup de temps en passant par un tableau de valeurs si la plage à traiter est grande.

Tu peux faire un truc du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub subNettoie()
Dim r As Excel.Range
Dim v As Variant, i As Long, j As Integer
 
Set r = Application.Selection
v = r.FormulaLocal
 
For i = 1 To UBound(v, 1)
    For j = 1 To UBound(v, 2)
        v(i, j) = Replace$(Replace$(Replace$(CStr(v(i, j)), " ", ""), "*", ""), "€", "")
        v(i, j) = Val(v(i, j))
    Next j
Next i
 
r.FormulaLocal = v
r.NumberFormat = "#,##0_);[Red](#,##0);* - _)"
 
Set r = Nothing
End Sub

Ici, j'ai considéré que la plage à traiter était sélectionnée, mais tu peux éviter en instanciant directement la variable d'objet r.
A mettre au point.

Cordialement,

PGZ

[Jules.LT]

Merci beaucoup pour vos réponses!
(désolé de ne pas avoir réagi plus vite, j'étais persuadé que je recevrais un mail du forum pour me prévenir mais l'option devait ê tre décochée)

Je teste tout ça et je reviens vers vous!