Discussion :

[Marion33]

Bonjour, afin de tester mon ping en bat j'utilise ceci et ça marche nickel:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PING www.google.fr -n 6 > NUL
 
IF %ERRORLEVEL% EQU 0 (calc.exe) ELSE (notepad.exe)
 
PAUSE>NUL

mais quand je tente de l'insérer dans ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Set oShell = CreateObject("WScript.Shell")
strHomeFolder = oShell.ExpandEnvironmentStrings("%USERPROFILE%")
 
Set lnk = oShell.CreateShortcut(strHomeFolder & "\chrome.lnk")
 
lnk.WindowStyle = 
lnk.IconLocation = 
lnk.TargetPath = "cmd.exe"
lnk.arguments = "/C PING www.google.fr -n 3 > NUL & IF %ERRORLEVEL% EQU 0 (calc.exe) ELSE (notepad.exe)"
lnk.Save
oShell.Run (strHomeFolder & "\testping.lnk")

Il ne prend pas en compte correctement ma condition, le code n'arrive pas à faire le lien avant et après le "&" je crois... il fait comme si il n'y a pas d'erreur lorsque je coupe ma connexion comment faire ?

Je vous remercie !

[ericlm128]

J'ai une exception il faut que je mette en remarque deux lignes

Code vbs :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Set oShell = CreateObject("WScript.Shell")
strHomeFolder = oShell.ExpandEnvironmentStrings("%USERPROFILE%")
 
Set lnk = oShell.CreateShortcut(strHomeFolder & "\chrome.lnk")
 
'lnk.WindowStyle = 
'lnk.IconLocation = 
lnk.TargetPath = "cmd.exe"
lnk.arguments = "/C PING www.google.fr -n 6 > NUL & IF %ERRORLEVEL% EQU 0 (calc.exe) ELSE (notepad.exe)"
lnk.Save

Il me semble que ERRORLEVEL est évalué "correctement" à partir d'un fichier de commande (bat, cmd) et pas en ligne de commande directement.

Préfère cette syntaxe de manière général :

Code vbs :

Sélectionner tout - Visualiser dans une fenêtre à part

PING www.google.fr -n 6 >nul&&(calc.exe)||(notepad.exe)

[hackoofr]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Set oShell = CreateObject("WScript.Shell")
strHomeFolder = oShell.ExpandEnvironmentStrings("%USERPROFILE%")
Set lnk = oShell.CreateShortcut(strHomeFolder & "\testping.lnk")
lnk.TargetPath = "cmd.exe"
lnk.arguments = "/C PING www.google.fr -n 1 && (calc.exe) || (notepad.exe)"
lnk.Save
oShell.Run strHomeFolder & "\testping.lnk",0,True

Ou bien en vbscript sans passer par un batch ou cmd avec une exécution plus rapide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit
Dim ws
Set ws = CreateObject("wscript.shell")
If IsOnLine("www.google.fr") Then
    ws.run "calc.exe"
Else
    ws.run "Notepad.exe"
End If
'**************************************************************************************
Function IsOnLine(strHost)
    Dim objPing,i,objRetStatus,PingStatus
    Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery _
    ("select * from Win32_PingStatus where address = '" & strHost & "'")
    i = 0
    Do
        i = i + 1
        For Each objRetStatus In objPing
            If IsNull(objRetStatus.StatusCode) Or objRetStatus.StatusCode <> 0 Then
                PingStatus = False
            Else
                PingStatus = True
            End If      
        Next    
        wscript.sleep 200
        If i = 4 Then Exit Do
    Loop until PingStatus = True
    If PingStatus = True Then 
        IsOnLine = True
    Else
        IsOnLine = False
    End If
End Function
'***************************************************************************************

[Marion33]

Vous êtes géniaux !! merci ! j'ai fais un poste juste avant sur windowstyle, vous n'auriez pas une piste ? merci encore