Discussion :

[Zutalor]

Bonsoir.
J'ai un formulaire nommé "Elèves", avec un champ "NOM" et un champ "Prénom" ... entre autre.
Je souhaiterais récupérer, un par un, tous les noms et prénoms de ce formulaire, et créer un dossier nommé "NOM_Prénom".

J'ai fait une fois de plus un bidouillage, qui marche, mais qui m'a généré quelques erreurs. Et je pense qu'il a certainement une meilleure alternative.

J'ai deux erreurs :

• le compteur se bloque à un moment donné, j'ai donc fait une gestion d'erreur pour sortir de la Boucle. Alternative qui marche ... mais pas très satisfaisante
• et quand les nom sont composés d'espace, style VAN DE BROOK Laurent ... cela ne me crée pas le dossier VAN DE BROOK_Laurent, mais VAN => Mkdir ne gère pas les espaces (d'où la présence du tiret bas d'ailleurs entre le nom et le prénom).

Voici mon code et quelle alternative pourrait être envisagée ?
Merci par avance. Bonne soirée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub CreerTousLesDossiersEleves()
Dim Chemin, Commande, NomPrenomDossier  As String
Dim nbEnregistrement As Integer
 
nbEnregistrement = DCount("*", "Eleves") - 1
MsgBox nbEnregistrement
DoCmd.GoToRecord , , acFirst
'MsgBox nb
 
'Crée d'un seul coup tous les répertoires
For i = 1 To nbEnregistrement
NomPrenomDossier = Nom.Value & "_" & Prénom.Value
Chemin = Application.CurrentProject.Path & "\" & AnneeScolaire & "\" & "ESS" & "\" & NomPrenomDossier
On Error GoTo GestionErreur
DoCmd.GoToRecord , , acNext
 
Commande = Environ("comspec") & " /c mkdir " & Chemin
Shell Commande, 0
Next i
 
GestionErreur:
DoCmd.GoToRecord , , acFirst
On Error Resume Next
 
End Sub

[Robert1957]

Bonjour Zutalor,

Voici un code plus simple et qui tient en compte les espaces. Il va parcourir la table qui contient les informations que tu désires et ensuite créer le répertoire dans celui de l'application.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub mkD()
On Error GoTo GestionErreurs
    Dim db As DAO.Database: Set db = CurrentDb
    Dim rst As DAO.Recordset
    Dim strDossier As String, strSQL As String, strRep As String
 
    strSQL = "SELECT TaTable.* FROM TaTable;" 'En choisissant la table désirée
    strRep = CurrentProject.Path
    Set rst = db.OpenRecordset(strSQL)
    While rst.EOF = False
        strDossier = "\" & rst("LeNomDuChampNom") & " " & rst("LeNomDuChampPrénom") 'Ici ce sont les deux champs qui contiennent les informations nom et prénom
        MkDir strRep & strDossier
        rst.MoveNext
    Wend
    rst.Close
    Set rst = Nothing
    Set db = Nothing
 
Exit Sub
GestionErreurs:
    Select Case Err.Number
        Case 75 'le dossier existe déjà
        Resume Next
    Case Else
        MsgBox "Erreur dans fuCopierFichier" & " " & Err.Number & " " & Err.Description
        Exit Sub
    End Select
End Sub

Bonne journée

[Zutalor]

Bnjr Robert.

Effectivement, cela marche beaucoup mieux.
Par contre, une dernière question : je souhaite enregistrer le document dans le chemin suivant :

Répertoire Courant (currrentProject.Path)/2014-2015/ESS/

Comment puis je créer au préalable ce dossier précis ? Car pour que ça fonctionne, il faut que je le crée manuellement. Je souhaiterais le créer en VBA, svp.

Merci bcp en tout cas.

[Robert1957]

Bonjour Zutalor,

Remplace la ligne 8 par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

strRep = CurrentProject.Path & "\2014-2015"

puis ajoute à la suite

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
MkDir strRep
strRep = strRep & "\ESS"
MkDir strRep

et finalement le reste du code.

Bonne journée

[Zutalor]

Faut vraiment être bête. La solution était si simple !
Ca fonctionne à merveille, sans erreur et bien plus rapidement.
Merci encore.
Excellente fin de soirée.