Discussion :

[Cryos]

Bonjour à tous,

J'ai la problèmatique suivante : Je dois réaliser un script VBS pour rechercher dans le dossier courant et ses sous dossiers les raccourcis .lnk. Pour chacun je dois vérifier où se trouve le fichier sur lequel ils pointent et si nécessaire modifier le lien.
En somme on a déplacer énormément de fichier d'un serveur à l'autre et pour certains pc on aurait besoin de rediriger les liens.

Pour le moment j'ai fais le code suivant, j'arrive à explorer récursivement et à consulter les types des fichiers :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
 
Dim courant_Dir
courant_dir =  WScript.ScriptFullName 
courant_dir = left(courant_dir, InStrRev(courant_dir, "\"))
 
explore_dossier(courant_dir)
wscript.quit
 
 
 
 
Sub explore_dossier(Dir_path)
    Dim Dir
	Dim collection_Dir, courant_Dir
	Dim collection_Fichiers, courant_Fichier
	Dim oFso, WshShell, oShellLink
 
	Set oFso = CreateObject("Scripting.FileSystemObject")
	Set WshShell = WScript.CreateObject("WScript.Shell")
 
 
	msgbox Dir_path
	Set Dir = oFso.getFolder(Dir_path)
	Set collection_Dir = Dir.SubFolders
	Set collection_Fichiers = Dir.Files
 
 
	For each courant_Dir in collection_Dir
		explore_dossier(courant_Dir.Path)
	Next
 
	For each courant_Fichier in collection_Fichiers
		if (courant_fichier.type = "Raccourci") then  
			'Partie du code qui ne fonctionne pas
			'Je ne peux accéder aux attributs suivants...
			msgbox courant_fichier.type
			msgbox courant_fichier.TargetPath
			msgbox courant_fichier.WorkingDirectory
		end if
	Next
end Sub

Voilà mon souci, je n'arrive pas à accéder aux attributs des raccourcis. Les méthodes/attributs ne sont pas gérés. J'aimerais avoir un coup de pouce là dessus.
Sur internet j'ai trouvé de quoi créer mais pas modifier les raccourcis. Est-ce que je dois caster le "courant_fichier" ? Si oui comment ?

Bref merci d'avance pour vos réponses.

[EDIT] D'ailleurs je pourrais recréer tout simplement les raccourcis, mais avant cela j'aurais besoin de récupérer la valeur des attributs du premier raccourci... Donc le problème reste entier :S

[Cryos]

En fait problème résolu ^^
J'ai mal utiliser et mal compris comment on exploitait les raccourcis.

Donc je donne mon script (ça peut servir).
Script pour explorer recursivement le dossier, contenant le script, ses sous-dossiers et modifier les raccourcis pour ne plus pointer sur un "serveur1" mais sur le "serveur2".

Bien sur il fonctionne mais sous réserve ^^

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Option Explicit
CONST serveur1 = "Orion"
CONST serveur2 = "Venus"
 
 
Dim courant_Dir
courant_dir =  WScript.ScriptFullName 
courant_dir = left(courant_dir, InStrRev(courant_dir, "\"))
 
explore_dossier(courant_dir)
wscript.quit
 
 
 
 
Sub explore_dossier(Dir_path)
    Dim Dir
	Dim collection_Dir, courant_Dir
	Dim collection_Fichiers, courant_Fichier
	Dim oFso, WshShell, Shortcut
 
	Set oFso = CreateObject("Scripting.FileSystemObject")
	Set WshShell = WScript.CreateObject("WScript.Shell")
 
 
	msgbox Dir_path
	Set Dir = oFso.getFolder(Dir_path)
	Set collection_Dir = Dir.SubFolders
	Set collection_Fichiers = Dir.Files
 
 
	For each courant_Dir in collection_Dir
		explore_dossier(courant_Dir.Path)
	Next
 
	For each courant_Fichier in collection_Fichiers
		if (courant_fichier.type = "Raccourci") then 
		    msgbox courant_fichier.path
		    Set Shortcut = WshShell.CreateShortcut(courant_fichier.path)
			Shortcut.TargetPath = replace(Shortcut.TargetPath, Serveur1, Serveur2)
			Shortcut.WorkingDirectory = replace(Shortcut.WorkingDirectory, Serveur1, Serveur2)
 
			Shortcut.save			        
		end if
	Next
end Sub

[lucky3131]

Bonjour,

Je n'arrive pas à faire fonctionner ce code. Quelqun pour me conseiller ?

Merci