Requete complexe pour stats

**dyolet** · 13/07/2015, 16h31

Bonjour, j'ai besoin de qq conseils pour obtenir une requete me permettant d'obtenir les montants cumulés de X factures par client.
J'ai deja une premiere requete qui me donne toutes les factures sur un période donnée et une zone geograhique donnée. Je voudrais donc m'appuyer sur cette selection pour avoir le total par client , lorqu'ils ont eu au moins 3 factures.

Comme c'est pas assez compliqué , ces 3 factures parmi "n" ne doivent etre que les 3 plus importantes (decroiss.) Tous les clients n'ayant pas 3 factures ne doivent pas etre remontés.

Merci de votre aide

**ClaudeLELOUP** · 14/07/2015, 09h58

Bonjour et bonne fête à mes voisins du dessous.

Un virtuose du SQL passera peut-être pour te proposer UNE requête.

Sinon voici une proposition :

Soit la table :

Une requête pour ranger les factures

Elle donne ceci

Et un code pour cumuler les 3 plus grosses de chacun :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Option Compare Database
Option Explicit
 
 
Public Sub Les3Factures()
  Dim rst As Recordset
  Dim i As Integer
  Dim lClient As Long
  Dim dTotal As Double
  Dim sSql As String
  'Vidanger tResultat
  DoCmd.SetWarnings False
  DoCmd.RunSQL "DELETE * FROM tResultat;"
  Set rst = CurrentDb.OpenRecordset("rFacRangees")
  rst.MoveFirst
  i = 1
  lClient = rst("Client")
  Do Until rst.EOF
    If lClient = rst("Client") Then
        Select Case i
          Case Is <= 3 'on cumule pour ce client
            dTotal = dTotal + rst("Montant")
            i = i + 1  ' après traitement de la 3e facture, i = 4
            rst.MoveNext
          Case Is > 3 ' on ne cumule plus pour ce client
            rst.MoveNext
        End Select
      Else
        'Rupture Ajouter dans la table le cumul du client précédent, si i>=3
        If i = 4 Then  'donc, s'il y a eu au moins 3 factures
            sSql = "INSERT INTO tResultat ( Client, Total3Factures ) SELECT " & lClient & " AS Expr1, " & dTotal & " AS Expr2;"
            DoCmd.RunSQL sSql
            'réinitialiser les compteurs pour client suivant
            lClient = rst("Client")
            dTotal = 0
            i = 1
          Else
            lClient = rst("Client")
            dTotal = 0
            i = 1
        End If
    End If
  Loop
  'Traitement du dernier client de la liste
  If i = 4 Then
      sSql = "INSERT INTO tResultat ( Client, Total3Factures ) SELECT " & lClient & " AS Expr1, " & dTotal & " AS Expr2;"
      DoCmd.RunSQL sSql
  End If
  'Montrer le résultat
  DoCmd.OpenTable "tResultat"
  'sortir
  DoCmd.SetWarnings True
  rst.Close
  Set rst = Nothing
End Sub