Discussion :

[grenth]

Bonjour tous,

Voila je débute depuis vraiment peu en VBS et en faisant mes recherches je retombe souvent sur developpez.net et j'ai aussi appris sur le site.

Aujourd'hui je souhaite renommer mes comptes administrateurs via un script vbs, jusqu'ici rien de difficile mais sur certains serveurs j'ai "Administrateur" et d'autres "Administrator" et la je bute... alors ma partie de script sur le renommage (car mon script fait d'autre choses qui fonctionnent) j'ai écrit un truc un peu moche qui est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
On Error resume next
 
strComputer = objTextIn.ReadLine
strOldName = "Administrator"
strOldName2 = "Administrateur"
strNewName = "Localusr"	
set objComp = GetObject("WinNT://" & strComputer)
set objUser = GetObject("WinNT://" & strComputer & "/" & strOldName & ",user")
set objUser = GetObject("WinNT://" & strComputer & "/" & strOldName2 & ",user")
set objNewUser = objComp.MoveHere(objUser.ADsPath, strNewName)
 
On Error GoTo 0

Cependant je voudrais faire un script sans le "on error" genre quelque chose qui vérifie le nom si c'est "administrateur" ou "administrateur" et si le sid correspond à celui de l'administrateur alors il renomme en "localusr".

j’espère être explicite dans ma demande et vous remercie par avance de votre aide.

Grenth

[pitchalov]

Bonjour,

Ce Hey Scripting Guy indique comment récupérer le nom du compte Adminsitrateur Local.
Tu peux t'en servir de cette manière :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
' Get Computer Name
Set WshNetwork = CreateObject("WScript.Network")
strComputer = WshNetwork.ComputerName
 
' WMI method to get local Administrator user name
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
 
Set colAccounts = objWMIService.ExecQuery _
    ("Select * From Win32_UserAccount Where Domain = '" & strComputer & "'")
 
For Each objAccount in colAccounts
    If Left (objAccount.SID, 6) = "S-1-5-" and Right(objAccount.SID, 4) = "-500" Then
        strAdminLocalUserName = objAccount.Name
    End If
Next
 
'Rename the user
strNewName = "Localusr"	
set objUser = GetObject("WinNT://" & strComputer & "/" & strAdminLocalUserName & ",user")
set objNewUser = objComp.MoveHere(objUser.ADsPath, strNewName)

Bonne continuation

[pitchalov]

Encore mieux : tout faire en WMI :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Set WshNetwork = CreateObject("WScript.Network")
strComputer = WshNetwork.ComputerName
 
strNewName = "Localusr"	
 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
 
Set colAccounts = objWMIService.ExecQuery _
    ("Select * From Win32_UserAccount Where Domain = '" & strComputer & "'")
 
For Each objAccount in colAccounts
    If Left (objAccount.SID, 6) = "S-1-5-" and Right(objAccount.SID, 4) = "-500" Then
        strAdminLocalUserName = objAccount.Name
        objAccount.Rename strNewName 
    End If
Next

[grenth]

Salut,

Entre temps j'ai fais casi la meme chose en wmi. il me manquer ta ligne 13 et 14, je ne savais pas comment traduire donc merci beaucoup

Grenth

[grenth]

J'ai une dernière question:

Si je veux renommer mes administrateurs depuis une liste.txt avec:
Serveur1
Serveur2
Serveur3
...

Je suis bloquer.

Par exemple dans le code de Pitchalov, je souhaite ajouter quelques lignes genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
dim objTextIn
strInputPath = "D:\log vbs\Liste_serveurs.txt"
set objTextIn = objFSO.OpenTextFile( strInputPath,1 )
strComputer = objTextIn.ReadLine
 
...
 
loop

Pour pouvoir renommer les admins de la liste

[Miistik]

Bonjour,

Tu peux procéder de cette façon :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
'a la suite du début de ton code pour ouvrir un fichier
Data = objTextIn.ReadAll
objTextIn.Close 
 
'Tableau contenant chaque ligne de ton fichier
arrLines = Split(Data,vbCrLf)
 
'Parcours du contenu de ton fichier
For i = 0 To UBound(arrLines)
	strComputer = arrLines(i)
	'Ton code pour les renommer les admins
Next