Discussion :

[peter2fr]

Bonjour, je n'arrive pas a afficher les caractères accentués venant d'informations affichées dans une fenêtre CMD affichée a partir d'une commande et récupérées dans une TextBox.
Exemple pour IPCONFIG, j'obtient :
Masque de sous-r‚seau. . . .ÿ. . . . . : 255.255.255.0
Passerelle par d‚faut. . . .ÿ. . . . . : fe80::72fc:8fff:fe69:3248%18

Voici la partie du code concernée :
'Execute la commande DOS
Private Sub ExecuteCommand(command As String)
Dim processInfo As New ProcessStartInfo("cmd", " /c " & command)
processInfo.RedirectStandardOutput = True
processInfo.UseShellExecute = False
processInfo.CreateNoWindow = True

Dim process As Process = Process.Start(processInfo)
Dim output As String = process.StandardOutput.ReadToEnd()
process.WaitForExit()

TextBox1.Text = output
End Sub

command est la valeur de la commande CMD que l'on va lancer, ici ipconfig.

Si je rajoute :
cmd.exe", " /c chcp 850" & command

J’obtiens une page vide dans la TextBox
Quelqu'un a-t-il une idée ?

[popo]

Il s'agit d'un problème d'encodage des plus classique.
Une solution simple est de redéfinir l'encodage de la sortie standard.
Au passage, pas besoin de cmd pour exécuter ipconfig.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Public Class Form1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
 
    Encoding.RegisterProvider(CodePagesEncodingProvider.Instance)
 
    Dim info = New ProcessStartInfo With {
            .UseShellExecute = False,
            .RedirectStandardOutput = True,
            .StandardOutputEncoding = Encoding.GetEncoding(850),
            .FileName = "ipconfig.exe"
        }
 
    Dim p = Process.Start(info)
    Dim output = p.StandardOutput.ReadToEnd()
 
    p.WaitForExit()
 
    TextBox1.Text = output
End Sub
End Class

Edit :
La version en passant par cmd au lieu de ipconfig directement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
 
    Encoding.RegisterProvider(CodePagesEncodingProvider.Instance)
 
    Dim info = New ProcessStartInfo("cmd", " /c " & "ipconfig") With {
        .RedirectStandardOutput = True,
        .StandardOutputEncoding = Encoding.GetEncoding(850),
        .UseShellExecute = False,
        .CreateNoWindow = True
    }
 
    Dim p = Process.Start(info)
    Dim output As String = p.StandardOutput.ReadToEnd()
 
    p.WaitForExit()
 
    TextBox1.Text = output
End Sub

[peter2fr]

Merci pour cette super réponse, je test et reviens pour donner le résultat.
😃

[umfred]

Sinon pour chainer les commandes en "DOS" il faut les séparer par un ou 2 & (2 si on souhaite que la seconde commande soit lancée si la 1ere est réussie)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

cmd.exe", " /c chcp 850 && " & command

devrait aussi fonctionner

Mais la solution de popo me semble meilleure dans l'approche.

[peter2fr]

Merci emfred, mais ta solution de fonctionne pas, et toujours pas de visualisation des lettres accentuées.

Et grand merci, popo, Ta solution fonctionne très bien, j'ai pris le 2eme choix pour uniformiser l'ensemble, au cas ou je doive mettre des instructions DOS comme dir ou autre.