Discussion :

[lilly74]

Bonjour,
Je n'arrive pas à récupérer la dernière macro-variable créée
(je ne connais pas a priori la taille du tableau)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
data _NULL_ ;
		set Projet.&nomAction;
		call symput('N',_N_) ;
	run;
%put &&date&N..;

Si j'écrit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 %put &date1

c'est ok, mais pour la macro-variable de fin, je dois avoir un problème de syntaxe
J'y ai passé un certain temps , quelqu'un pourrait-il me donner un coup de pouce, svp?

[RemiBousquet]

Ca ne marche pas à cause des blancs qui sont enregistrés devant ton nombre &N.
C'est un problème lié au call symput.
Au par avant, il était courant de faire call symput ("N", left(trim(_N_))) pour enlever ces blancs.
Depuis la V9.1, il y a call symputX qui permet de mieux gérer ce cas de figure.
Demonstration par le code sas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
option nonotes nosource ;
data test ;
    format date yymmdd10. ;
    do date = "21nov1976"d to "24dec1976"d ; output ; end ;
run ;
 
DATA _NULL_ ;
		SET test ;
        CALL SYMPUT (COMPRESS("date"||_N_),put(date, ddmmyy10.)) ;  
		call SYMPUT ('N'                  ,_N_                 ) ;
		call SYMPUTx('Nx'                 ,_N_                 ) ;
run;
%put Avec call symput , _N_  = _&N._ , %nrstr(date&N) = date&N. --> Il y aura une erreur :(;
%put Avec call symputX, _NX_ = _&NX._, %nrstr(date&Nx) = date&Nx. --> Fonctionnera bien :) ;
%put &&date&Nx..;

[lilly74]

Ca ne marche pas à cause des blancs qui sont enregistrés devant ton nombre &N.
C'est un problème lié au call symput.
Au par avant, il était courant de faire call symput ("N", left(trim(_N_))) pour enlever ces blancs.
Depuis la V9.1, il y a call symputX qui permet de mieux gérer ce cas de figure.
Demonstration par le code sas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
option nonotes nosource ;
data test ;
    format date yymmdd10. ;
    do date = "21nov1976"d to "24dec1976"d ; output ; end ;
run ;
 
DATA _NULL_ ;
		SET test ;
        CALL SYMPUT (COMPRESS("date"||_N_),put(date, ddmmyy10.)) ;  
		call SYMPUT ('N'                  ,_N_                 ) ;
		call SYMPUTx('Nx'                 ,_N_                 ) ;
run;
%put Avec call symput , _N_  = _&N._ , %nrstr(date&N) = date&N. --> Il y aura une erreur :(;
%put Avec call symputX, _NX_ = _&NX._, %nrstr(date&Nx) = date&Nx. --> Fonctionnera bien :) ;
%put &&date&Nx..;

Merci
Je ne connaissais pas call symputx!
Si tu as encore quelques minutes, pourrais-tu m'expliquer, stp, quels sont les blancs enregistrés davant &N?
Apparemment, j'utilise call symput sans avoir très bien compris comment cela fonctionne...

[RemiBousquet]

Je pense que call symput crée une macro variable qui contient par défaut 12 caractères et renseigne la valeur "à droite".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
option nonotes nosource ; 
data _NULL_ ;
    x = 123456789012 ;    
    y = 1 ;
    call symput("test1",x);
    call symput("test2",y);
run ;
%put *|---(12)---|* ;
%put *&test1.* ;
%put *&test2.* ;

Call symputx et call symput sont bien décrits dans ce doc :
http://support.sas.com/techsup/technote/ts739.pdf

[lilly74]

Merci pour ce bon exemple et pour la doc
Je vais m'y plonger de ce pas