Discussion :

[wizou44]

Bonjour,

Actuellement en stage de fin d'étude en data management, je dois créer un macro programme permettant de concaténer des variables(enfin ya d'autres trucs, mais c'est cet endroit qui me bloque). J'avais donc créer des programmes tels que celui ci-dessous. Mais le problème c'est que selon le nombre de variable (non constant) à concaténer, il faut créer d'autres macro programmes (qui possèdent un nombre d'appels de variables différent). Hors mes supérieurs veulent un seul macro programme (ce qui est compréhensible)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
%macro essai4 ( var, var1, var2, var3);
data Essai;
SET Batch2.Essai;
a4 = catx('/',&var,&var1,&var2,&var3) ;
RUN;
%mend;

J'ai donc penser à stocker les variables dans une seule macro variable. Mais du coup je ne vois pas comment concaténé les variables contenues dans une seule macro-variable.

Merci d'avance

wizou44

[olivier.decourt]

Un seul paramètre au macro-programme, qui contiendrait la liste des variables séparées par des espaces, me semble une bonne solution.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
%macro essai4 (variables);
%LET variables = %SYSFUNC(COMPBL(&variables)) ; /* supprime les blancs inutiles */
%LET variables = %SYSFUNC(TRANSLATE(&variables,%STR(,),%STR( ))) ; /* remplace les blancs par des virgules */
DATA Essai;
SET sashelp.class;
a4 = catx('/', &variables) ;
RUN;
%mend;
%essai4(name age sex)

Olivier

[wizou44]

Merci, pour ta réponse clair et rapide.

J'avais imaginer plein de trucs mais aucun ne marchait, mais bon je suis encore en stage pour trois mois, j'ai un peu de temps pour acquérir encore un peu d'expérience

wizou44

[fafabzh6]

Bonjour,
Une autre solution du même style est l'utilisation de PARMBUFF :
Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
%MACRO test/PARMBUFF;
....
%MEND;

Avec une exécution :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%test(v1,v2,v3,v4);

[wizou44]

bonjour fafabzh6

Pourrais-tu m'expliquer en quoi consiste l'option PARMBUFF, je n'en ai jamais entendu parler.

merci

[olivier.decourt]

Dans un style plus inhabituel, et réservé à ce genre de cas avec des nombres de paramètres variables, il y a l'option PARMBUFF.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
%macro essai4 / PARMBUFF ; 
/* --> on alimente une macro-variable SYSPBUFF avec les paramètres */
/* Attention, SYSPBUFF contient aussi des parenthèses autour de l'ensemble des valeurs */
DATA Essai;
SET sashelp.class;
a4 = catx('/', %SYSFUNC(COMPRESS(&syspbuff,%STR(%(%))))) ;
RUN;
%mend;
%essai4(name,age,sex)

Bon courage pour ton stage & pour la suite.
Olivier

[wizou44]

Daccord, ça peut être utile en effet.
Merci pour ton explication

Christophe

[wizou44]

Re-bonjour,

J'ai essayer la première méthode mais il se trouve que cela me donne un message d'erreur lors de l'utilisation de plusieurs variables.. Pourriez-vous m'aider à résoudre cette erreur. Merci, d'avance.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
1335  %macro essai4 (VARIABLES);
1336  %LET VARIABLES = %SYSFUNC(COMPBL(&variables)) ; /* supprime les blancs inutiles */
1337  %LET VARIABLES = %SYSFUNC(TRANSLATE(&variables,%STR(,),%STR())) ; /* remplace les blancs
1337! par des virgules */
1338  DATA batch2.Essai3;
1339  SET batch2.class;
1340  a4 = catx('/', &variables) ;
1341  RUN;
1342  %mend;
1343  %essai4(name age sex);
 
NOTE: The SAS System stopped processing this step because of errors.
WARNING: The data set BATCH2.ESSAI3 may be incomplete.  When this step was stopped there were 0
         observations and 6 variables.
WARNING: Data set BATCH2.ESSAI3 was not replaced because this step was stopped.
NOTE: DATA statement used (Total process time):
      real time           1.82 seconds
      cpu time            0.00 seconds
 
NOTE: Line generated by the macro variable "VARIABLES".
1      name age sex
            --- ---
            388 202
 
ERROR 388-185: Expecting an arithmetic operator.
 
ERROR 202-322: The option or parameter is not recognized and will be ignored.

[steelspirit]

le problème vient de CATX et du contenu de &variables :

tu fais : a4 = catx('/', &variables) ; c'est à dire
a4 = catx('/', name age sex) ;

or la syntaxe est : a4 = catx('/',name,age,sex) ;

dans une fonction les arguments sont séparées par des ,

[wizou44]

Mais normalement la fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%LET VARIABLES = %SYSFUNC(TRANSLATE(&variables,%STR(,),%STR())) ;

devrait transformer "name age sex" en "name,age,sex".

Je suppose donc que c'est cette fonction qui ne marche pas, mais je n'arrive pas à trouver sont problème. Pourrais-tu m'aider?

[steelspirit]

et voila

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%LET VARIABLES = %SYSFUNC(TRANSLATE(&variables,%str(,),%nrquote( ))) ;

avec %nrquote ça marche mieux ...

Attention : ne pas oublié de mettre l'espace dans %nrquote : %nrquote( )

[wizou44]

Merci de ton aide, ça marche nickel