Discussion :

[Danyel]

Salut All,

Je voudrais faire un petit effet de vision 3D sur un label en vs2005.
En VB6, c'etait facile car il suffisait de superposer 2 labels avec 1 pixel en plus à droite et bas et de couleurs differentes pour faire un beau rendu.
Mais maintenant, avec la fausse transparence ... on ne peut plus faire cela.

Qq connaitrait-il comment faire cela ?
Thx All,
Danyel.

[smyley]

Et pourquoi ne pas faire ton petit rendu dans l'évènement Paint du label ?

[Totanne]

Plus que dans l'event Paint, une bonne fois pour toute à l'initialisation du label en créant un bitmap que tu affecte à la propriété image du label.
Propriété Text à "" et texte a afficher dans la propriété Tag par ex.

[Danyel]

Et pourquoi ne pas faire ton petit rendu dans l'évènement Paint du label ?

Oui, je vais deja aller dans ce sens pour voir un peu.

Plus que dans l'event Paint, une bonne fois pour toute à l'initialisation du label en créant un bitmap que tu affecte à la propriété image du label.
Propriété Text à "" et texte a afficher dans la propriété Tag par ex.

Un exemple totanne ?

[olsimare]

Bonjour.

Plus que dans l'event Paint, une bonne fois pour toute à l'initialisation du label en créant un bitmap que tu affecte à la propriété image du label.
Propriété Text à "" et texte a afficher dans la propriété Tag par ex.

Certes mais ça oblige à gérer le resize, le changement de .text, de forecolor et autres...

Donc je passerai plutôt par le onpaint en utilisant un buffer (via une bitmap) et en faisant un textrenderer ou plutôt un drawstring (la qualité est meilleure dans ce cas), puis un second décalé par rapport au premier.
Puis, afficher l'image par le graphic du onpaint.

Cdt.

[Danyel]

- je passerai plutôt par le onpaint en utilisant un buffer (via une bitmap)
- Puis, afficher l'image par le graphic du onpaint.

Salut Olsi,
Tu peux m'en dire un peu plus sur ces 2 phrases.
Ok pour le drawstring, mais pas sur le buffer puis sur l'affichage du dit buffer.
Merci pour ton aide.

[olsimare]

Bonjour.

C'est parce que je pars du principe que ton label est transparent (au vue des posts précédents ).

Donc il s'agit de dessiner le contenu du label dans une bitmap intégralement (le BackGround ET le ForeGround), avant d'afficher le tout via un graphics.drawimage.

Plutôt qu'un long discours :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
Option Strict On
Option Explicit On
Imports System.Runtime.InteropServices
 
Public Class LabelForDany
    Inherits Label
 
#Region "declaration"
    Private cShadowForeColor As Color = Color.WhiteSmoke
#End Region
 
#Region "Graphique"
    Public Property ShadowForeColor() As Color
        Get
            Return cShadowForeColor
        End Get
        Set(ByVal value As Color)
            cShadowForeColor = value
        End Set
    End Property
 
    Protected Overrides Sub OnPaint( _
    ByVal e As PaintEventArgs)
 
        Dim bufferImage As Bitmap
        bufferImage = New Bitmap(Bounds.Width, Bounds.Width)
        Dim gd As Graphics = Graphics.FromImage(bufferImage)
        gd.SmoothingMode = Drawing2D.SmoothingMode.HighQuality
        gd.TextRenderingHint = Drawing.Text.TextRenderingHint.AntiAlias
 
        PaintParentBackground(gd)
 
        Dim intShadowOffset As Integer = CInt(Font.Size / 10)
 
        gd.DrawString(Text, Font, New SolidBrush(ShadowForeColor), New Point(intShadowOffset, intShadowOffset))
        gd.DrawString(Text, Font, New SolidBrush(ForeColor), New Point(0, 0))
 
        gd.Dispose()
 
        e.Graphics.DrawImage(bufferImage, 0, 0)
 
        bufferImage.Dispose()
 
    End Sub
    Private Sub PaintParentBackground(ByVal g As Graphics)
        If Not Me.Parent Is Nothing Then
            Dim rect As Rectangle = New Rectangle(Left, Top, Width, Height)
            g.TranslateTransform(-rect.X, -rect.Y)
            Dim pea As PaintEventArgs = New PaintEventArgs(g, rect)
            pea.Graphics.SetClip(rect)
            InvokePaintBackground(Parent, pea)
            g.TranslateTransform(rect.X, rect.Y)
        Else
            g.FillRectangle(SystemBrushes.Control, ClientRectangle)
        End If
    End Sub
 
    Protected Overrides Sub OnPaintBackground( _
    ByVal pevent As PaintEventArgs)
        ' rien
    End Sub
 
