Discussion :

[amelyfred]

Bonjour,
Je voudrais pouvoir fermer tous les formulaire ouvert sauf un ayant un nom précis.

Ce code me permet de fermer tous les formulaires mais comment le modifier pour éviter la fermeture du formulaire "toto"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Do While Forms.Count > 0
     DoCmd.Close acForm, Forms(0).Name
Loop

Merci à tous pour votre aide
Fred

[Didier L]

Bonjour,

Tout simplement avec un "If" et en changeant la condition de ton While.
Car tu boucle tant que tu a un formulaire ouvert
Essaye plutôt:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
NbrForms=Forms.Count
For I=0 to NbrForms
	if Forms(I).Name<>"TOTO" then
     		DoCmd.Close acForm, Forms(I).Name
	end if
Next I

[madefemere]

Bonjour,

En faisant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Do While Forms.Count > 0
     If Forms(0).Name <> "Toto" then
          DoCmd.Close acForm, Forms(0).Name
     End If
Loop

Cordialement,

[Didier L]

Bonjour madefemere

Comment tu sorts de ta boucle ???
Car si tu ne ferme pas le formulaire "toto" Forms.Count sera toujours supérieur à zéro

[ClaudeLELOUP]

Bonjour,

Je propose ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Sub FermeTousSaufToto()
  Do While Forms.Count > 1
      If Forms(0).Name <> "toto" Then
          DoCmd.Close acForm, Forms(0).Name
        Else
          DoCmd.Close acForm, Forms(1).Name
      End If
  Loop
End Sub

Didier,




À chaque occurrence de suppression, la numérotation change

[madefemere]

Salut tout le monde,

Eh oui, répondre dans la foulée n'est jamais évident Manque d'attention et pas de tests, donc on laisse passer certaines trivialités .

Fred, t'as compris, il faut mettre un If quelque part.

Bonne continuation à tous

[Didier L]

Ok pour le If, mais il faut pouvoir sortir de la boucle aussi

Pour ma part l'erreur que claude a eu c'est a cause d'une boucle qui va trop loin !
Si la collection part de zéro alors il faut allez jusqu'a Forms.Count-1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
NbrForms=Forms.Count-1
For I=0 to NbrForms
	if Forms(I).Name<>"TOTO" then
     		DoCmd.Close acForm, Forms(I).Name
	end if
Next I

méa cupla

[madefemere]

Didier,

Je parlais de "nous" avec notre volonté d'aider les autres et d'être presser.
On attend ce que va dire Fred

Bonne continuation

[ClaudeLELOUP]

Didier,
Imagine
FormulaireA : forms(0)
FormulaireB: forms(1)
FormulaireToto: forms(2)

Tu dis boucler de 0 à 2

1er tour avec 0
tu fermes FormulaireA
=> les index deviennent
FormulaireB: forms(0)
FormulaireToto: forms(1)

2e tour avec 1
Tu évites Toto et il reste
FormulaireB: forms(0)
FormulaireToto: forms(1)

3e tour avec 2
Tu cherches forms(2)

[Didier L]

Bonsoir Claude

Merci et bien vu pour le débogage

effectivement c'est vrai que les index de la collection Forms se modifie des lors que l'on va en ouvrir ou en fermer un
Bravo et merci a toi
Je l'avais oublié et pas tester.
A force d'avoir l'habitude de parcourir les collections d'objets mais sans les fermer, j'avais omis ce point de détail très important.
Ta solution est donc la seule qui marche.
je n'essayerai même pas d'expliquer comment charger les noms des formulaires dans une variable tableau excepté le "toto" en question pour ensuite fermer tous les formulaires ouverts dont on a récupéré le nom
Ta solution est plus simple et plus claire
Mais c'est bien pour cela aussi que tu es "rédacteur"

Bonne soirée à tous et surtout bonne continuation à fred

PS : madefemere j'avais bien compris et bien pris ce que tu disais

[ClaudeLELOUP]

Bonjour,

charger les noms des formulaires dans une variable tableau excepté le "toto" en question pour ensuite fermer tous les formulaires ouverts dont on a récupéré le nom.

Bonne idée ! … et l’occasion d’expliquer comment alimenter un tableau en lui ajoutant une colonne à chaque cycle de la boucle sur les formulaires ouverts (instruction Redim).

« Rédacteur » parce que j’ai du temps libre et que j’aime expliquer quand j’ai enfin compris comment ça marche.

