Discussion :

[kened4]

Bonjour à tous,

Je dois transposer des données avec SAS mais je n'arrive à concrétiser la solution à mon besoin.

Après de nombreuses étapes j'ai réussi à créer la table SAS WORK.STOCGARCPT_CDCDS111_DETTE2 suivante:



Je voudrais transposer les données pour afficher en ligne les données LB_VAL et MTDET pour chaque IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR.
De plus, les noms des colonnes de LBVAL devraient etre LBDONCOM3,LBDONCOM4, LBDONCOM5...



Est ce possible avec une procédure transpose unique; je n'arrive pas obtenir ce résultat?

Si j'utilise basiquement la proc transpose avec 2 var comme ci-dessous:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
proc transpose data=WORK.STOCGARCPT_CDCDS111_DETTE2 out=WORK.STOCGARCPT_CDCDS111_FINAL;
  by IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR;
  var LB_VAL MTDET;
run ;

J'obtiens alors des données transposées mais sur 2 lignes par IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR. Une ligne pour les données LB_VAL et une ligne pour MTDET.

Par ailleurs, je ne te peux trier les données sur MTDET. Le tri de la table est le suivant: IDSUR (alphanumérique) RNG (numérique).

Si quelqu'un aurait une piste pour m'aiguiller, je lui en serai reconnaissant.

Merci de m'avori lu.

[steelspirit]

Bonjour,
Une solution serait de faire un proc transpose pour LB_VAL et un autre pour MTDET puis de faire un merge des 2 tables :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
proc transpose data=WORK.STOCGARCPT_CDCDS111_DETTE2 out=WORK.STOCGARCPT_CDCDS111_LBVAL prefix=LBDONCOM;
  by IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR;
  var LB_VAL ;
  id RNG;
run ;
proc transpose data=WORK.STOCGARCPT_CDCDS111_DETTE2 out=WORK.STOCGARCPT_CDCDS111_MTDET prefix=MTDET;
  by IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR;
  var MTDET;
  id RNG;
run ;
 
DATA WORK.STOCGARCPT_CDCDS111_FINAL;
    merge WORK.STOCGARCPT_CDCDS111_LBVAL WORK.STOCGARCPT_CDCDS111_MTDET ;
    by IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR;
RUN;

Bon courage,
Steel

[kened4]

Merci mais si je ne me trompe pas mon résultat sera le suivant (au niveau de l'ordre des colonnes)::

IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR LBDONCOM3 LBDONCOM4 LBDONCOM5 LBDONCOM6 .... MTDET3 MTDET4 MTDET5 MTDET6

alors que je souhaite:
IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR LBDONCOM3 MTDET3 LBDONCOM4 MTDET4 LBDONCOM5 MTDET5 LBDONCOM6 MTDET6....

[kened4]

j'ai quand meme testé et j'avais vu juste.

Alors , on pourrait s'amuser a faire 8 tables pour le LB_VAL et le MTDET et merger ensuite dans l'ordre mais c'est vraiment trop sale

[steelspirit]

depuis quand l'ordre des variables d'un dataset est important ?

Bon OK parceque c'est toi je vais te donner une astuce : on peut tricher et mettre un RETAIN avant un SET ou un MERGE dans une étape data pour changer l'ordre des variables...
du coup en utilisant une macro tu peux faire un truc dans le genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
%macro test;
DATA STOCGARCPT_CDCDS111_FINAL_2;
	retain IDSUR CDCDS CDETA CDSOUETA DTACQ MTSURREV MTSUR
		%do i=3 %to 10;
			LBDONCOM&i MTDET&i
		%end;
	;
    set  STOCGARCPT_CDCDS111_FINAL;
RUN;
%mend;
%test

Evidemment les valeurs de ta boucle %do i=3 %to 10 peuvent être récupérées automatiquement et stockées dans des macro variables (en utilisant une proc sql par exemple).

Bon courage,
Steel