Discussion :

[Mathj]

Bonjour,

Je tente d'importer un fichier excel et de changer le nom des colonnes. Voici mon petit programme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
libname stt '.';
options fmtsearch=(stt);
 
proc format library=stt;
  value $Genderfmt 'M'='Homme'
                             'F'='Femme';
  value $SchoolSizefmt 'M'='Moyenne'
		                   'S'='Petite'
				   'L'='Grande';
  value $Scholarshipfmt 'N'='Non'
		                   'Y'='Oui';
run;
 
proc import datafile="college.xls"
                        out=stt.college
			dbms=xls
			replace;
		range="college$A1:F100";
		getnames=yes;
		label StudentID='Code identifiant de l''etudiant'
		          Gender='Sexe'
			  SchoolSize='Taille du college'
			  Scholarship='Bourse d''etude'
			  GPA='Moyenne cumulative'
			  ClassRank='Rang';
	    format Gender $Genderfmt. SchoolSize $SchoolSizefmt. Scholarship $Scholarshipfmt.;
run;
 
 
 
proc print data=stt.college;
run;

Le problème est que le nom des colonnes ne change pas. Je me demande si c'est parce que je mets le label dans le proc import ?

[josef1980]

Bonjour,
L'instruction format n'est pas supporté dan l'import:
- pour le format, vous pouvez utiliser proc datasets pour modifier le format
- pour les labels: il suffit juste d'utiliser l'option LABEL de la proc print.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
 
 
proc datasets lib=work;
	modify college;
	format Gender $Genderfmt. SchoolSize $SchoolSizefmt. Scholarship $Scholarshipfmt.;
run;
quit;
proc print data=college label;
run;

Cordialement.
Youc

[Mathj]

Merci beaucoup!


J'ai trouvé une façon inspirer de la votre, mais qui utilisait les notions de mon cours. Je me demandait quel était la différence entre faire :

Vous:
proc datasets lib=work;
modify college;
format Gender $Genderfmt. SchoolSize $SchoolSizefmt. Scholarship $Scholarshipfmt.;
run;

ce que moi j'ai fait:
data collegefr;
set college;
format Gender $Genderfmt. SchoolSize $SchoolSizefmt. Scholarship $Scholarshipfmt.;
run;


Quel est la différence entre l'option modify et set ? Les deux fonctionnent mais je me si l'une est mieux que l'autre ou si c'est la même chose

[josef1980]

Bonsoir,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
 
proc datasets lib=work;/*-je donne le libname ou se trouve mes tables-*/
modify college;/*--je donne le nom de la table sur laquelle j'effectue des modifs sur la structure--*/
format Gender $Genderfmt. SchoolSize $SchoolSizefmt. Scholarship $Scholarshipfmt.;/*je change le format des variables, je peux biensur utiliser rename pour renommer des variables, je peux aussi modifier les labels des variables, biensur il n'y a pas que cela que vous pouvez faire avec proc datasets mais beaucoup d'autres chose*/
run;
 
https://support.sas.com/documentation/cdl/en/proc/61895/HTML/default/viewer.htm#a000393161.htm

La proc DATASETS agit que sur la partie descriptive des table (structure ) c'est à dire:
on peut changer les formats des variables, les labels, les nom des variables.
la table ne passe pas dans le le vecteur de travail (PDV).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
 
data collegefr;
set college;
format Gender $Genderfmt. SchoolSize $SchoolSizefmt. Scholarship $Scholarshipfmt.;
run;

Votre programme lit toute la table (il fait passer toute la table dans le veceteur de travail observation par observation.

L'avantage de proc datasets : c'est le temps d’exécution.
Proc datasets est avantageuse que data...;set....;

attention a ne pas confondre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
proc datasets lib=..;
modify nom_table;
...
run;

ce Programme modifie la structure de la table mais pas les données.
ET

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
DATA nomtab;
modify nomtab;
run;

le deuxième programme modifie les données de la table.

Cordialement.