Discussion :

[Legnano]

Bonjour
J'ai une liste de 5000 documents, avec leur chemin complet, répartis dans une multitude de dossiers, et j'aimerais imprimer chacun de ces documents (imprimer en PDF).
Un logiciel capable de faire ce travail? J'ai cherché sans succès.
ou encore mieux, quelques lignes de commande?
je pensais faire un .bat avec la commande PRINT.


PRINT [/D:device] [[drive:][path]filename[...]]

Mais j'ai du mal à maitriser cette commande. en tapant 2 fois de suite la même commande, 1 fois ça marche, la seconde fois erreur "Impossible d’initialiser le périphérique" ...
j'ai réussi à projeter mon PDF au bon endroit, en mettant le chemin de projection après "/D:" , a la place du nom de l'imprimante...
vous sauriez m'expliquer comment ca marche?

[JML19]

Bonjour

Imprimer plusieurs fichiers PDF sous Windows

1. Localisez les documents PDF que vous souhaitez imprimer et déplacez-les dans un dossier.

2. Maintenez la touche "Ctrl" enfoncée et sélectionnez tous les fichiers PDF que vous voulez imprimer, en sélectionnant plusieurs fichiers PDF en même temps.

3. Cliquez avec le bouton droit de la souris sur les fichiers PDF sélectionnés pour sélectionner Imprimer.

Si vous avez déjà connecté votre ordinateur à une imprimante physique avec succès, cela vous permettra d'imprimer les multiples fichiers PDF sélectionnés en une seule fois.

[Legnano]

j'ai 5000 documents, réparis un peu partout sur le serveur, c'est des documents partagés avec les collègues, et je ne peux pas me permettre de déplacer ni copier tous ces documents.

C'est vraiment la méthode par l'invite de commande qui m’intéresse.
Peut etre que je ne poste pas dans la bonne section de forum?

[JML19]

Il n'est pas possible de faire dossier par dossier ?

[l_autodidacte]

J'ai une liste de 5000 documents, avec leur chemin complet, répartis dans une multitude de dossiers

La liste des fichiers à imprimer devrait contenir les chemins complets UN SEUL PAR LIGNE.
Si c'est bien le cas, on peut procéder à l'impression en utilisant un script vbs simple tel que :

Code VB :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Explicit
 
Const ForReading = 1
Const ListeFichiers = "C:\Temp\ListePDF.txt" 'Fichier contenant la liste des PDF à imprimer(à modier selon le besoin)
                                             ' UN SEUL CHEMIN PAR LIGNE
Dim objShell, colItems, objItem, objFolder
Set objShell = CreateObject("Shell.Application")
 
Call LireListe ' Lecture de la liste puis impression
 
Sub LireListe()
    Dim fso, LigneLue, NomFichier, NomDossier, oFile
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set oFile = fso.OpenTextFile(ListeFichiers, ForReading, False)
    Do While Not oFile.AtEndOfStream
        LigneLue = oFile.ReadLine
        If LigneLue <> "" Then ' vérifie si une ligne est vide évitant ainsi des erreurs de lecture 
            NomDossier = Left(LigneLue, InstrRev(LigneLue, "\"))
            NomFichier = Right(LigneLue, Len(LigneLue)-Len(NomDossier))
            Call PrintPDF(NomDossier, NomFichier)
            ' SI besoin d'une attente avant de commencer avec le fichier suivant, on fait :
            Wscript.Sleep 5000 ' Attente de 5 secondes(qu'on peut augmenter au choix) 
' MsgBox LigneLue & " // " & NomFichier  ' pour vérification
        End If
    Loop    
End Sub
'==============================
Sub PrintPDF(strDir, strFile)
     Set objFolder = objShell.Namespace(strDir)  
     Set colItems = objFolder.Items 
      For Each objItem in colItems 
        If Ucase(Right(ObjItem.Name,4)) = ".PDF" Then  
           ' Vérifie qu'il s'agit bien d'un fichier de la liste établie au préalable puis l'imprime
           If UCase(ObjItem.Name) = UCase(strFile) Then  objItem.InvokeVerbEx("Print") 
        End If 
      Next
End Sub

Il suffit de mettre le chemin du fichier contenant la liste dans la constante ListeFichiers.
Le script se charge de chercher les fichiers là où ils sont puis les envoie vers l'imprimante par défaut.

[Legnano]

Merci autodidacte,
Je pense que ça correspond assez bien a ce qu'il me faut.
en effet, j'ai la liste avec un chemin par ligna dans un .txt
Je vais faire un essai pour voir comment l'imprimant pdf gère les nom et emplacement de l'impression pdf.
see you soon