Configuration de l'installation de SAS : Changer nom de machine

**Deciprog** · 14/12/2009, 15h44

Lors de la configuration de l'installation de SAS, j'ai indiqué pour les noms d'hôtes l'ip de ma machine au lieu du nom de ma machine.

J'ai changé ip de ma machine.
Comment faire pour répercuter ce changement dans SAS sans le réinstaller.

Merci d'avance

**Manoutz** · 14/12/2009, 16h15

Je sais pas si ca aidera, mais tu peux peut ête partir de ca:

http://www.devenezia.com/downloads/sas/samples/

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
/*
 * Richard A. DeVenezia
 * Obtain IP address of host
 *
 * Tested platforms:
 * Windows NT 4 and SAS v6.12/v8.1
 *
 * Adapted from:
 * VBnet - Randy Birch, MSKB, http://www.mvps.org/vbnet/code/network/ipaddress.htm
 */
 
filename sascbtbl catalog 'WORK.WINAPI.IPADDR.SOURCE';
 
data _null_;
  file sascbtbl ;
  infile cards length=len;
  length line $200;
  input line $varying. len;
  put line;
cards4;
ROUTINE
  WSAStartup
  MODULE=WSOCK32
  MINARG=8
  MAXARG=8
  STACKPOP=CALLED
  RETURNS=LONG
;
arg 1 NUM INPUT  BYVALUE FORMAT=PIB4. ; * long wVersionRequired ;
arg 2 NUM UPDATE FDSTART FORMAT=IB2.  ; * int wVersion - lpWSADATA ;
arg 3 NUM UPDATE         FORMAT=IB2.  ; * int wHighVersion ;
arg 4 NUM UPDATE         FORMAT=PIB1. ; * byte szDescription (0 To MAX_WSADescription=256) ;
arg 5 NUM UPDATE         FORMAT=PIB1. ; * byte szSystemStatus(0 To MAX_WSASYSStatus=128) ;
arg 6 NUM UPDATE         FORMAT=IB2.  ; * int wMaxSockets ;
arg 7 NUM UPDATE         FORMAT=IB2.  ; * int wMaxUDPDG ;
arg 8 NUM UPDATE         FORMAT=PIB4. ; * long dwVendorInfo ;
 
ROUTINE
  WSACleanup
  MODULE=WSOCK32
  MINARG=0
  MAXARG=0
  STACKPOP=CALLED
  RETURNS=LONG
;
 
ROUTINE
  gethostname
  MODULE=WSOCK32
  MINARG=2
  MAXARG=2
  STACKPOP=CALLED
  RETURNS=LONG
;
arg 1 CHAR         UPDATE FORMAT=$CSTR200. ; * szHost ;
arg 2 NUM  BYVALUE UPDATE FORMAT=PIB4.  ; * long dwHostLen;
 
ROUTINE
  gethostbyname
  MODULE=WSOCK32
  MINARG=1
  MAXARG=1
  STACKPOP=CALLED
  RETURNS=LONG
;
arg 1 CHAR INPUT FORMAT=$CSTR200. ; * szHost ;
 
;;;;
run;
 
%* WS_VERSION_REQD = 0101x ;
 
%let hostname = UNKNOWN;
%let ipaddr = UNKNOWN;
 
data _null_;
  retain v1-v7 0;
  rc = moduleN ('WSAStartup', 0101x, v1, v2, v3, v4, v5, v6, v7);
  if rc ^= 0 then do;
    put "WSAStartup failed";
    stop;
  end;
 
  if v5 < 1 then do;
    put "SystemStatus < 1";
    stop;   %* require one socket to get ip addr;
  end;
 
  major = BAND (v1, 000FFx);
  minor = BAND (v1, 0FF00x) / 0100x;
 
  if major < 1 or (major=1 and minor<1) then do;
    put "WSA version insufficient";
    goto CleanUp;
  end;
 
  length hostname $200;
  hostname = '';
 
  rc = moduleN ('gethostname', hostname, 200);
  if rc = -1 then do;
    put 'Unable to gethostname';
    goto CleanUp;
  end;
 
  lpHost = moduleN ('gethostbyname', hostname);
  hLen  = peek (lpHost+10, 2);
  hAddr = peek (lpHost+12, 4);
  lAddr = peek (hAddr);
 
  length ipAddr $20;
  ipAddr = ''; dot='';
  do i = 0 to hLen-1;
    ipAddr = trim(ipAddr) || trim(dot) || put (peek (lAddr+i,1), 3.) ;
    dot='.';
  end;
 
  call symput ('HOSTNAME', trim(hostname));
  call symput ('IPADDR', compress(ipAddr));
 
CleanUp:
  rc = moduleN ('WSACleanup');
 
stop;
 
run;
 
%put HOST &HOSTNAME HAS IP ADDRESS &IPADDR;

**datametric** · 15/12/2009, 11h23

La recommendation est de rejouer l'installation car ce n'est pas triviale.

EN 9.2 (mais plus tard) une interface sera mise à dispo pour cela.

Si tu y tiens, tu dois chercher dans les fichiers ET les métadonnées pour effectuer le remplacement.

Je ne garantis pas le résultat (ie. t'es tout seul dans ces moments.. plus d'amis.. plus rien

)