Discussion :

[bailamos]

est ce que il ya un moyen pour faire un target en visual basic c'est a dire ouvrire les liens d'un webbrowser dans un autre en sachant que je peux aussi modifier la source html???????????????????





merci d'avence

[SilkyRoad]

bonjour

Je ne suis pas sur d'avoir compris



Pour lister les liens d'une page html:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub CommandButton1_Click()
    Dim i As Integer
    For i = 0 To WebBrowser1.Document.links.Length - 1
        Debug.Print WebBrowser1.Document.links.Item(i)
    Next
End Sub

Pour déclencher un lien spécifique:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub CommandButton2_Click()
    'nécéssite d'activer la référence Microsoft HTML Objects Library
    'nécéssite d'activer la référence Microsoft Internet Controls
    Dim Cible As HTMLAnchorElement
    Dim MaPageHtml As HTMLDocument
 
    Set MaPageHtml = WebBrowser1.Document
    '0 est le 1er lien dans la page
    Set Cible = MaPageHtml.links(0)
    Cible.Click
End Sub

michel

[bailamos]

merci SilkyRoad


ce que je veux c'est un moyen pour que a chaque fois que l'utilisateur clic dans le webbrowser1 le lien soit ouver dans webbrowser2 ou lieux de 1

[SilkyRoad]

bonsoir


j'espère que tu pourras adapter cet exemple VBA Excel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
'--------------------------------------
'A placer dans un module standard
Option Explicit
 
Public Collect As Collection
'--------------------------------------

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
'--------------------------------------
'A placer dans un module de classe nommé "Classe1"
'
Option Explicit
 
'Nécessite d'activer la référence "Microsoft HTML Object Library"
Public WithEvents Lnk As MSHTML.HTMLAnchorElement
 
 
'Exemple pour gérer l'évènement clic sur les objets
'type MSHTML.HTMLAnchorElement (liens) dans le WebBrowser.
Private Function Lnk_onclick() As Boolean
    'MsgBox Lnk.href
 
    'Affiche l'URL du lien cliqué dans un 2eme WebBrowser
    UserForm1.WebBrowser2.Navigate Lnk.href
End Function
'--------------------------------------

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
'--- A placer dans un UserForm contenant 2 WebBrowsers ---
 
Option Explicit
 
Dim maPageHtml As HTMLDocument
 
 
Private Sub UserForm_Initialize()
    WebBrowser1.Navigate "http://www.developpez.com"
End Sub
 
 
 
Private Sub WebBrowser1_DocumentComplete(ByVal pDisp As Object, URL As Variant)
    Dim Cl As Classe1
    Dim i As Integer
    Dim imgHtml As HTMLAnchorElement
 
    Set Collect = New Collection
    Set maPageHtml = WebBrowser1.Document
 
    'Boucle sur les liens contenus dans le WebBrowser
    For i = 0 To maPageHtml.links.Length - 1
        Set imgHtml = maPageHtml.links.Item(i)
 
        'ajoute l'objet dans la classe
        Set Cl = New Classe1
        Set Cl.Lnk = imgHtml
        Collect.Add Cl
    Next i
 
End Sub
 
 
 
Private Sub WebBrowser1_BeforeNavigate2(ByVal pDisp As Object, _
    URL As Variant, Flags As Variant, TargetFrameName As Variant, _
    PostData As Variant, Headers As Variant, Cancel As Boolean)
 
    Set Collect = Nothing
    Set maPageHtml = Nothing
 
End Sub
 
 
 
Private Sub WebBrowser1_NewWindow2(ppDisp As Object, Cancel As Boolean)
    Cancel = True
End Sub
'---------

michel

[bailamos]

merci SilkyRoad