Discussion :

[Bigasse]

Chers amis,
J'utilise ce Macro, édité sur excel 2007, pour ouvrir les graphiques.
Quelqu'un peut me dire, ce que je peux modifier pour l'utiliser sur excel 2003 ?
Merci
Bigasse

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Trend()
'
' Trend Macro
'
    Sheets("Value1").Select
    Set Plage = Application.InputBox("Select your range from line 9 to line 35. Exemple: B9:B35", "Sélection Range", Type:=8)
    Plage.Select
    Selection.Copy
    Sheets("Trends").Select
    Range("A9").Select
    ActiveSheet.Paste
'
    Range("A9:A35").Select
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.SetSourceData Source:=Range("Trends!$A$9:$A$35")
    ActiveChart.ChartType = xlLine
    ActiveChart.SeriesCollection(1).XValues = "='Value1'!$A$12:$A$35"
    ActiveChart.ChartArea.Copy
    Sheets("Value1").Select
    Range("H3").Select
    ActiveSheet.Paste
    ActiveWindow.SmallScroll Down:=-24
 
    Range("D1").Select
    Selection.ClearContents 
 
End Sub

[mercatog]

un exemple pour créer un graphique dans feuille Value1 en prenant en compte la plage sélectionnée par l'utilisateur
Tu remarque que je n'ai pas utilisé de select

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Trend()
Dim Plage As Range
Dim NbLig As Integer, Deb As Integer
Dim Graf As ChartObject
 
On Error Resume Next
Set Plage = Application.InputBox("Select your range from line 9 to line 35. Exemple: B9:B35", "Sélection Range", Type:=8)
NbLig = Plage.Rows.Count
On Error GoTo 0
If NbLig > 0 Then
    Deb = Plage.Cells(1).Row
    With Sheets("value1")
        Set Graf = .ChartObjects.Add(.Range("H3").Left, .Range("H3").Top, 400, 200)
        With Graf.Chart
            .SetSourceData Source:=Plage
            .ChartType = xlLine
            .SeriesCollection(1).XValues = Sheets("value1").Range("A" & Deb & ":A" & Deb + NbLig - 1)
        End With
    End With
    Set Graf = Nothing
    Set Plage = Nothing
End If
End Sub