Bon week-end.

[Didier L]

Bonjour,

Parce que c'est samedi
Parce que j'ai le temps
Parce que cela m'amuse
Voila un petit morceau de code qui peut servir d'exemple de passage de paramètre, de parcours d'une collection d'objet, de redimensionnement d'un tableau dynamique et de récupération de son nombre d'élément grâce a "Ubound"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub FermeToutSauf(ByVal psFormName As String)
Dim I As Integer
Dim vtFormNames() As String
Dim voForm As Form
    For Each voForm In Forms
        If voForm.Name <> psFormName Then
            ReDim Preserve vtFormNames(I)
            vtFormNames(I) = voForm.Name
            I = I + 1
        End If
    Next
    For I = 0 To UBound(vtFormNames)
        DoCmd.Close acForm, vtFormNames(I)
    Next
End Sub

Et pour appeler la procédure :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FermeToutSauf "toto"

Bonne journée

[ClaudeLELOUP]

Ben, tu vois quand on a le temps !

[amelyfred]

Salut les gars et merci à vous trois pour vos réponses.
Je vais tester tout ca lundi à tête repose car la avec le changement d heure je suis un peu décalé
J avais essayé avec un if mais j avais bien réussi.
Le solution de Claude me semble très bien mais pour le fun je vais essayer de comprendre ton bout de code Didier.
Bon we
Fred

[Didier L]

Bonjour,

Comme c'est dimanche et que j'ai un peu de temps, je vais faire ma BA et essayer de mettre des commentaire
Ce n'est pas mon fort, mais cela pourras t'aider à comprendre le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub FermeToutSauf(ByVal psFormName As String)
Dim I As Integer
Dim vtFormNames() As String 'déclaration d'une variable de type tableau
Dim voForm As Form 'déclaration d'une variable objet de type formulaire
    ' dans un premier temps on parcours la collection Forms des formulaires ouverts afin de récupérer dans un tableau leurs noms
    For Each voForm In Forms ' Grace au For Each je parcours toute la collection sans avoir besoin d'un Set pour affecté ma variable voForm
        If voForm.Name <> psFormName Then 'Je test le nom du formulaire qui se trouve dans ma variable  voForm et le compare au nom passé en paramètre dans la variable psFormName ("toto" dans ton cas)
            ReDim Preserve vtFormNames(I) 'A chaque fois, j'ajoute un élément dans ma variable tableau tout en préservant les valeurs initialement remplies
            vtFormNames(I) = voForm.Name 'Ensuite j'affecte le nom de mon formulaire à ce nouvel élément de mon tableau
            I = I + 1 'J'incrémente mon compteur afin de pouvoir le cas échéant ajouter une nouvel dimension à mon tableau.
        End If
    Next
    ' à la sortie de ma boucle, j'ai récupérer la liste de tous les noms des formulaires ouverts dans ma variable tableau excepté celui passé en paramètre
    For I = 0 To UBound(vtFormNames) 'Je parcours tous les éléments de mon tableau grâce  a leur indice et m'arrête sur le N° du dernier élément renvoyé par Ubound()
        DoCmd.Close acForm, vtFormNames(I) 'je ferme ces formulaires grâce à leur nom.
    Next
End Sub

Donc si on appelle la procédure ainsi:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FermeToutSauf "Toto"

On ferme tout sauf le formulaire "Toto" et s'il n'est pas ouvert, on ferme tout comme si on mettait le nom d'un formulaire qui n'existe pas ou si on met "" à la place de "Toto"

Si on avait voulu ne pas être obligé de passer un paramètre pour pouvoir tout fermer on aurait du déclarer la procédure comme cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sub FermeToutSauf(Optional ByVal psFormName As String)

Ce qui nous permet d'appeler la procédure de la manière suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
FermeToutSauf "Toto"
ou
FermeToutSauf

Et voila

Bon dimanche

[amelyfred]

Salut Didier
Merci pour tes commentaires c'est très clair et j'ai bien compris. C'est nickel.
Mais du coup en terme d'efficacité, quelle sera la différence entre ton code et celui de Claude? (juste pour mon info car je travaille seulement avec 4-5 formulaire donc je ne suis pas sur que la différence soit visible).

Bonne journée
Fred

[Didier L]

Bonjour,

Aucune c'était juste un exercisse de style pour pouvoir expliquer d'autres manière de manipuler les collections

[amelyfred]

OK merci.
Ca marche nicke!!!