Discussion :

[xilay]

Bonjour,

J'ai besoin de modifier une macro sas, sachant que je ne connais presque rien à sas.
Bref, j'importe le contenu d'un fichier dans une table sas, dont une colonne au format alpha sous le schéma "JJ/MM/AAAA HH:MM".

J'ai besoin de faire ensuite une extraction sur une période donnée.
J'ai donc créé une nouvelle donnée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

periode=INPUT(substr(dateX,1,10), DDMMYY10.);

lors de l'intégration de mon fichier.
Puis j'ai voulu créer une nouvelle table SAS avec comme tri :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
%let periodedeb = INPUT(compress('01'||'/'||&MOISDEB||'/'||&ANDEB), DDMMYY10.);
%let periodefin = INPUT(compress('01'||'/'||&MOISFIN||'/'||&ANFIN), DDMMYY10.);
 
data extract;
    set fullextract (where=(periode BETWEEN &periodedeb AND &periodefin)) ;
run;

sachant que moisdeb etc sont les paramètres de la macro.

Mais j'ai beau tout essayer, tracer, etc, ça ne fonctionne pas, j'ai droit à "ERREUR: L'opérateur de la clause where requiert des variables alphan."
J'ai tout essayé, en passant par un format date, alpha, bref, je suis complètement perdu.

[Bruno.Thevenin]

Bonjour,

Lors de l'import du fichier, il suffit de préciser l'informat de la donnée (comment la lire) à SAS du style

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

periode=INPUT(dateX,DATETIME.);

Cet informat permet à SAS de traduire la donnée lue en nombre de secondes écoulées depuis le premier janvier 1960 à zéro heure.

Pour extraire la partie date de l'objet date-time :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ladate=DATEPART(periode);

Pour exprimer à SAS un date-time (qu'il traduit donc en un nombre de secondes etc...):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
"06APR2009:00:00:00"DT /* Objet DateTime */
"06APR2009"D  /* Objet Date exprimée en nb de jours écoulés depuis 01/01/1960*/

Le jour sur deux caractères, le mois sur trois caractères (mois en anglais!), l'année sur 4 caractères, les heures, les minutes et les secondes sur 2 caractères le tout entre quotes et suivi de DT (pour DATETIME!).

On peut alors faire de beaux tests dans de beaux macro-programmes sans "bricoler" les données...

Bon courage !

[olivier.decourt]

Bonjour.
Ton code n'est pas loin du compte, mais il faut comprendre que le compilateur macro, par défaut, ne fait aucun calcul, juste du copier/coller. Donc la formule que tu donnes après ton %LET ... = ne sera pas évaluée, juste mise en mémoire (les &macro-variables seront juste remplacées par leurs valeurs) et injectées ensuite dans le WHERE.
Tu pourrais donc directement écrire tes INPUT dans le WHERE :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
DATA extract;
    SET fullextract (WHERE=(periode BETWEEN INPUT(compress('01'||'/'||"&MOISDEB"||'/'||"&ANDEB"), DDMMYY10.)
                                                 AND INPUT(compress('01'||'/'||"&MOISFIN"||'/'||"&ANFIN"), DDMMYY10.))) ;
run;

Il fallait juste rajouter des "..." autour des &MOISDEB et compagnie, pour que SAS voie juste du texte à concaténer avec le reste. Par contre, pas de '&MOISDEB' parce que les guillemets simples interdisent le remplacement des macro-variables par leur valeur.
Pour alléger un peu le code, je te proposerais d'utiliser la fonction MDY, qui prend comme arguments le mois, le jour, l'année (tous numériques) et renvoie une date SAS. Ca évitera les concaténations et les INPUT et les guillemets.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
DATA extract;
    SET fullextract (WHERE=(periode BETWEEN MDY(&MOISDEB, 1, &ANDEB)
                                                 AND MDY(&MOISFIN, 1, &ANFIN))) ;
run;

Bon courage.
Olivier

[xilay]

Merci de votre aide.
Effectivement, je ne maitrise pas vraiment le principe des variables et du formatage de SAS, mais ça va venir.