Discussion :

[djedje-08]

Bonjour à tous,
Dans un Form, j'ai 4 panels placés les uns en dessous des autres.
Ils mesurent chacun 950 x 1378px
Chacun de ces panels contient différents éléments (label, picturebox, textbox etc ...).
J'aimerai pouvoir imprimer ces panels chacun sur une page.
Pour se faire, j'ai voulu utiliser le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
        PrintForm1.PrintAction = Printing.PrintAction.PrintToPreview
        PrintForm1.PrinterSettings.DefaultPageSettings.Margins.Top = 0
        PrintForm1.PrinterSettings.DefaultPageSettings.Margins.Bottom = 0
        PrintForm1.PrinterSettings.DefaultPageSettings.Margins.Left = 0
        PrintForm1.PrinterSettings.DefaultPageSettings.Margins.Right = 0
        PrintForm1.Print(Me, PowerPacks.Printing.PrintForm.PrintOption.Scrollable)

Malheureusement pour moi, seul la partie visible à l'écran apparait dans l'aperçu, soit environ la première moitié du 1er panel.
Ma première question est donc : comment "forcer" l'impression d'un panel complet sur une page ?
Et naturellement ma seconde question est : comment imprimer un panel par page ?

Je pense qu'il me faudrait utiliser HasMorePages mais je ne vois absolument pas comment l'utiliser dans mon cas.

Je vous remercie par avance pour vos réponses

[MABROUKI]

bonjour

Pour imprimer un control il faut le dessiner au préalable dans un bitmap...
DrawToBitmap(bitmap, Control.ClientRectangle) est ton ami...

voici un exemple de code qui récupère les panels du Form et les dessine un à un dans un List(Of Bitmap)...

Les bitmaps du List(Of Bitmap) sont imprimés dans l'évent PrintDocument_PrintPage...
code .vb :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
Public Class Form1
 
    Private pnlImages As List(Of Bitmap)
    Private count As Integer
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
 
    End Sub
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
 
        'recupere chaque panal du form et le dessine dans un bitmap
        'la liste de bitmap contient tous les panels
        pnlImages = New List(Of Bitmap)
        For Each ctl As Control In Me.Controls
            If TypeOf ctl Is Panel Then
                Dim bmp As New Bitmap(ctl.Width, ctl.Height)
                ctl.DrawToBitmap(bmp, ctl.ClientRectangle)
                pnlImages.Add(bmp)
            End If
 
 
        Next
        'compteur de bitmap à imprimer
        count = 0
        PrintDialog1.Document = PrintDocument1
        If PrintDialog1.ShowDialog = DialogResult.OK Then
            PrintDocument1.Print()
        End If
    End Sub
    Private Sub PrintDocument1_PrintPage(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
        Dim gr As Graphics = e.Graphics
        Dim rect As Rectangle = e.PageBounds
        gr.DrawImage(pnlImages(count), rect)
        e.HasMorePages = count < pnlImages.Count - 1
        If e.HasMorePages Then
 
            count += 1
        End If
 
 
 
    End Sub
 
 
 
 
 
End Class

Bon code...

[djedje-08]

Merci, j'essaye ça dès que possible

[djedje-08]

ça marche impec !
Merci beaucoup