Discussion :

[marcoole]

Bonjour à tous,
J'ai un problème lors de la création de graphique via une macro.
J'ai au préalable créé une macro via l'enregistreur de macro. Lorsque je relance la macro via vba pour recréer le graphique, j'ai un message d'erreur (erreur d'execution 1004 sur la ligne de code en rouge ci-dessous).

C'est un erreur de syntaxe mais je n'arrive pas à trouver laquelle.

Merci d'avance pour vos réponses

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
ActiveSheet.Shapes.AddChart.Select
    ActiveChart.SetSourceData Source:=Range("Feuil1!$B$3:$M$3")
    ActiveChart.ChartType = xlColumnClustered
    ActiveChart.SeriesCollection(1).Delete
    ActiveChart.SeriesCollection.NewSeries
    ActiveChart.SeriesCollection(1).Values = _
        "=Feuil1!$B$3;Feuil1!$D$3;Feuil1!$F$3;Feuil1!$H$3;Feuil1!$J$3;Feuil1!$L$3"
    ActiveChart.SeriesCollection.NewSeries
    ActiveChart.SeriesCollection(2).Values = _
        "=Feuil1!$C$3;Feuil1!$E$3;Feuil1!$G$3;Feuil1!$I$3;Feuil1!$K$3;Feuil1!$M$3"

[titou31000]

Est-ce qu'il y a un message avec l'erreur d'exécution et le numéro?

[mercatog]

Remplace les points-virgules par des virgules.

Sinon pour une meilleure formalisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Test()
 
With ActiveSheet.ChartObjects.Add(100, 100, 500, 300).Chart
    .ChartType = xlColumnClustered
    .SeriesCollection.NewSeries.Values = "=Feuil1!$B$3,Feuil1!$D$3,Feuil1!$F$3,Feuil1!$H$3,Feuil1!$J$3,Feuil1!$L$3"
    .SeriesCollection.NewSeries.Values = "=Feuil1!$C$3,Feuil1!$E$3,Feuil1!$G$3,Feuil1!$I$3,Feuil1!$K$3,Feuil1!$M$3"
End With
End Sub

[Invité]

classe clsGraphe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Dim Shap As Shape
Enum style
    PieExploded = 69
    Pie = 5
    TroisDLine = -40101
    TrisDBarStacked100 = 62
End Enum
 
Public Sub Graphique_New(Feuille As Worksheet)
Set Shap = Feuille.Shapes.AddChart
End Sub
Public Sub Graphique_Source(Myrange As Range)
 Shap.Chart.SetSourceData Myrange
End Sub
Public Sub Graphique_Style(MyStyle As style)
 Shap.Chart.ChartType = MyStyle
End Sub
Public Sub Graphique_NewSeries(Myrange As Range)
 Shap.Chart.SeriesCollection.NewSeries.Values = Myrange
End Sub
Public Sub Graphique_NewSeries_String(Page As String)
 Shap.Chart.SeriesCollection.NewSeries.Values = Page
End Sub
Public Sub Graphique_SeriesCollection()
 
 Shap.Chart.SeriesCollection(1).ApplyDataLabels
End Sub
 
Public Sub Graphique_Taille(Hauteur As Integer, Largeur As Integer)
 Shap.Height = Hauteur
 Shap.Width = Largeur
End Sub
Public Sub Graphique_Position(X As Integer, Y As Integer)
 Shap.Top = X
 Shap.Left = Y
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub test()
 
Dim grph As New clsGraphe
grph.Graphique_New ActiveSheet
grph.Graphique_Source ActiveSheet.UsedRange
grph.Graphique_Style PieExploded
grph.Graphique_NewSeries ActiveSheet.Range("E1")
grph.Graphique_NewSeries_String "=Feuil1!$B$3,Feuil1!$D$3,Feuil1!$F$3,Feuil1!$H$3,Feuil1!$J$3,Feuil1!$L$3"
grph.Graphique_NewSeries_String "=Feuil1!$C$3,Feuil1!$E$3,Feuil1!$G$3,Feuil1!$I$3,Feuil1!$K$3,Feuil1!$M$3"
grph.Graphique_SeriesCollection
grph.Graphique_Taille 200, 300
grph.Graphique_Position 50, 100
End Sub

[marcoole]

Ca marche. merci beaucoup!