Discussion :

[Mobius]

Bonjour,

Je voudrais savoir si il est possible de fusionner des balises XML à l'aide d'une transformation XSL.
Pour illustrer ma demande, voici un exemple

J'ai quelque chose de ce genre :

Code XML source :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
<root>
    <foo name="1">
        <bar value="test11"/>
    </foo>
    <foo name="1">
        <bar value="test12"/>
    </foo>
    <foo name="2">
        <bar value="test21"/>
    </foo>
    <foo name="2">
        <bar value="test22"/>
    </foo>
</root>

pour obtenir ceci :

Code XML cible :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
<root>
    <foo name="1">
        <bar value="test11"/>
        <bar value="test12"/>
    </foo>
    <foo name="2">
        <bar value="test21"/>
        <bar value="test22"/>
    </foo>
</root>

Merci pour vos idée

[laurentibus]

les valeurs de l'attribut name de la balise foo sont finies ?

[Mobius]

les valeurs de l'attribut name de la balise foo sont finies ?

non

Edit: Autre info : les balises foo ne sont pas ordonées. En fait, le code XML source resemble plus a ceci :

Code XML source :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
<root>
    <foo name="1">
        <bar value="test11"/>
    </foo>
    <foo name="2">
        <bar value="test21"/>
    </foo>
    <foo name="1">
        <bar value="test12"/>
    </foo>
    <foo name="2">
        <bar value="test22"/>
    </foo>
</root>

Derniere chose. Dans mon cas, les balises qui ont le meme attribut name vont toujours par 2. Par contre, j'aurai aimé une solution assez générique si cela est possible.

[laurentibus]

ok as tu vu la Faq ???
ca regroupe selon le nom de balise, mais je pense qu on peux arriver a regrouper selon la valeur d'un attribut .... en ne modifiant pas grand chose ..

tiens nous au jus

[Mobius]

J'ai enfin trouvé.
Je dois bien avouer que la FAQ m'a bien aidé même si au départ j'ai pensé que la solution proposé été éloigner de ce que je voulais.

En me creusant la tête, voici la solution que j'ai trouvé (peut être a rajouter a la FAQ a coté de l'autre solution)

Code XSL :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
   <xsl:key name="regrouper" match="foo" use="@name"/>
   <xsl:template match="root">
      <root>
         <xsl:apply-templates select="foo[generate-id(.)=generate-id(key('regrouper',@name)[1])]"/>
      </root>
   </xsl:template>
   <xsl:template match="foo">
      <foo name="{@name}">
         <xsl:apply-templates select="//bar[../@name=current()/@name]"/>
      </foo>
   </xsl:template>
   <xsl:template match="bar">
      <xsl:copy-of select="."/>
   </xsl:template>
</xsl:stylesheet>

Pour finir : Merci laurentibus pour ton aide