Discussion :

[Thargor]

Bonjour,

Alors voila, mon application est un petit programme qui crée et compresse des fichiers via winzip.

Pour cela l'appli je fais un appel au shell :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

res = Shell(commande_line, 1)

(command_line contient les instructions pour lancer winzip avec le nom des fichiers etc...)

Alors cela fonctionne tres bien depuis de nombreuses années sur des pcs pas trop performants mais depuis que le parc PCs a ete mis a jour des erreurs se produisent .... il semblerait que cela soit du a la vitesse des machines...

Ce qu'il faudrait c'est que j'arrive a detecter a quel moment la commande shell a fini de s'executer pour pouvoir effectuer la suite de mon code.

Y a t il moyen de faire cela? par exemple en detectant la fermeture de la fenetre DOS ou autre?

Merci d'avance pour votre aide.

rq: ce que j'ai trouve comme explication sur le shell etait tres bref et si ce sujet a deja ete evoque sur le forum je m'en excuse, mais il y a bcp de sujets....

[SfJ5Rpw8]

tu peu essayer :

Comment exécuter un programme externe ?

c'est du VBScript mais qui doit "tourner" en VB6..

[Thargor]

Voici ce que j'ai trouve, c'est un peu complique mais ca a resolu mon problème.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
 
Private Type STARTUPINFO
      cb As Long
      lpReserved As String
      lpDesktop As String
      lpTitle As String
      dwX As Long
      dwY As Long
      dwXSize As Long
      dwYSize As Long
      dwXCountChars As Long
      dwYCountChars As Long
      dwFillAttribute As Long
      dwFlags As Long
      wShowWindow As Integer
      cbReserved2 As Integer
      lpReserved2 As Long
      hStdInput As Long
      hStdOutput As Long
      hStdError As Long
   End Type
 
   Private Type PROCESS_INFORMATION
      hProcess As Long
      hThread As Long
      dwProcessID As Long
      dwThreadID As Long
   End Type
 
   Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
      hHandle As Long, ByVal dwMilliseconds As Long) As Long
 
   Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
      lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
      lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
      ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
      ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
      lpStartupInfo As STARTUPINFO, lpProcessInformation As _
      PROCESS_INFORMATION) As Long
 
   Private Declare Function CloseHandle Lib "kernel32" _
      (ByVal hObject As Long) As Long
 
   Private Declare Function GetExitCodeProcess Lib "kernel32" _
      (ByVal hProcess As Long, lpExitCode As Long) As Long
 
   Private Const NORMAL_PRIORITY_CLASS = &H20&
   Private Const INFINITE = -1&
 
   Public Function ExecCmd(cmdline$)
      Dim proc As PROCESS_INFORMATION
      Dim start As STARTUPINFO
      Dim ret_test As Variant
 
 
      ' Initialize the STARTUPINFO structure:
      start.cb = Len(start)
 
      ' Start the shelled application:
      ret_test = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
         NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)
 
      ' Wait for the shelled application to finish:
         ret_test = WaitForSingleObject(proc.hProcess, INFINITE)
         Call GetExitCodeProcess(proc.hProcess, ret_test)
         Call CloseHandle(proc.hThread)
         Call CloseHandle(proc.hProcess)
         ExecCmd = ret_test
   End Function
 
   Sub Command1_Click()
      Dim res As Long
      Dim commande_line As String
 
      commande_line = "C:\Program Files\Winzip\Wzzip.exe C:\PackageEudorV21\data\LOCAL2EUDORARCHIVE\TU_PUBPDF_IL7606423ESC_1_20070726154038.zip  C:\PACKAG~1\data\PUBPOU~1\IL7606423ESC.jpg C:\PACKAG~1\data\PUBPOU~1\IL7606423ESC_002.pdf C:\PackageEudorV21\data\LOCAL2EUDORARCHIVE\U_PUBPDF_IL7606423ESC_1_20070726154038.xml"
 
      res = ExecCmd(commande_line)
      MsgBox "Process Finished, Exit Code " & res
   End Sub