Discussion :

[WDKyle]

Bonsoir à tous !

J'aimerais réaliser des pauses pendant un affichage de splashscreen, j'utilise donc la fonction Sleep comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
System.Threading.Thread.Sleep(1000)
        Label_Chargement.Text = "Recherche clé dongle ..."
        System.Threading.Thread.Sleep(2000)
        Label_Chargement.Text = "Lancement ..."

Le souci est que lorsque je lance le debug, je ressent les pauses car le form ne s'affiche pas et après quelques secondes j'ai mon form avec d'affiché dans Label_Chargement : "Lancement ..." . En gros, il fais les pauses avant et après il m'ouvre le form avec la dernière commande ...

Avez-vous eu ce soucis ? Ou est-ce que je procède mal ?

Merci de votre aide s'il vous plait !

[Pol63]

le thread principal sert à l'affichage, quand celui ci est surchargé de travail ou est en pause, l'interface ne se rafraichit pas et windows affiche "Ne répond pas"

pour les traitement long (> 1 seconde) il faut alors les mettre dans un thread séparé
pour les pauses comme tu veux faire il faut procéder autrement (un timer et une variable d'étape par exemple)

[WDKyle]

J'ai essayé dans un timer, même résultat

[WDKyle]

Alors j'ai essayé avec un Thread, ca a l'air de marché mais il renvoi une erreur celle ci :

Opération inter-threads non valide : le contrôle 'Label_Chargement' a fait l'objet d'un accès à partir d'un thread autre que celui sur lequel il a été créé.

sur cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Label_Chargement.Text = "Recherche clé dongle ..."

Je ne peux pas utiliser mon Label ? :s

[Sankasssss]

Regarde ce post tu auras ta réponse

[Graffito]

C'est pas vraiment la solution la plus propre, mais tu peux essayer Application.DoEvents() avant le Sleep().

[WDKyle]

J'ai essayé ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
    Private Thread_Boot As Thread
 
    Private Sub ThrFunc1()
        If Label_Chargement.InvokeRequired Then
            Label_Chargement.Invoke(AddressOf FonctionLabelChange)
        Else
            FonctionLabelChange()
        End If
 
    End Sub
 
    Private Sub FonctionLabelChange()
        System.Threading.Thread.Sleep(1000)
        Label_Chargement.Text = "Recherche clé dongle ..."
        System.Threading.Thread.Sleep(2000)
        Label_Chargement.Text = "Lancement ..."
        System.Threading.Thread.Sleep(1000)
        Form1.Show()
    End Sub
 
    Private Sub StartThread()
        Thread_Boot = New Thread(AddressOf ThrFunc1) 'ThrFunc est la fonction exécutée par le thread.
        Thread_Boot.Name = "Thread1" 'Il est parfois pratique de nommer les threads surtout si on en créé plusieurs.
        Thread_Boot.Start() ' Démarrage du thread.
    End Sub
 
    Private Sub Boot_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        StartThread()
    End Sub

Mais j'ai une erreur sur AddressOf :

L'expression 'AddressOf' ne peut pas être convertie en 'System.Delegate', car le type 'System.Delegate' est déclaré 'MustInherit' et ne peut pas être créé.

[cougarg]

Bonjour,
Le paramètre de Invoke doit être un delegate

[KooKiz]

Les BackgroundWorker servent à ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Imports System.ComponentModel
Imports System.Threading
 
Public Class Form1
 
    Protected BackgroundWorker As BackgroundWorker
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Me.BackgroundWorker = New BackgroundWorker()
 
        Me.BackgroundWorker.WorkerReportsProgress = True
 
        AddHandler Me.BackgroundWorker.DoWork, AddressOf Worker_DoWork
        AddHandler Me.BackgroundWorker.ProgressChanged, AddressOf Worker_ProgressChanged
 
        Me.BackgroundWorker.RunWorkerAsync()
 
    End Sub
 
    Private Sub Worker_ProgressChanged(ByVal sender As Object, ByVal e As ProgressChangedEventArgs)
        Dim message As String = e.UserState
 
        Me.Label1.Text &= message & Environment.NewLine
 
    End Sub
 
    Private Sub Worker_DoWork(ByVal sender As Object, ByVal e As DoWorkEventArgs)
        Dim worker As BackgroundWorker = sender
 
        worker.ReportProgress(0, "Starting...")
 
        Thread.Sleep(1000)
 
        worker.ReportProgress(0, "Première étape")
 
        Thread.Sleep(3000)
 
        worker.ReportProgress(0, "Deuxième étape")
 
        Thread.Sleep(2000)
 
        worker.ReportProgress(100, "Terminé")
    End Sub
 
 
End Class