Calculer des périodes à partir de dates entrées

**bperrobar** · 27/02/2014, 16h33

Bonjour
J'essaie de simplifier au plus mon projet et de le rendre plus facile à l'utilisation future...
Du coup, je suis reparti sur d'autres bases concernant le calcul de Période/Semaine...
la table t_periode servira à renseigner les différentes dates : rentrée scolaire, date des vacances (avec habituellement début = vendredi soir et fin = lundi matin)...

la table t_jourt pour les jours travaillés...
~~J'aimerais ici que la colonne calcul_PS indique pour le jour rentré le code P#S#...~~
Désolé ! En fait il faudrait calculer le résultat dans 2 champs : champs "Periode" et champs "Semaine"

il faudrait qu'il y ait un calcul : de date à date,des périodes et des semaines pour chaque période : avec RAZ à chaque fois par ex. ~~P1S1 P1 S2 ... PS8 puis, P2S1.... P2S7 puis P3S1 à P3S9~~ etc.
Ex d'affichage dans 2 champs distinct : P1 ; S1 à P1 ; S8 (s'il y a 8 semaines dans la période) puis remise à zéro du compteur et ensuite P2 ; S1 etc...

J'espère être assez clair ?

Merci d'avance
calcul_ps.zip

**paidge** · 03/03/2014, 15h22

Bonjour,

Je ne suis pas sûr que tu sois au bon endroit mais je vais quand même te donner un bout de solution que j'ai trouvé pour toi grâce à cette fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
Public Function PeriodeSemaine(pDate As Variant) As String
    Dim rst As DAO.Recordset
    Dim strSQL As String
    Dim i As Integer
    Dim bytPeriode As Byte
    Dim intSemaine As Integer
    Dim boolVacances As Boolean
    Dim varDate As Date
 
    If IsNull(pDate) Then
        PeriodeSemaine = ""
        Exit Function
    End If
 
    ' Requête où l'on récupère l'année scolaire comprenant la date saisie
    strSQL = "SELECT [Date rentree], " & _
                    "[Debut toussaint], " & _
                    "[Fin toussaint], " & _
                    "[Debut Noël], " & _
                    "[Fin Noël], " & _
                    "[Debut hiver], " & _
                    "[Fin hiver], " & _
                    "[Debut printemps], " & _
                    "[Fin printemps], " & _
                    "[Debut ete] " & _
             "FROM t_periode " & _
             "WHERE [Date rentree]<=" & CDbl(pDate) & " AND [Debut ete]>=" & CDbl(pDate) & ";"
 
    Set rst = CurrentDb.OpenRecordset(strSQL)
    bytPeriode = 1
    boolVacances = True
 
    If Not rst.EOF Then
        ' La requête nous retourne une ligne
        For i = 1 To rst.Fields.Count
            If i Mod 2 = 0 Then
                'On est dans des petites vacances
            Else
                ' On est dans une période
                If rst(i - 1) <= pDate And pDate <= rst(i) Then
                    ' La date saisie est incluse dans la période
                    intSemaine = 1
                    varDate = rst(i - 1)
                    boolVacances = False
                    ' Pour chaque  semaine
                    Do While varDate <= rst(i)
                        If varDate <= pDate And pDate < varDate + 7 Then
                            ' La date saisie se trouve dans la semaine
                            Exit Do
                        Else
                            ' La date saisie ne se trouve pas dans la semaine
                        End If
                        intSemaine = intSemaine + 1
                        varDate = varDate + 7
                    Loop
                    Exit For
                Else
                    ' La date saisie n'est pas incluse dans la période
                End If
                bytPeriode = bytPeriode + 1
            End If
        Next i
 
        If Not boolVacances Then
            ' La date saisie correspond à une période
            PeriodeSemaine = "P" & CStr(bytPeriode) & "S" & CStr(intSemaine)
        Else
            ' La date saisie ne correspond pas à une période
            PeriodeSemaine = "La date saisie se trouve dans une période de petites vacances"
        End If
    Else
        ' La requête ne retourne rien
        PeriodeSemaine = "La date saisie se trouve dans une période non enregistrée ou pendant les grandes vacances"
    End If
    Set rst = Nothing
End Function