Pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter, inscrivez-vous gratuitement !

 

  1. #1
    Membre du Club
    Inscrit en
    novembre 2006
    Messages
    106
    Détails du profil
    Informations forums :
    Inscription : novembre 2006
    Messages : 106
    Points : 41
    Points
    41

    Par défaut Fin d'instruction attendue 800A0401

    Bonjour,

    lorsque je veux exécuter ce script j'ai l'erreur suivante :

    ---------------------------
    Windows Script Host
    ---------------------------
    Script : C:\Users\user\Desktop\Clé Registre AddIn.vbs
    Ligne : 49
    Caract. : 50
    Erreur : Fin d'instruction attendue
    Code : 800A0401
    Source : Erreur de compilation Microsoft VBScript

    ---------------------------
    OK
    ---------------------------

    Pouvez-vous m'aider?

    merci d'avance

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    Const EXCEL_ADDIN_PATH_BEFORE = "HKCU\Software\Microsoft\Office\" 
    Const EXCEL_ADDIN_PATH_AFTER = "\Excel\Options\" 
    Const ADDIN_REG_VALUE = "C:\generix6\chf\Integration_GNX.xla"
     
    Function RegistrationKeyExists(key) 
        On Error Resume Next 
        objShell.RegRead (key) 
        If Err = 0 Then 
            RegistrationKeyExists = True 
        Else 
            RegistrationKeyExists = False 
        End If 
    End Function 
     
    Function RegistrationKeyValueGet(name) 
        On Error Resume Next 
        Dim value 
        value = objShell.RegRead(name) 
        If Err = 0 Then 
            RegistrationKeyValueGet = value 
        Else 
            RegistrationKeyValueGet = "" 
        End If 
    End Function 
     
    Function RegistrationKeyValueSet(name, value) 
        On Error Resume Next 
        objShell.RegWrite name, value, "REG_SZ" 
        If Err = 0 Then 
            RegistrationKeyValueSet = True 
        Else 
            RegistrationKeyValueSet = False 
        End If 
    End Function 
     
    Dim EXCEL_ADDIN_PATH 
    Dim versions 
    Dim officeval 
    Dim objShell 
    Dim count 
    Dim value 
    Dim exists 
    Dim success 
     
    Set objShell = CreateObject("WScript.Shell") 
     
    WScript.Echo "Excel Add-in Registration Tool" 
     
    versions = Array("12.0", "14.0", "15.0", "16.0") For Each officeval In versions 
        EXCEL_ADDIN_PATH = EXCEL_ADDIN_PATH_BEFORE & officeval & EXCEL_ADDIN_PATH_AFTER 
     
        WScript.Echo "Checking Office Version - " & officeval 
     
        If RegistrationKeyExists(EXCEL_ADDIN_PATH) Then 
            count = 0 
            exists = False 
            value = RegistrationKeyValueGet(EXCEL_ADDIN_PATH & "OPEN") 
     
            While Len(value) > 0 And Not exists 
                count = count + 1 
                value = RegistrationKeyValueGet(EXCEL_ADDIN_PATH & "OPEN" & count) 
                If value = ADDIN_REG_VALUE Then 
                    exists = True 
                End If 
            Wend 
     
            If exists = True Then 
                WScript.Echo "Office Version - " & officeval & " Already Registered" 
            Else 
                If count > 0 Then 
                    success = RegistrationKeyValueSet(EXCEL_ADDIN_PATH & "OPEN" & count, ADDIN_REG_VALUE) 
                Else 
                    success = RegistrationKeyValueSet(EXCEL_ADDIN_PATH & "OPEN", ADDIN_REG_VALUE) 
                End If 
                If success Then 
                    WScript.Echo "Office Version - " & officeval & " Registration Complete" 
                Else 
                    WScript.Echo "Office Version - " & officeval & " Unable to Register Add-In" 
                End If 
            End If 
        Else 
            WScript.Echo "Office Version - " & officeval & " Not Found" 
        End If 
    Next 
    Set objShell = Nothing

  2. #2
    Rédacteur/Modérateur
    Avatar de ProgElecT
    Homme Profil pro
    Retraité
    Inscrit en
    décembre 2004
    Messages
    4 534
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 62
    Localisation : France, Haute Savoie (Rhône Alpes)

    Informations professionnelles :
    Activité : Retraité
    Secteur : Communication - Médias

    Informations forums :
    Inscription : décembre 2004
    Messages : 4 534
    Points : 9 787
    Points
    9 787

    Par défaut

    Salut

    Et si
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    versions = Array("12.0", "14.0", "15.0", "16.0")
    For Each officeval In versions
    '...............
    next
    ProgElecT
    Soyez sympa, pensez -y
    Balises[CODE]...[/CODE]
    Balises[CODE=NomDuLangage]...[/CODE] quand vous mettez du code d'un autre langage que celui du forum ou vous postez.
    Le bouton en fin de discussion, quand vous avez obtenu l'aide attendue.
    ......... et pourquoi pas, pour remercier, un pour celui/ceux qui vous ont dépannés.

  3. #3
    Membre du Club
    Inscrit en
    novembre 2006
    Messages
    106
    Détails du profil
    Informations forums :
    Inscription : novembre 2006
    Messages : 106
    Points : 41
    Points
    41

    Par défaut

    Super merci ça fonctionne !

+ Répondre à la discussion
Cette discussion est résolue.

Discussions similaires

  1. [VBScript] Problème avec fin d'instruction attendue
    Par MateoFalcon dans le forum VBScript
    Réponses: 27
    Dernier message: 21/06/2013, 10h29
  2. fin d'instruction attendue(erreur 800A0400 ) en vbscript
    Par regisyves dans le forum VBScript
    Réponses: 4
    Dernier message: 06/06/2010, 22h55
  3. vbs erreur : fin d'instruction attendue
    Par Armadeus dans le forum Windows Vista
    Réponses: 0
    Dernier message: 25/08/2009, 10h28
  4. Réponses: 5
    Dernier message: 27/04/2006, 19h53

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo