Discussion :

[blackbird67]

Bonjour à tous,

J'aurais voulu savoir comment donné des ailes à mon programme bien lent.

J'ai un tableau contenant mes points et je souhaite les dessiner afin de former une courbe. Pour cela je fais une boucle for et j'insère mes points dans un group que j'insère ensuite dans le content de ma scene.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
var graph_group:Group = Group{
translateX: 1
translateY: 1
};
 
var graph = new Polyline;
...
var x:Number=0
for (i in [0...15000] //j'ai beaucoup de point
{
      insert [x, 260-plot[i]] into graph.points;
      x+=0.2;
}

Existe t-il un moyen d'accéléré la chose car c'est vraiment lent environ 10sec... Je pensais faire une animation avec ça, à moi les saccades...Bon je sais c'est 15000 points mais quand même

[bouye]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
 
/*
 * To change this template, choose Tools | Templates
 * and open the template in the editor.
 */
package test;
 
import javafx.scene.Scene;
import javafx.scene.control.Button;
import javafx.stage.Stage;
import javafx.scene.Group;
import javafx.scene.shape.Polyline;
import javafx.util.Math;
import javafx.scene.paint.Color;
import javafx.scene.layout.HBox;
import java.lang.System;
 
def button1: Button = Button {
            text: "Old"
            action: function(): Void {
                def graph = Polyline {
                            stroke: Color.BLUE
                        };
                var x: Number = 0;
                def plot: Number[] = for (i in [0..15000]) {
                            Math.random() * 260;
                        }
                def timeA: Long = System.currentTimeMillis();
                //j'ai beaucoup de point
                for (i in [0..15000]) {
                    insert [x, 260.0 - plot[i]] into graph.points;
                    x += 0.2;
                }
                def timeB: Long = System.currentTimeMillis();
                println("Old: {timeB - timeA}ms");
                def graph_group: Group = Group {
                            translateX: 1
                            translateY: 1
                            content: graph
                        }
                insert graph_group into button1.scene.content;
            }
        }
def button2: Button = Button {
            text: "New"
            action: function(): Void {
                def graph = Polyline {
                            stroke: Color.RED
                        };
                var x: Number = 0;
                def plot: Number[] = for (i in [0..15000]) {
                            Math.random() * 260;
                        }
 
                def timeA: Long = System.currentTimeMillis();
                //j'ai beaucoup de point
                graph.points = for (i in [0..15000]) {
                            def seq: Number[] = [x, 260.0 - plot[i]];
                            x += 0.2;
                            seq;
                        }
                def timeB: Long = System.currentTimeMillis();
                println("New: {timeB - timeA}ms");
                def graph_group: Group = Group {
                            translateX: 1
                            translateY: 1
                            content: graph
                        }
                insert graph_group into button1.scene.content;
            }
        }
 
Stage {
    width: 1600
    height: 500
    scene: Scene {
        content: [
            HBox {
                spacing: 5
                content: [
                    button1,
                    button2
                ]
            }
        ]
    }
}

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
New: 6ms
Old: 16ms
New: 2ms
Old: 6ms
New: 1ms
Old: 6ms
New: 3ms
Old: 7ms
New: 3ms
Old: 6ms
Old: 6ms
New: 1ms
New: 2ms
New: 3ms
New: 2ms
New: 1ms
Old: 6ms
Old: 6ms
Old: 6ms
Old: 6ms
Old: 7ms

Faut se souvenir qu'avec insert into on créée une nouvelle séquence graph.points à chaque itération de la boucle.

Par contre y a pas de miracles, dès qu'il y a trop de courbes affichées ça rame.

Pis faut surtout pas activer Prism car alors c'est la catastrophe, le programme ne peut même pas afficher une seule courbe...

[blackbird67]

ok merci pour tes conseils ! ça à l'air drôlement plus rapide d'un seul coup

edit : 10sec => 1 sec !!! MERCI