#End Region
 
End Class

Ca n'est pas parfait (pas de gestion du TextAlign ou autre) mais illustre le truc.

Cdt.

[Danyel]

Merci olsi.
Vais etudier tout cela ... à tête repose

[Danyel]

Une petite aide pour le textalign middlecenter serait apprecie
J'ai rajoute au controle la propriete de valeur de distance de l'ombre, mais je n'arrive pas à faire le textalign.
Merci pour votre aide.

[Pol63]

en partant d'un label normal, il est aussi possible de faire quelques drawline pour faire de l'effet

[Danyel]

en partant d'un label normal, il est aussi possible de faire quelques drawline pour faire de l'effet

Que veux tu dire par là ?

[olsimare]

Bonjour.

Tiens Danyel, en passant, grâce à Sperot (rendons à Cesar ...) j'ai un peu optimiser la façon de gérer le background :
http://www.developpez.net/forums/sho...d.php?t=531927

Pour le textalign dans un drawstring, j'utilise une methode shared perso qui donne le point d'insertion du texte à partir du ContentAlignment, du rectangle, du font et du text car je n'ai pas trouvé de méthode du framework pour le faire.

Cdt.

[Danyel]

Oui j'ai vu ton code sur l'autre post ... je vais modifier.
Pour le middlecenter, je vais mettre les mains ... on verra bien
Merci olsi.

[Danyel]

