Discussion :

[Thierry_ZT]

Bonjour à toutes et à tous.

Merci d'avance pour votre aide.
Ça fait 2 jours que je planche la dessus et je n'y arrive pas.
Mon but étant de pouvoir importer des fiches techniques en pièces jointes.
j'ai donc un dossier parent:


avec un certain nombre de fiches à l’intérieur:


J'ai réussi à trouver quelques codes sur le net me permettant de faire le maximum. Pour la première référence l'importation se passe bien, ça bloque à la deuxième. je pense qu'il y a une petite coquille dans le code mais ne suis pas assez à l'aise encore.

Merci pour votre coopération.

[Thierry_ZT]

En fait ce qu'il se passe c'est que le module repasse dans le dossier autant de fois qu'il y a de fichiers.
Comment limité ce problème?

Cordialement.

PS: Si vous avez un code plus court et plus simple je suis preneur.

[madefemere]

Bonjour,

Le type pièce jointe a été effectivement proposé dans les dernières versions d'Access mais il n'est pas très simple à exploiter dès qu'on veut faire quelque chose de plus poussée.
1- Pour enregistrer un fichier dans un champ de table, on se contente souvent d'un champ texte avec le chemin complet du nom du fichier (quitte à créer effectivement un sous-dossier du dossier de l'application pour les stocker) dont tu as un exemple dans le tuto de Caféine pour la gestion des photos.
2- Ensuite, tu peux utiliser les instructions dans la discussion ci-jointe à partir d'un évènement de ton formulaire ou ses contrôles pour ouvrir ton fichier.

Cordialement.

[Thierry_ZT]

Merci madefemere mais la fonction: LoadAttachments() fonctionne bien.
il faudrait que je la lance une fois dans chaque dossier.

C'est ça que je n'arrive pas à faire, aller de dossier en dossier pour pouvoir lancer ma fonction.

Je pense que c'est un code tout bête mais je n'ai pas encore trouver la solution.

[Thierry_ZT]

Bonjour,

Voici donc les différents modules nécessaires et fonctionnels pour cette tâche, cela pourra peut être intéressé des personnes.

Le code pour le bouton:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Admin_Click()
 
    Dossier_Import = BrowseFolder("Choisissez votre répertoire:")
    Marque = "LEGRAND"
    Import (Dossier_Import)
    MsgBox "Terminé !", vbInformation
 
End Sub

La fonction BrowseFolder:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Function BrowseFolder(Title As String, _
        Optional InitialFolder As String = vbNullString, _
        Optional InitialView As Office.MsoFileDialogView = _
            msoFileDialogViewList) As String
    Dim V As Variant
    Dim InitFolder As String
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = Title
        .InitialView = InitialView
        If Len(InitialFolder) > 0 Then
            If Dir(InitialFolder, vbDirectory) <> vbNullString Then
                InitFolder = InitialFolder
                If Right(InitFolder, 1) <> "\" Then
                    InitFolder = InitFolder & "\"
                End If
                .InitialFileName = InitFolder
            End If
        End If
        .Show
        On Error Resume Next
        Err.Clear
        V = .SelectedItems(1)
        If Err.Number <> 0 Then
            V = vbNullString
        End If
    End With
    BrowseFolder = CStr(V)
End Function

Le module Import:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Sub Import(Dossier_Import As String)
 
    Dim rst As DAO.Recordset2
    Dim strDossier As String
    Dim varSousDossiers As Variant
    Dim intSousDossiers As Integer
    Dim intI As Integer
    Dim strFichier As String
 
    Set rst = CurrentDb.OpenRecordset("Base", dbOpenDynaset)
 
    strDossier = Dossier_Import
    varSousDossiers = ListerSousDossiers(strDossier)
    intSousDossiers = UBound(varSousDossiers)
 
    If intSousDossiers <= 0 Then
        Debug.Print "Aucun sous-dossier"
    Else
        For intI = 1 To intSousDossiers
        rst.AddNew
        rst("Marque") = "LEGRAND"
        rst("Référence") = Right(varSousDossiers(intI), 6)
        rst.Update
        LoadAttachments (varSousDossiers(intI))
        Next
    End If
 
    rst.Close
    Set rst = Nothing
 
End Sub

Et la fonction LoadAttachments (un peu modifiée):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
Public Function LoadAttachments(strPath As String, Optional strPattern As String = "*.*") As Long
    Dim dbs As DAO.Database
    Dim rst As DAO.Recordset2
    Dim rsA As DAO.Recordset2
    Dim fld  As DAO.Field2
    Dim strFile As String
 
    'Get the database, recordset, and attachment field
    Set dbs = CurrentDb
    Set rst = dbs.OpenRecordset("Base")
    Set fld = rst("Fiche Technique")
 
    'Navigate through the table
    Do While Not rst.EOF
 
        'Get the recordset for the Attachments field
        Set rsA = fld.Value
 
        'Load all attachments in the specified directory
        strFile = Dir(strPath & "\*.*")
 
        rst.Edit
        Do While Len(strFile) > 0
            'Add a new attachment that matches the pattern.
            'Pass "" to match all files.
            If strFile Like strPattern And rst("Référence") = Right(strPath, 6) And rst("Marque") = "LEGRAND" Then
                rsA.AddNew
                rsA("FileData").LoadFromFile strPath & "\" & strFile
                rsA.Update
 
                'Increment the number of files added
                LoadAttachments = LoadAttachments + 1
            End If
            strFile = Dir
        Loop
        rsA.Close
 
        rst.Update
        'Next record
        rst.MoveNext
    Loop
 
    rst.Close
    dbs.Close
 
    Set fld = Nothing
    Set rsA = Nothing
    Set rst = Nothing
    Set dbs = Nothing
End Function

Voila