Discussion :

[thanaos]

Bonjour à tous.
J'ai un serveur Apache2 sous WiwiXP sur un serveur distant qui plante de temps à autre.
Mise à par la recherche du problème, je voudrais être informer automatiquement du plantage (style tâche planifiée) et faire de telle sorte qu'il soit relancé.
Est ce possible ?
Merci pour vos réponses.

[tractos]

Salut toi tout seul,

Voici un petit script vbs sans prétention récupéré sur le net et modifié par mes soins ,à intégrer dans le planificateur de tâche, lancé toutes les minutes .

Code VB :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Dim Service
Dim ServiceChecked
Dim CheckServices
 
ServiceChecked="Apache2" ' <= Indiquez le nom du service Apache tel que décrit dans la liste des services Windows
 
Set WshShell = WScript.CreateObject("WScript.Shell")
 
For Each Service In GetObject("winmgmts:{impersonationLevel=impersonate}!//" & ComputerToConnect).InstancesOf("win32_service")
	If LCase(Service.Name) = LCase(ServiceChecked) Then
  	CheckServices = Service.State
  	Exit For
  Else
    CheckServices = "Not Found"
  End If
Next
 
If CheckServices = "Stopped" Then
	WshShell.run "Net start " & ServiceChecked
End If

A corriger/améliorer/adapter bien entendu.

@plouche.

[Regnak]

He he il est pas mal le petit script ;
en fait c'est un watch dog que l'on peut recycler sur plein d'autre choses,

[thanaos]

Désolé je suis pas doué en VB.
J'en fais quoi de ce script ?

[tractos]

Oups, j'avions oublié
Tu colle le code dans un fichier texte avec l'extension .vbs
ça se comporte ensuite comme un programme classique.

[tractos]

Salut ,

Un petit rajout pour un envoi de mail à chaque redémarrage .

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
 
Dim Service
Dim ServiceChecked
Dim CheckServices
Dim SMTPServer
Dim MailFrom
Dim MailTo
Dim MailSubject
Dim MailBody
 
'-------------------------------------------------------------------------------------------------
'|       Indiquez le nom du service Apache tel que décrit dans la liste des services Windows     |
'-------------------------------------------------------------------------------------------------
 
	ServiceChecked = "Apache2"
 
'------------------------------------------------------------------------------------
'|      Indiquez le nom du serveur SMTP servant à envoyer le mail d'alerte          |
'------------------------------------------------------------------------------------
 
	SMTPServer = "smtp.server.fr"
 
'----------------------------------------------------------------------
'|       Indiquez le mail de l'expéditeur du message d'alerte         |
'----------------------------------------------------------------------
 
	MailFrom = "moi@ici.com"
 
'---------------------------------------------------------------------------------
'|       Indiquez le(s) mail(s) du(des) destinataire(s) du message d'alerte         |
'---------------------------------------------------------------------------------
 
	MailTo = "lui@labas.com;eux@kelkepart.com"
 
'-------------------------------------------------------
'|       Indiquez le sujet du message d'alerte         |
'-------------------------------------------------------
 
	MailSubject = "Redémarrage du serveur Apache de Production"
 
'-------------------------------------------------------
'|       Indiquez le corps du message d'alerte         |
'-------------------------------------------------------
 
	MailBody = "Le serveur Apache de Production à redémarré le " & Date & " à " & Time & "."
 
Set WshShell = WScript.CreateObject("WScript.Shell")
 
For Each Service In GetObject("winmgmts:{impersonationLevel=impersonate}!//" & ComputerToConnect).InstancesOf("win32_service")
	If LCase(Service.Name) = LCase(ServiceChecked) Then
  	CheckServices = Service.State
  	Exit For
  Else
    CheckServices = "Not Found"
  End If
Next
 
If CheckServices = "Stopped" Then
	WshShell.run "Net start " & ServiceChecked
	Set objEmail = CreateObject("CDO.Message") 
	objEmail.From = MailFrom 
	objEmail.To = MailTo
	objEmail.Subject = MailSubject 
	objEmail.Textbody = MailBody
	objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
	objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTPServer
	objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
	objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
	objEmail.Configuration.Fields.Update 
	objEmail.Send
End If

En espérant que ça vous serve

@plouche