Discussion :

[Phili34]

Bonjour tous,

Je tente de sauvegarder des fichiers d'un disque sur un autre à J-1 (c'est à dire tous les fichiers créés hier !)
voici le script Vbs que j'ai écrit
ligne 1 : la Variable x prend la date du jour et applique J-1
ligne 2 : la variable x2 reformate la date en mm-jj-yyyy (pour pouvoir utiliser la commande Xcopy
ligne 3 : Lancement de Xcopy avec l'option /d & la variable x2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
X= DateAdd("d",-1,date())
X2 = Month(x)& "-"& Day(x)& "-" & Year(x)
Xcopy F:\DiskFichier\ e:\NewDisque\DiskFichier /E /C /H /d: & x2

J'ai une erreur sur la ligne Xcopy que je n'arrive pas à résoudre. Si vous pouviez m'aider...

Passez tous une bonne année.

Merci

[JML19]

Bonjour

XCopy est un exécutable qui se trouve dans c:\windows\system32 peut être qu'il ne trouve pas l'exécutable si tu ne mets pas le chemin complet.

Tu peux faire aussi en te positionnant avant à l'endroit où se trouve xcopy.exe

[Andnotor]

As-tu essayé d'ajouter le paramètre /s ?

[Phili34]

Bonjour

XCopy est un exécutable qui se trouve dans c:\windows\system32 peut être qu'il ne trouve pas l'exécutable si tu ne mets pas le chemin complet.

Tu peux faire aussi en te positionnant avant à l'endroit où se trouve xcopy.exe

merci de de vous intéresser à mon problème.

J'ai l'habitude d'utiliser cet utilitaire et quand le lance manuellement la commande :
Xcopy F:\DiskFichier e:\NewDisque\DiskFichier/E /C /H /d:06-23-2017
L'action se déroule bien et les fichiers dont la date de création est supérieure au 23/06/2017 se copient bien de F: sur E:
Je cherche juste à mettre l'option /d: avec une variable de date

[Phili34]

As-tu essayé d'ajouter le paramètre /s ?

L'option /S Copie les répertoires et sous-répertoires à l'exception des répertoires vides.
Je n'utilise pas cette option car je veux copier les répertoires vides.

C'est vraiment le passage de la date calculée à j-1 que j'essaye de passer en paramètre à la commande Xcopy.

Merci.

[JML19]

Bonjour

Lorsque tu lances xcopy.exe depuis la racine ou Windows il n'y a pas de problème pour le chemin.

Mais lorsque tu utilises une application ce n'est pas la même chose, le Path Windows ne fonctionne pas.

[ProgElecT]

Salut

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim objShell, X, X2, cmd
 
Set objShell = CreateObject("WScript.Shell")
X= DateAdd("d",-1,date())
X2 = Month(x)& "-"& Day(x)& "-" & Year(x)
cmd = "F:\DiskFichier\ e:\NewDisque\DiskFichier /E /C /H /d:" & X2
Shell.Exec "Xcopy.exe " & cmd
Set objShell = Nothing

[hackoofr]

Il faut construire avant la commande Xcopy avec ses paramètres et l'afficher dans une MsgBox pour la "debugger"
Voici ma méthode pour construire cette commande en tenant compte aussi des doubles quotes pour les chemins avec espaces

Code Vbscript :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
Dim X, X2,StrCmd,Source,Cible,Params,OnThisDate
X= DateAdd("d",-1,date())
OnThisDate = Month(x)& "-"& Day(x)& "-" & Year(x)
Source = "F:\DiskFichier"
Cible = "e:\NewDisque\DiskFichier"
Params = " /E /C /H /d:" & OnThisDate
StrCmd = "Xcopy " & DblQuote(Source) &" "& DblQuote(Cible) & Params
'Afficher la commande dans Msgbox pour vérifier si la construction
'de celle-ci est bonne ou non, si oui, on peut alors la supprimer du code
msgbox StrCmd
Call Execute(StrCmd)
'********************************************************************
Function Execute(StrCmd)
    Dim ws,MyCmd,Resultat
    Set ws = CreateObject("wscript.Shell")
        MyCmd = "CMD /C " & StrCmd & ""
        Resultat = ws.run(MyCmd,0,True)
        If Resultat <> 0 Then
            MsgBox "Une erreur inconnue est survenue !",16,_
            "Une erreur inconnue est survenue !"
        End If
    Execute = Resultat
End Function
'********************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'********************************************************************

[Phili34]

Bonjour à tous,

La solution de ProgElecT fonctionne parfaitement.

Merci à tous pour votre diligence à m'aider.

[ericlm128]

xcopy direct dans un .vbs