Discussion :

[number7]

Bonjour
Voici mon problème.

Lorce que je modifie le contenue d'une cellule de ma DataGridView, ca change de ligne après avoir appuyer sur ENTER.


J'ai regardé du coté de ses propriétés mais je n'ai rien trouver.
J'ai aussi essayé de sélectionner la cellule de droite à l'aide de l'évènement Grd_CellEndEdit, mais sans succès.

Comment puis-je empêcher ca?

Merci

[mactwist69]

Il faut détecter l'évènement KeyDown du DatagridView, et faire un teste sur la touche appuyée.

En fonction du résultat, tu feras ce que tu veux.

[sylverio]

il me semble même que ton datagridview à une fonction CellEnter

[number7]

J'ai déjà essayer KeyDown et CellEnter. Mais ca n'empeiche pas le changement de cellule automatique.

Autre chose à proposer?

[Kropernic]

Utiliser la touche Tab plutôt que la touche Enter pour passer à la cellule d'à côté ? (comme dans Excel en fait)

Ou tu veux juste valider la cellule sans passer à la suivante ?

[mactwist69]

J'ai déjà essayer KeyDown et CellEnter. Mais ca n'empeiche pas le changement de cellule automatique.

Autre chose à proposer?

Il aurait été plus utile de nous montrer le code qui "ne fonctionne pas".

Bon, j'ai fais un petit test, et ça ça marche (ca annule l'action du Enter, mais en soit, mon code ne fait rien d'autre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub DataGridView1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles DataGridView1.KeyDown
 
        If e.KeyCode = Keys.Enter Then
 
            e.Handled = True
 
        End If
 
End Sub

[chrismonoye]

Bonsoir,
la touche Tab est dédié pour passer à la cellule de droite, avec le DGV Windows Form.
Mais c'est pratique aussi d'avoir le Return, pour la même fonction, surtout avec le pavé numérique.
Une possibilité est la personnalisation de ce contrôle.
Ça foisonne sur le net, genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
    Public Class CustomDataGridView
 
        Inherits Windows.Forms.DataGridView
 
        Protected Overrides Function ProcessCmdKey(ByRef msg As Message, ByVal keyData As Keys) As Boolean
 
            If keyData = Keys.Enter Then
                Dim row As Integer = Me.CurrentCell.RowIndex, column As Integer = Me.CurrentCell.ColumnIndex
 
                column += 1
                If column = Me.ColumnCount Then
                    row += 1
                    If row = Me.Rows.Count Then
                        Dim dr As DataRowView = CType(Form1.bindingSource1.AddNew, DataRowView)
                    End If
                    column = 0
                End If
 
                Me.CurrentCell = Me.Rows(row).Cells(column)
 
                If Not Me.IsCurrentCellInEditMode Then
                    Return True
                End If
            End If
            Return MyBase.ProcessCmdKey(msg, keyData)
        End Function
 
    End Class

[chrismonoye]

Bonsoir,
Dans le cas où l'on veut garder son DGV WinForm standard, en bidouillant un peu, c'est possible aussi.
Pour le passage d'une cellule vers celle de droite, sans entrer en mode édition c'est facile, en s'inspirant du code du contrôle personnalisé ci dessus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
    Dim row As Integer
    Dim column As Integer
 
    Private Sub DataGridView1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles DataGridView1.KeyDown
 
        If e.KeyCode = Keys.Enter Then
            ' Lorsque l'on valide une cellule en mode NON édition, on passe à la cellule suivante sur la même ligne, 
            ' ou à la 1ère cellule de la ligne suivante si la cellule est la dernière de la ligne en cours.
            ' Avec création d'une nouvelle ligne si cette ligne est la dernière.
            row = DataGridView1.CurrentCell.RowIndex
            column = DataGridView1.CurrentCell.ColumnIndex
            column += 1
            If column = DataGridView1.ColumnCount Then
                row += 1
                If row = DataGridView1.Rows.Count Then
                    If row = DataGridView1.RowCount Then
                        If DataGridView1.DataSource IsNot Nothing Then
                            bindingSource1.AddNew()
                        Else
                            DataGridView1.Rows.Add()
                        End If
                    End If
                End If
                column = 0
            End If
 
            DataGridView1.CurrentCell = DataGridView1.Rows(row).Cells(column)
 
            ' Arrivant en fin de ligne, par defaut Enter crée une nouvelle ligne, mais vu qu'elle a déjà été
            ' créée par programmation, nous indiquons que l'événement a été géré.
            e.Handled = True
        End If
 
    End Sub

Mais si on entre dans une cellule pour y mettre une valeur (c'est quand même le but), le contrôle, en mode édition, passe à la cellule de dessous, ignorant l'événement KeyDown.
En y regardant de plus près, on constate que l'événement SelectionChanged est traité avant.
Il suffit donc de savoir si le DGV est en mode édition et d'agir sur SelectionChanged, en complétant le code ci dessus avec celui ci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
    Dim modeEdition As Boolean
 
    Private Sub DataGridView1_EditingControlShowing(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewEditingControlShowingEventArgs) Handles DataGridView1.EditingControlShowing
        modeEdition = True
    End Sub
 
    Private Sub DataGridView1_SelectionChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles DataGridView1.SelectionChanged
 
        If modeEdition = True Then
            row = DataGridView1.CurrentCell.RowIndex
            column = DataGridView1.CurrentCell.ColumnIndex
            column += 1
            If column = DataGridView1.ColumnCount Then
                row += 1
                column = 0
            End If
            DataGridView1.CurrentCell = DataGridView1.Rows(row - 1).Cells(column)
            modeEdition = False
        End If
 
    End Sub