Publicité
Discussion fermée
Page 2 sur 2 PremièrePremière 12
Affichage des résultats 21 à 25 sur 25
  1. #21
    Membre Expert
    Avatar de I'm_HERE
    Homme Profil pro Walid Toumi
    Inscrit en
    juillet 2008
    Messages
    959
    Détails du profil
    Informations personnelles :
    Nom : Homme Walid Toumi
    Localisation : Tunisie

    Informations forums :
    Inscription : juillet 2008
    Messages : 959
    Points : 1 601
    Points
    1 601

    Par défaut Lvd.Cmd

    salut,

    pour tester si un fichier contient des lignes vides:

    Code :
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    ::
    ::  C-NAME: Lvd.Cmd 
    ::  AUTHOR: WALID
    ::  DATE-C: 08/04/2009
    :: 
    ::  SYNTAX: Lvd [file.ext]
    ::  EX-SYN: Lvd fichier.txt
    ::
    ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    @echo off & setlocal
    
    If not exist "%~1" (
       Cls&findstr /rc:"^>" "%~f0"
       goto:eof
    )
    
    Set file="%~1"
    type %file% |find /v /c "" >"%Temp%\.$$$"
    Set /p count1=<"%Temp%\.$$$"
    For /f "delims=" %%a In ('type %file%') do (
          Set /a nb+=1
    )
    
    Set /a sum=%count1%-%nb%
    
      if %count1% gtr %nb% (
            Echo il y a %sum% Lignes vides dans %file%
    ) Else (Echo Pas de lignes vide dans %file%)
    
    del "%Temp%\.$$$" 2>nul
    Endlocal
    goto :eof
    >
    >      Vous devez inclure un fichier existant
    >      les fichiers contenant des espaces doivent
    >      etre mis entre guillemets
    >
      0  0

  2. #22
    Membre Expert
    Avatar de I'm_HERE
    Homme Profil pro Walid Toumi
    Inscrit en
    juillet 2008
    Messages
    959
    Détails du profil
    Informations personnelles :
    Nom : Homme Walid Toumi
    Localisation : Tunisie

    Informations forums :
    Inscription : juillet 2008
    Messages : 959
    Points : 1 601
    Points
    1 601

    Par défaut ULC.Cmd

    salut,

    Pour convertir une chaîne de caractère du majuscule/minuscule ou en minuscule/majuscule

    Code :
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    ::
    ::  C-NAME: ULC.Cmd     ::(Upper/Lower)Case.Cmd
    ::  AUTHOR: WALID
    ::  DATE-C: 03/06/2009
    :: 
    ::  SYNTAX: ULC [STRING]
    ::  EX-SYN: ULC bonjour maitre  
    ::
    ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    @echo off
    
    set "x=%*"
    if defined x ( echo:%x% ) else ( goto:eof )
    
    Call:Char Aa Bb Cc Dd Ee Ff Gg Hh Ii Jj Kk Ll Mm ^
              Nn Oo Pp Qq Rr Ss Tt Uu Vv Ww Xx Yy Zz
    echo:%x%
    goto:eof
    
    :Char
      if .%1==. goto:eof
      Set Ch=%1
      Set Upper=%Ch:~0,1%
      Set Lower=%Ch:~1,1%
      call set "x=%%x:%Lower%=%Upper%%%"  # LowerCase To UpperCase
    ::call set "x=%%x:%Upper%=%Lower%%%"  # UpperCase To LowerCase 
      shift
    goto:Char
      0  0

  3. #23
    Membre Expert
    Avatar de I'm_HERE
    Homme Profil pro Walid Toumi
    Inscrit en
    juillet 2008
    Messages
    959
    Détails du profil
    Informations personnelles :
    Nom : Homme Walid Toumi
    Localisation : Tunisie

    Informations forums :
    Inscription : juillet 2008
    Messages : 959
    Points : 1 601
    Points
    1 601

    Par défaut psw.cmd

    salut,

    pour ne pas afficher la saisie utilisateur:

    Code :
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    ::
    ::  C-NAME: PSW.Cmd 
    ::  AUTHOR: WALID
    ::  DATE-C: 24/07/2009
    :: 
    ::  SYNTAX: PSW
    ::  EX-SYN: PSW
    ::            
    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    @echo off
    setlocal
    mode 50,20
    set /a "c=3"                           
    :ndef ===============================================================
    title reste: %c%
    cls&echo/&echo/&echo/&set "mdp="
    (more +40 "%~f0") > "%Temp%\psw.vbs"     
    <nul  set /p "mdp=     Mot de Passe: "  
    for /f "tokens=*" %%a In ('cscript /nologo %Temp%\psw.vbs') do set mdp=%%a
    cd|set /p "mdp= "                      
    if not defined mdp (goto:ndef)
    del "%Temp%\psw.vbs" 2>nul                      
      cls                                   
      echo.&echo.&if "%mdp%"=="123456" (
      echo.
      echo      Mot de passe correct *** [%mdp%] ***
      echo.
      start /min sndrec32 /play /close %windir%\media\tada.wav
    ) else (
      if %c% equ 1 (goto:eof)
      Set /a c=c-1
      echo.
      echo      Saisie Invalide: [%mdp%]
      start /min sndrec32 /play /close %windir%\media\ringout.wav
      Ping 127.1 -n 5 >nul
      goto:ndef
    )
    endlocal&ping 127.1 -n 4 >nul&goto:EOF ================================
    '
    '
    '
    set PassW = WScript.CreateObject("ScriptPW.Password")
    Pass = PassW.GetPassWord()
    WScript.Echo Pass
    tester sous WinXpSP2
      0  0

  4. #24
    Membre à l'essai

    Inscrit en
    août 2009
    Messages
    7
    Détails du profil
    Informations forums :
    Inscription : août 2009
    Messages : 7
    Points : 21
    Points
    21

    Par défaut Sauvegardes Automatisées via Gestionnaire de tâches

    Bonsoir,
    Sur les conseils de I'm_HERE j'apporte ma modeste contribution.
    Cela fait redondance avec ce message ... mais bon

    Ce code à pour objectif d'être lancé automatiquement par le gestionnaire de tâche de Windows et ainsi d'assurer la sauvegarde de ces données

    Titre du code : Sauvegarde automatique
    Compatibilité : Windows 2000, XP
    But : Sauvegarder ses données sur 1 clic ou automatiquement (Via gestionnaire de tâches)

    Code dos :
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
    93
    94
    95
    96
    97
    98
    99
    100
    101
    @echo off
    echo         **********************************************************
    echo         *                                                        *
    echo         *       Supposons que nous voulions sauvegarder          *
    echo         *        les repertoires "Travail" et "Perso"            *
    echo         *               du disque dur ci-dessous                 *
    echo         *                                                        *
    echo         *   Poste de travail                                     *
    echo         *    :                                                   *
    echo         *    +-Sys (C:)                                          *
    echo         *      :                                                 *
    echo         *      +-Mes_fichiers                                    *
    echo         *      : :                                               *
    echo         *      : +-Travail                                       *
    echo         *      :                                                 *
    echo         *      +-Perso                                           *
    echo         *                                                        *
    echo         *              sur le disque externe USB E:              *
    echo         *          Architecture de la meme facon que C:          *
    echo         *                                                        *
    echo         *   Poste de travail                                     *
    echo         *    :                                                   *
    echo         *    +-USB_Sauvegarde (E:)                               *
    echo         *      :                                                 *
    echo         *      +-Mes_fichiers                                    *
    echo         *      : :                                               *
    echo         *      : +-Travail                                       *
    echo         *      :                                                 *
    echo         *      +-Perso                                           *
    echo         *                                                        *
    echo         *   /!\ Repertoires avec accents = pas pris en comptes   *
    echo         *  Le sript ci-dessous devra être adapté en fonction de  *
    echo         *  vos fichiers sources et votre lecteur de destination  *
    echo         *                                                        *
    echo         **********************************************************
    ECHO.
    Echo Debut de la routine
    ECHO.
    ECHO           *****************************************************
    ECHO           *                                                   *
    ECHO           *  SAUVEGARDE JOURNALIERE SUR SUPPORT USB EN COURS  *
    ECHO           *                                                   *
    ECHO           *****************************************************
    ECHO.
    REM -------- MEMORISATION ET DECOMPOSITON DE l'HEURE DE DEBUT ---------
    set debut=%TIME%
    set /a hd=%TIME:~0,2%*3600 
    set /a md=%TIME:~3,2%*60 
    set Sd=%TIME:~6,5%
    set /a s1=hd+md+sd
    REM -------- SAUVEGARDE DU REPERTOIRE TRAVAIL ---------
    ECHO - SAUVEGARDE DU REPERTOIRE TRAVAIL EN COURS -
    xcopy C:\Mes_fichiers\Travail\ E:\Mes_fichiers\Travail\ /Q /E /R /Y /I
    ECHO - SAUVEGARDE DU REPERTOIRE TRAVAIL TERMINEE -
    ECHO.
    ECHO.
    REM -------- SAUVEGARDE DU REPERTOIRE PERSO ---------
    ECHO - SAUVEGARDE DU REPERTOIRE EN COURS -
    xcopy C:\Perso\ E:\Perso\ /Q /E /R /Y /I
    ECHO - SAUVEGARDE DU REPERTOIRE TERMINEE -
    ECHO.
    ECHO.
    ECHO           *****************************************************
    ECHO           *                                                   *
    ECHO           *  SAUVEGARDE JOURNALIERE SUR SUPPORT USB TERMINEE  *
    ECHO           *                                                   *
    ECHO           *****************************************************
    ECHO.
    ECHO.
    REM -------- MEMORISATION ET DECOMPOSITON DE L'HEURE DE FIN ---------
    set fin=%TIME%
    set /a hf=%TIME:~0,2%*3600 
    set /a mf=%TIME:~3,2%*60 
    set Sf=%TIME:~6,5%
    set /a s2=hf+mf+sf
    REM -------- CALCUL DE LA DUREE EN SECONDES ---------
    set /a s3=s2-s1
    rem ----- CONVERTION DUREE EN MINUTES ET SECONDES -----
    set /a h1=s3/3600
    set /a m1=(s3/60)-(h1*60)
    set /a s4=s3-((h1*3600)+(m1*60))
    REM -------- MISE EN PAGE RESULTAT ---------
    Echo          +------------------------------------+
    Echo          : Debut de sauvegarde : %debut%  :
    Echo          +---------------------+--------------:
    Echo          :  Fin de sauvegarde  : %fin%  :
    Echo          +------------------------------------+
    REM -------- INFORMATION SUR DUREE CONDITIONNEE -------
    if %s3% leq 3599 goto minutes
    :heures
    Echo          : Temps de sauvegarde : %h1% h %m1% min %s4% s
    goto fin
    :minutes
    if %s3% leq 59 goto secondes
    Echo          : Temps de sauvegarde : %m1% min %s4% s
    goto fin
    :secondes
    Echo          : Temps de sauvegarde : %s4% secondes
    :fin
    Echo          +------------------------------------+
    pause

    Bon y'a peut-être plus simple ... mais je n'ai pas réussi à faire autrement.

    et voilà le résultat

    Lien (si la phot n'apparaît pas) : http://cjoint.com/data/imnEtoM3Mq_Resultat1.jpg


    La pose finale à la fin de l'exécution ne permet de contrôler le matin en arrivant que le script c'est bien lancé pendant la nuit.

    Ah oui, comme je l'ai dit .... j'utilise le gestionnaire de tâches de Windows pour lancer au moment voulu mes ou mon petit programmes (Je fais des sauvegardes journalières et/ou hebdomadaire)
    Vous trouverez ce gestionnaire dans le panneau de configuration ---> Démarrer>Panneau de configuration
    Ouvrez le gestionnaire (Tâches Planifiées ou scheduled tasks) et cliquez sur "Création d'une tâche planifiée" ... et suivre la procédure .... Pour info et/ou rappel le programme à lancer c'est le fichier .bat que vous avez crée

    Cela existe déjà peut-être ... Mais je voulais juste faire partager le résultat de mes travaux, comme j'en ai l'habitude dans d'autres domaines
    a+
      0  0

  5. #25
    Expert Confirmé Sénior
    Avatar de shawn12
    Homme Profil pro Thomas Garcia
    Chef de projet en SSII
    Inscrit en
    avril 2006
    Messages
    3 369
    Détails du profil
    Informations personnelles :
    Nom : Homme Thomas Garcia
    Âge : 28
    Localisation : France

    Informations professionnelles :
    Activité : Chef de projet en SSII
    Secteur : Finance

    Informations forums :
    Inscription : avril 2006
    Messages : 3 369
    Points : 6 440
    Points
    6 440

    Par défaut

    Vous pouvez désormais proposer directement vos sources aux téléchargement en les postant dans la catégorie Scripts/Batchs de la rubrique téléchargements.

    >> Cliquez ici pour y accéder <<


    Les codes-sources proposés dans cette discussions ont été importés dans l'outil.
      0  0

Liens sociaux

Règles de messages

  • Vous ne pouvez pas créer de nouvelles discussions
  • Vous ne pouvez pas envoyer des réponses
  • Vous ne pouvez pas envoyer des pièces jointes
  • Vous ne pouvez pas modifier vos messages
  •