Discussion :

[BasicZX81]

Bonjour à tous,
J'aurais bien besoin de votre aide pour le problème cité en objet.
Je me suis inspiré de ces 2 exemples ci-dessous et j'arrive à personnaliser les champs sans liste de choix du type Integer, single, double, string avec mise en forme via un TypeConverter.
Je sais aussi personnaliser les choix du type Boolean via un BooleanConverter et également les Enum via un EnumConverter.

https://www.codeproject.com/Articles...g-PropertyGrid
https://www.cyotek.com/blog/creating...nverter-part-1

Mon problème est que j'aimerais afficher une List(of string) pour faire un choix dans la liste et stocker l''élément dans la propriété string de mon objet. Je pense que les Enum ne conviendront pas car ma liste possède un nombre d'éléments qui peux varier au contraire des Enum qui ont un nombre d'éléments fini.

Il existe tous un tas de TypeConverter comme les StringConverter, les TypeListConverter ou encore les CollectionConverter et j'avoue que je ne sais déjà pas lequel choisir, comment charger ma liste et ensuite obtenir l'élément. je suppose qu'il faut utiliser les méthodes ConvertTo et ConvertFrom mais un exemple serait vraiment le bienvenue.

En vous remerciant.

[BasicZX81]

J'ai trouvé...Héhé
Dans mon exemple ma liste de string s'appelle : ListeDataTypes

Ma Classe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Public Class ListeTypes
    Implements IValueListTypes
    Private Shared _Liste As List(Of String)
    Shared Sub New()
        _Liste = ListeDataTypes
    End Sub
    Public Function GetValues() As IEnumerable(Of String) Implements IValueListTypes.GetValues
        Return _Liste
    End Function
End Class
 
Public Interface IValueListTypes
    Function GetValues() As IEnumerable(Of String)
End Interface
 
Public Class StringListConverter(Of VALUES As {IValueListTypes, New})
    Inherits TypeConverter
 
    Public Overrides Function GetStandardValuesSupported(ByVal context As ITypeDescriptorContext) As Boolean
        Return True
    End Function
 
    Public Overrides Function GetStandardValues(ByVal context As ITypeDescriptorContext) As StandardValuesCollection
        Dim values As VALUES = New VALUES()
        Return New StandardValuesCollection(values.GetValues.ToList())
    End Function
End Class

Mon Objet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public class MonObjet
        <Category("B-Propriétés")>
        <Description("Catégorie de l'équipement")>
        <TypeConverter(GetType(StringListConverter(Of ListeTypes)))>
        Public Property Type As String
            Get
                Return _Type
            End Get
            Set(ByVal value As String)
                _Type = value
                MyBase.OnPropertyChanged()
            End Set
        End Property
End Class