Discussion :

[mickisa]

* Bonjour *

voilà avec mon code ci dessous lorsque je l'éxecute il me renvoie une erreur sur la ligne ".send"
la valeur de configuration "sendusing" est non valide.
une petite idée?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub courriel()
Dim temp As String
temp = "C:\temp.xls"
    Sheets("trame").Select
    Cells.Select
    Selection.Copy
    Workbooks.Add
    Cells.Select
    ActiveSheet.Paste
    Application.CutCopyMode = False
    ChDir "C:\"
    ActiveWorkbook.SaveAs Filename:="C:\temp.xls", FileFormat:=xlNormal, _
        Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, _
        CreateBackup:=False
    ActiveWindow.Close
Dim CdoMessage As Object
Dim fichier As Variant
    fichier = temp
 
    If fichier = False Then Exit Sub
 
    Set CdoMessage = CreateObject("CDO.Message")
    With CdoMessage
        .Subject = "Exemple"
        .From = "xxxxx@wanadoo.fr"
        .To = "yyyyy@orange.fr"
        .CC = ""
        .BCC = ""
        .TextBody = "Texte dans le corps de message"
        .AddAttachment fichier
        .Send
    End With
 
    Set CdoMessage = Nothing
    Kill temp
End Sub

[Fvandermeulen]

Bonjour Mickisa,
L'utilisation de la méthode "CDO" pour l'envoi de mail nécessite de récupérer l'adresse SMTP, il te faut un code supplémentaire, voici un exemple
Place ceci avant la ligne 'With CdoMessage' de ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Cdo_Message.Configuration = GetSMTPServerConfig()

Et colle cette function dans ton module en adaptant l'adresse SMTP (voir remarque dans code)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Function GetSMTPServerConfig() As Object
' Microsoft CDO for Windows 2000 Library
    Const cdoSendUsingPickup = 1
    Const cdoSendUsingPort = 2
    Const cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing"
    Const cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
    Const cdoSMTPServerPort = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
 
    Dim Cdo_Config As Object 'New CDO.Configuration
    Set Cdo_Config = CreateObject("CDO.Configuration")
    Dim Cdo_Fields As Object
    Set Cdo_Fields = Cdo_Config.Fields
 
    With Cdo_Fields
        .Item(cdoSendUsingMethod) = cdoSendUsingPort
        .Item(cdoSMTPServer) = "xxx-mail.xxxx.com" 'Adapter l'adresse SMTP
        .Item(cdoSMTPServerPort) = 25
        .Update
    End With
 
    Set GetSMTPServerConfig = Cdo_Config
    Set Cdo_Config = Nothing
    Set Cdo_Fields = Nothing
 
End Function

Et n'oublie pas d'activer la référence Microsoft CDO for Windows 2000 Library si ce n'est pas déjà fait.

A+