Discussion :

[alphons77]

Bonjour,

J'ai un fichier texte de 10000 lignes que je dois mettre sur 5000 lignes, les 5000 lignes de fin de fichier doivent venir à coté des 5000 premières lignes...
C'est une sorte de concaténation mais en ligne...
Grosso-modo et pour mieux me faire comprendre, ma "structure" de fichier d'origine et de 28 caractères, au final elle sera de 58 caractères.
Le but du jeux bien sur c'est de pouvoir faire la manip en une seule fois et non pas ligne par ligne car ça pourrait être fastidieux (!!!...)
Merci si tu connais bien Notepad++ de me donner la façon de faire cette manip; dommage aussi que tous les menus ne soient pas disponible en français... jamais content celui-là, déjà que c'est un logiciel gratos...

A+

Alphons

Configuration: Windows XP
Firefox 3.5.2

[Mac LAK]

Et pourquoi ne pas tout simplement le faire via un fichier BATCH, ta copie ?

Si j'ai bien compris, tu veux un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Ligne 1
Ligne 2
...
Ligne 4998
Ligne 4999
Ligne 5000
Ligne 5001
....
Ligne 9999
Ligne 10000

qui deviendrait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Ligne 1     Ligne 5000 
Ligne 2     Ligne 5001 
...         ....       
Ligne 4998  Ligne 9999 
Ligne 4999  Ligne 10000

C'est bien ça ?

[alphons77]

Sympa si t'as une méthode même avec un batch; je pensais, en découvrant NOTEPAD++ qu'il pouvait y avoir une fonction qui fasse cette manip facilement.

Merci pour ton aide.

Alphons

[Mac LAK]

Je sais qu'avec UltraEdit, c'est très facile grâce à ses scripts intégrés, ou même à la main avec le mode colonne, mais c'est tout aussi possible en batch. Pour Notepad++, d'après la doc, c'est possible aussi.

Après, en batch, ça donne ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
@echo off
setlocal enableextensions enabledelayedexpansion

if "%1"=="" goto help

REM Compter le nombre de lignes avant tout.
echo Analyzing "%1"...
set nblines=0
for /F "delims=" %%I in ('type "%1"') do set /a nblines+=1
REM On divise par deux.
set /a line=%nblines% / 2
echo Done: input file has %nblines% lines, will cut at line %line%.

REM Découpage du fichier en deux parties.
type NUL> "%1.part1"
REM Première partie.
echo Extracting first part...
set current=0
for /F "delims=" %%I in ('type "%1"') do (
	set /a current+=1
	if !current! LEQ %line% (
		echo %%I>> "%1.part1"
	) else (
		REM Arrêt de la boucle, pour ne pas sortir les lignes suivantes.
		goto :break1
	)
)
:break1
echo Done.
echo Extracting second part...
REM Deuxième partie : parcours du fichier d'origine, en sautant "line" lignes.
REM Sauf que là, on fait un fichier par ligne à cause des problèmes de parcours double.
set current=0
for /F "skip=%line% delims=" %%I in ('type "%1"') do (
	set /a current+=1
	REM Sortie de la ligne.
	echo %%I> "%1.part2.!current!"
)
echo Done.

REM Fusion des deux parties.
echo Joining the two parts...
set current=0
type NUL> "%1.joined"
rem echo on
for /F "delims=" %%I in ('type "%1.part1"') do (
	set /a current+=1
	for /F "delims=" %%J in ('type "%1.part2.!current!"') do (
		REM Attention : 5 tabulations entre les deux variables !
		REM On pourrait aussi ajouter un pattern reconnaissable.
		echo %%I					%%J>> "%1.joined"
	)
)
REM Suppression des fichiers temporaires.
del /Q "%1.part1" > NUL 2>&1
del /Q "%1.part2.*" > NUL 2>&1
goto :eof

:help
echo Syntax : %0 ^<File^>
echo Will cut the file in two parts, and set the 2nd part as a 2nd column.
echo The resulting file will be named "<File>.joined".
goto :eof

C'est pas forcément optimal : c'est un poil long, mais ça marche partout. On pourrait aller beaucoup plus vite avec des outils externes mais cela demanderait alors de les installer.

[yodaime]

Normalement en sélectionnant tes 5000 dernières lignes avec ALT+Click et en venant les copier a la fin de la première ligne ca devrait marcher.