Discussion :

[r0t0r]

Bonjour à tous,

J'aimerais avec une label (lbl_deplace) déplacer un formulaire. J'ai essayer la fonction MouseMove, mais cela fait un bug. 4 image du formulaire s'affichent.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
Private Sub lbl_deplace_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)    
    If Button = 1 Then
    index.Left = X
    index.Top = Y
    End If
End Sub

Merçi à tous d'avance

[ucfoutu]

Bonjour,

que veux-tu finalement déplacer ?
Le Label ou la Form qui le contient, ou les deux ?
Et que représente index dans ton code ?

[r0t0r]

En fait je veux rediriger avec le label le formulaire (Index).
Dés que je clique sur le label.

[ucfoutu]

En fait je veux rediriger avec le label le formulaire (Index).
Dés que je clique sur le label.

1) Ta Form a pour nom Index ?
Pas vraiment une bonne idée.. tu devrais lui trouver un autre nom (index a une signification précise sous VB)
2) pourquoi n'utilises-ru pas tout simplement la barre de menu de ta Form (qui inclut précisément le déplacement dans son menu système) ?
Si tu ne l'affiches pas, évidemment, c'est autre chose et on veillera à te guider dans ton mécanisme... (si vraiment nécessaire...)

[r0t0r]

En fait je trouvais cela plus beau en cachant la barre de menu d'origine de windows.

Je vais corriger l'erreur pour le formulaire. Je l'appelerais "formulaire".

[ucfoutu]

Tiens...

Inspire-toi de cet exemple simple et bâclé...
ici, on utilise l'évènement Mouse_move de la form elle-même ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Option Explicit
Private Declare Function SetCursorPos Lib "user32" (ByVal X As Long, ByVal Y As Long) As Long
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  If Button <> 1 Then Exit Sub
  Dim toto As Integer
  toto = Me.ScaleMode
  Me.ScaleMode = vbTwips
  DoEvents
  If Me.Top + Y <= 0 Then Exit Sub
  If Me.Left + X <= 0 Then Exit Sub
  If Me.Left + X + Me.Width >= Screen.Width Then Exit Sub
  If Me.Top + Y + Me.Height >= Screen.Height Then Exit Sub
  Me.Move Me.Left + X, Me.Top + Y
  SetCursorPos ScaleX(Me.Left, ScaleMode, vbPixels), ScaleY(Me.Top, ScaleMode, vbPixels)
  Me.ScaleMode = toto
End Sub
 
Private Sub aie()
  SetCursorPos ScaleX(Me.Left, ScaleMode, vbPixels), ScaleY(Me.Top, ScaleMode, vbPixels)
End Sub

[zazaraignée]

Bonjour à tous,

J'aimerais avec une label (lbl_deplace) déplacer un formulaire. J'ai essayer la fonction MouseMove, mais cela fait un bug. 4 image du formulaire s'affichent.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
Private Sub lbl_deplace_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)    
    If Button = 1 Then
    index.Left = X
    index.Top = Y
    End If
End Sub

Merçi à tous d'avance

En fait je veux rediriger avec le label le formulaire (Index).
Dés que je clique sur le label.

Déplacer? Rediriger? Si tu veux que l'on comprenne la question, il faudrait être soit constant, soit plus précis dans tes explications.

S'il s'agit de déplacer une fenêtre via la souris, la barre de titre de celle-ci contient déjà cette fonctionnalité. Ceci dit, si la barre d'état n'est plus affichée (BorderStyle = None), les coordonnées X et Y peuvent être utiles si tu as le point de départ et un quelconque point lors du déplacement, généralement la position de la souris, pour effectuer le calcul.

Voici un petit exemple. Une form dont les propriétés son ajustées ainsi:

• AutoRedraw : True
• BorderStyle : 0 - None

Et qui contient les composants suivants
Un Frame: (tout les autres composants sont placés dans ce Frame - arbitrairement et uniquement pour des raisons esthétiques)

• Caption : "" (vide)

Un Label

• Left, Top, Width et Height :
  de façon à occuper un max de la largeur dans le haut du Frame
• BackColor : Hilight
• Caption : "Déplace moi!"
• ForeColor : HilightText

2 labels pour afficher les titres de champs de coordonnées (X et Y)
2 labels pour afficher les coordonnées X et Y, nommés respectivement lblX et lblY

• BorderStyle : 1 - Fixed Single
• Caption : "" (vide)

Un bouton de commande

• Name : cmdFermer
• Caption : "&Fermer la fenêtre"

Code de l'exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
Private rX As Single, rY As Single ' réels
 
Private Sub Form_Load()
    lblX.Caption = Me.Left
    lblY.Caption = Me.Top
End Sub
 
Private Sub Label1_MouseDown(Button As Integer, Shift As Integer, _
                             X As Single, Y As Single)
    If Button = vbLeftButton And Shift = 0 Then
        rX = X
        rY = Y
    End If
End Sub
 
Private Sub Label1_MouseMove(Button As Integer, Shift As Integer, _
                             X As Single, Y As Single)
    If Button = vbLeftButton And Shift = 0 Then
        Me.Left = Me.Left + (X - rX)
        Me.Top = Me.Top + (Y - rY)
        lblX.Caption = Me.Left
        lblY.Caption = Me.Top
    End If
End Sub
 
Private Sub cmdFermer_Click()
    End
End Sub

Vue de la fenêtre obtenue en pièce jointe.

[r0t0r]

Merçi à zazaraignée et ucfoutu pour leurs aide précieuse