Pour ceux que ca interesse, voici le code complet du LabelShadow.
(avec possibilite de choisir la distance de l'ombre et aussi avec tous les textalign)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
Public Class LabelShadowbyDany
 
    Inherits Label
 
    Private cShadowForeColor As Color = Color.WhiteSmoke
    Private vDistance As Integer = 2
 
 
    Public Property ShadowForeColor() As Color
        Get
            Return cShadowForeColor
        End Get
        Set(ByVal value As Color)
            cShadowForeColor = value
        End Set
    End Property
 
    Public Property ShadowDistance() As Integer
        Get
            Return vDistance
        End Get
        Set(ByVal value As Integer)
            vDistance = value
        End Set
    End Property
 
 
    Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
 
        Dim bufferImage As Bitmap
        bufferImage = New Bitmap(Bounds.Width, Bounds.Width)
        Dim gd As Graphics = Graphics.FromImage(bufferImage)
        gd.SmoothingMode = Drawing2D.SmoothingMode.HighQuality
        gd.TextRenderingHint = Drawing.Text.TextRenderingHint.AntiAlias
 
        PaintParentBackground(gd)
 
        gd.DrawString(Text, Font, New SolidBrush(ShadowForeColor), New Point(textPosition(0)))
        gd.DrawString(Text, Font, New SolidBrush(ForeColor), New Point(textPosition(1)))
 
        e.Graphics.DrawImage(bufferImage, 0, 0)
 
        gd.Dispose()
        bufferImage.Dispose()
 
    End Sub
 
    Private Sub PaintParentBackground(ByVal g As Graphics)
 
        If Not Me.Parent Is Nothing Then
            Dim rect As Rectangle = New Rectangle(Left, Top, Width, Height)
            g.TranslateTransform(-rect.X, -rect.Y)
            Dim pea As PaintEventArgs = New PaintEventArgs(g, rect)
            pea.Graphics.SetClip(rect)
            InvokePaintBackground(Parent, pea)
            g.TranslateTransform(rect.X, rect.Y)
        Else
            g.FillRectangle(SystemBrushes.Control, ClientRectangle)
        End If
 
    End Sub
 
    Protected Overrides Sub OnPaintBackground(ByVal pevent As PaintEventArgs)
 
        ' rien
 
    End Sub
 
    Private Function textPosition(ByVal Lequel As Integer) As Point
 
        Dim sTextSize As Size = TextRenderer.MeasureText(Me.Text, Me.Font)
        If sTextSize.Width > Me.Bounds.Width Then
            sTextSize.Width = Me.Bounds.Width
        End If
        If sTextSize.Height > Me.Bounds.Height Then
            sTextSize.Height = Me.Bounds.Height
        End If
        Dim intLeft As Integer = 0
        Dim intTop As Integer = 0
        Dim intRigth As Integer = Me.Bounds.Width - sTextSize.Width
        Dim intBottom As Integer = Me.Bounds.Height - sTextSize.Height
        Dim intXCenter As Integer = CInt((Me.Bounds.Width - sTextSize.Width) / 2)
        Dim intYCenter As Integer = CInt((Me.Bounds.Height - sTextSize.Height) / 2)
 
        Dim intShadowOffset As Integer = CInt(ShadowDistance)
 
        Select Case Lequel
            Case 0
                intLeft += intShadowOffset
                intTop += intShadowOffset
                intRigth += intShadowOffset
                intBottom += intShadowOffset
                intXCenter += intShadowOffset
                intYCenter += intShadowOffset
        End Select
 
        Select Case Me.TextAlign
            Case ContentAlignment.BottomCenter
                Return New Point(intXCenter, intBottom)
            Case ContentAlignment.BottomLeft
                Return New Point(intLeft, intBottom)
            Case ContentAlignment.BottomRight
                Return New Point(intRigth, intBottom)
            Case ContentAlignment.MiddleCenter
                Return New Point(intXCenter, intYCenter)
            Case ContentAlignment.MiddleLeft
                Return New Point(intLeft, intYCenter)
            Case ContentAlignment.MiddleRight
                Return New Point(intRigth, intYCenter)
            Case ContentAlignment.TopCenter
                Return New Point(intXCenter, intTop)
            Case ContentAlignment.TopLeft
                Return New Point(intLeft, intTop)
            Case ContentAlignment.TopRight
                Return New Point(intRigth, intTop)
        End Select
 
    End Function
 
End Class

Le code is made by Olsi and by Me.

PS : Commence à bien saisir les controls persos
... Grace à Olsi bien sûr

[olsimare]

Bonjour.

Oui j'ai vu ton code sur l'autre post ... je vais
modifier.

Et alors ? On reproduit le code avec le InvokePaintBackground(Parent, pea) ?

Cdt.

[Danyel]

Ben en fait, j'ai essaye hier soir le nouveau code, mais il genere une erreur chez moi, donc j'ai garde l'ancien pour l'instant.
Quand j'aurai un moment, je re-essayerai et je te donnerai l'erreur sur le post en question.

[Danyel]

Il y a juste un truc que j'arrive pas a faire :
J'ai rajoute une propriete qui permet de choisir la distance x;y de l'ombrage.
Alors ca fonctionne, mais quand je modifie la valeur, il n'y a pas de refresh automatique sur le formulaire.
Donc ma question :
Comment faire pour que dès que je modifie la valeur, ca s'affiche directement dans le form.
Merci pour votre aide.

...

Edit : Je viens d'optimiser mon objet et je n'ai plus le probleme. Ca doit se faire automatiquement.

[smyley]

Sinon tu peut forcer le contrôle à se redessiner complètement lorsqu'une propriété est modifiée en appelant this.Invalidate(true);

[Pol63]

this

pas de gros mot ici

[smyley]

Ahem, oui donc, juste Me.Invalidate(True)