Discussion :

[TheTcha]

Bonjour,
J'ai access 2000 et je voudrais exporter une table de ma base access en fichier csv.
Déjà je n'arrive pas à trouver le format csv, je suis obligé de l'exporter en fichier texte.
J'ai un autre soucis, c'est le fait que quand j'exporte un fichier en format texte, il me garde que 2 virgules après la virgule.
Je voudrais garder l'ensemble des chiffres après la virgule.
Comment faire?
Merci d'avance

[TheTcha]

J'ai réussi à exporter en csv mais maintenant je voudrais récupérer l'ensemble des chiffres qui se trouvent derrière la virgule.
Comme fait on pour paramétrer ça?
Merci

[PipoWIL]

Oui en effet l'export texte avec des champs delimittés (csv) ne donne pas automatiquement les virgules et chiffres décimaux. L'export texte avec champs de longueur fixe les donne. MS Access prevoit de pouvoir enregistrer la paramétrisation de l'export (click sur Advanced...).

Pour ma part, je me méfie des settings Windows qui varient en fonctions des utilisateurs. Ils entrainent de la confusion entre la virgule ou le point décimal et donc entre la virgule ou le point-virgule entre les champs.

Si cela peut t'aider, voici un exemple de code VBA qui fera ton export

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Compare Database
Option Explicit
Function demo_CSV()
Dim db As DAO.Database
Dim rst As DAO.Recordset
 
Dim strLine As String
Dim iFileNbr As Integer
Dim strSQL As String
 
Set db = Application.CurrentDb
Set rst = db.OpenRecordset("Table1")
 
'The file is created as a text file because the Transfertext method relies on Windows locales and requires
'a transfer template to be saved locally
 
'prendre le premier numero de fichier libre
iFileNbr = FreeFile
 
'ouvrir le fichier
Open "C:\Temp\Test.csv" For Output As iFileNbr
'parcourir la table avec mes données
rst.MoveFirst
Do Until rst.EOF
    strLine = rst![Entier]
    'composer la ligne en séparant les champs par le caractère de mon choix
    strLine = strLine & ";" & rst![NombreDouble]
    strLine = strLine & ";" & rst![NombreDecimal]
    'De la Table1, j'exporte trois champs.  Le premier champ s'appelle 'Entier', le second 'NombreDouble' et le troisieme s'appelle 'NombreDecimal'
    'écrire la ligne sur le fichier texte
    Print #iFileNbr, strLine
    rst.MoveNext
Loop
 
'fermer le fichier
Close iFileNbr
 
'supprimer les pointeurs
Set rst = Nothing
Set db = Nothing
 
End Function