Discussion :

[Optimistic]

Bonjour je suis debutant en vbscript et puis on m'a demander de faire un script et je ne suis pas a l'aise car je ne trouve pas comment il faut faire


Ecrire un script qui recoit en aprametre un nom de repertoire et qui affiche les fichiers contenus dans ce repertoire et ensuite parcours tout les sous-repertoires pour afficher le contenu des fichiers et des sous-repertoires recursivement. Apres chaque nom, le script affiche <DIR> si c'est un repertoire ( ou rien sinon) L'affichage est placé en retrait (Indentation) pour chaque sous-repertoire.


Merci pour votre aide ca serait tres apprecié

[Thulkash]

Présente un truc de la forme :
Contenu du dossier C:\Toto
\__Fichier1
\__Dossier1

\__Fichier11

\__Fichier12

\__Dossier11

\__Fichier111

\__Dossier2

A toi à l'améliorer
@+

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Set objFSO = CreateObject("Scripting.FileSystemObject")
strDossierRacine = InputBox("Saisir le dossier racine :", "Dossier racine", "Dossier racine")
intNiveauArborescence = 0
 
subVerifExistenceDossier strDossierRacine
Set objDossierRacine = objFSO.GetFolder(strDossierRacine)
subAfficherArborescence	objDossierRacine, intNiveauArborescence
 
Sub subVerifExistenceDossier(strNomDossier)	'vérifie que le dossier de base existe	
	If Not objFSO.FolderExists(strNomDossier) Then
		Wscript.Echo "Le dossier spécifié n'existe pas"
		Wscript.Quit
	Else
		Wscript.Echo "Contenu du dossier " & strNomDossier
	End If
End Sub
 
Sub subAfficherArborescence(objDossierParent, intNiveauArborescence)
	Set colFicArbo = objDossierParent.Files
 
	If colFicArbo.Count <> 0 Then
		For Each objFicArbo In colFicArbo
			strLigne = ""
			For i=0 To intNiveauArborescence
				strLigne = strLigne & "  "
			Next
			Wscript.Echo strLigne & "\__" & objFicArbo.Name
		Next
	End If
 
	Set colSousDossiers = objDossierParent.SubFolders
	If colSousDossiers.Count <> 0 Then	'vérifie qu'il y a des sous-dossiers
		For Each objDossierArbo In colSousDossiers
			strLigne = ""
			For i=0 To intNiveauArborescence
				strLigne = strLigne & "  "
			Next
			Wscript.Echo strLigne & "\__" & objDossierArbo.Name
			subAfficherArborescence objDossierArbo, intNiveauArborescence + 1	'RECURSIVITE !!!!!
		Next
	End If
End Sub