Discussion :

[Abdaz]

salut!

Je conçois des applications sur access et j'aimerais pouvoir qu'au lancement de mon application, l'icone qui s'affichera dans la barre des taches ne soit pas celle d'access mais plutot une icone propre à mon application!

Merci d'avance!

[Jean-Philippe André]

Salut,

il est possible de changer l'icone de ton application, avec par exemple ce bout de code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Public Sub SetIcon()
Dim strIcon As String
strIcon = "C:\temp\examples.ico"
ChangeProperty "AppIcon", dbText, strIcon
End Sub
 
Function ChangeProperty(strPropName As String, varPropType As String, varPropValue As Variant) As Integer
 
    Dim dbs As DAO.Database
    Dim prp As DAO.Property
 
    Set dbs = CurrentDb
    On Error GoTo PROC_ERROR
 
    dbs.Properties(strPropName) = varPropValue
    ChangeProperty = True
 
PROC_EXIT:
    On Error Resume Next
    Set prp = Nothing
    Set dbs = Nothing
    Exit Function
 
PROC_ERROR:
    If Err.Number = 3270 Then
        Set prp = dbs.CreateProperty(strPropName, varPropType, varPropValue)
        dbs.Properties.Append prp
        Resume Next
    Else
        ChangeProperty = False
        Resume PROC_EXIT
    End If
End Function

Cela ne change pas l'icone dans la barre directement (ce qui je crois n'est pas possible base par base), mais lorsque tu souhaiteras te deplacer avec Alt+TAb, tu verras bien l'icone + icone en haut a gauche dans ton interface..