Discussion :

[Kropernic]

Hello,

Voici une Sub d'un formulaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
    Private Sub btnFilter_Click(sender As Object, e As EventArgs) Handles btnFilter.Click
        Dim data = (From d In Promo.DTO.DetailsDemo
                    Select Id = d.Id, Department = d.CodeDemo.Department, CodeDemo = d.CodeDemo, Percentage = d.Percentage, Description = d.Description, Note = d.Note, ListType = d.ListType).Concat(
                    From d In Promo.DTO.DetailsDepartment
                    Select Id = d.Id, Department = d.Department, CodeDemo = CType(Nothing, PROMO_DTO.CodeDemo), Percentage = d.Percentage, Description = d.Description, Note = d.Note, ListType = d.ListType)
 
        If ckbDepartment.Checked Then
            data = (From d In data
                    Where d.Department.Id = CShort(cbDepartment.SelectedValue)
                    Select d)
        End If
 
        If ckbConcession.Checked Then
            data = (From d In data
                    Where d.CodeDemo.Id = CInt(cbConcession.SelectedValue)
                    Select d)
        End If
 
        If ckbPercent.Checked Then
            data = (From d In data
                    Where d.Percentage = nudPercent.Value
                    Select d)
        End If
 
        dgvDemo.DataSource = data.ToList
    End Sub

Ce que je cherche à faire est de déclarer data en tant que variable de classe histoire de pouvoir l'utiliser dans une autre Sub tout en gardant les filtres s'il y en a eu.

Par contre, il faut lui donner un type du coup à cette variable. Et c'est là que je coince. Aucune idée de ce qu'il faut mettre vu que c'est un type anonyme...

Je viens donc quémander des idées.

Merci d'avance !

[Pol63]

tu peux faire une classe avec toutes ces propriétés, et faire un select new machin with {... idem}
ta classe n'est plus anonyme mais au moins elle est utilisable

sinon faire une sub dans la sub (new action() sub () code end sub ())).invoke

[Kropernic]

J'aurais aimé pouvoir me passer de créer une classe de plus juste pour faire un affichage.

Pourrais-tu développer un peu plus ton histoire de sub dans une sub ?? J'ai pas bien compris (encore jamais fait ça).

Ou m'indiquer des mots clefs pour demander à google.

Sinon, je viens de trouver que, en C#, on peut utiliser le type Dynamic mais il n'y a apparemment pas d'équivalent en VB. C'est la première fois que je tombe sur un truc faisable en C# et pas en VB .

[mactwist69]

Au début Pol63 proposait de créer une classe contenant plutôt les filtre que l'objet en lui même. Ce qui revient au même.

Pas trop suivi sur le New Sub Invoke (il faudrait que je me penche dessus).

Sinon, à la question initiale, le type "mère" qui peut tout contenir est le type Object.

Si tu stockes un objet de type Type1 et que tu souhaites accéder a ses propriétés, alors il faudra faire un (Direct)Cast dessus pour qu'il l'objet retrouve son type d'origine.

[Kropernic]

Sauf que si je fais Dim data As Object, je vais pouvoir lui filer la query mais c'est mort pour appliquer les filtres après. Vu qu'il s'agit d'un type anonyme, hors de question de faire un cast .

[Kropernic]

Autre possibilité, parvenir à convertir data.ToList en BindingList ^^.

Vu qu'en fait c'est pour pouvoir faire des tris sur les colonnes d'un DataGridView, si je parviers à lui passer un objet qui implémente IBindingList, ça marche aussi. Et plus besoin de data en variable de classe dans ce cas.

Mais pareil que pour la question originelle, je sèche...

[worm83]

Hello,

Voici une Sub d'un formulaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
    Private Sub btnFilter_Click(sender As Object, e As EventArgs) Handles btnFilter.Click
        Dim data = (From d In Promo.DTO.DetailsDemo
                    Select Id = d.Id, Department = d.CodeDemo.Department, CodeDemo = d.CodeDemo, Percentage = d.Percentage, Description = d.Description, Note = d.Note, ListType = d.ListType).Concat(
                    From d In Promo.DTO.DetailsDepartment
                    Select Id = d.Id, Department = d.Department, CodeDemo = CType(Nothing, PROMO_DTO.CodeDemo), Percentage = d.Percentage, Description = d.Description, Note = d.Note, ListType = d.ListType)
 
        If ckbDepartment.Checked Then
            data = (From d In data
                    Where d.Department.Id = CShort(cbDepartment.SelectedValue)
                    Select d)
        End If
 
        If ckbConcession.Checked Then
            data = (From d In data
                    Where d.CodeDemo.Id = CInt(cbConcession.SelectedValue)
                    Select d)
        End If
 
        If ckbPercent.Checked Then
            data = (From d In data
                    Where d.Percentage = nudPercent.Value
                    Select d)
        End If
 
        dgvDemo.DataSource = data.ToList
    End Sub

Ce que je cherche à faire est de déclarer data en tant que variable de classe histoire de pouvoir l'utiliser dans une autre Sub tout en gardant les filtres s'il y en a eu.

Par contre, il faut lui donner un type du coup à cette variable. Et c'est là que je coince. Aucune idée de ce qu'il faut mettre vu que c'est un type anonyme...

Je viens donc quémander des idées.

Merci d'avance !

La définition d'un type anonyme est justement que celui-ci n'est connu que dans le scope de la fonction ou il est déclarer. Sinon ce n'est plus un type anonyme. Tu ne peux pas faire ce que tu demande, c'est sa définition même.

en revanche tu peux faire de la réfléxion ou utiliser un type dynamic.

[Kropernic]

Hello,

J'ai finalement résolu mon souci comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
    Private _dicFilter As Dictionary(Of Filter, Decimal)
    Private Enum Filter As Integer
        Department = 1
        Demo = 2
        Percent = 3
    End Enum
 
    Private Sub btnFilter_Click(sender As Object, e As EventArgs) Handles btnFilter.Click
        _dicFilter = New Dictionary(Of Filter, Decimal)
 
        If ckbDepartment.Checked Then
            _dicFilter.Add(Filter.Department, CShort(cbDepartment.SelectedValue))
        End If
 
        If ckbConcession.Checked Then
            _dicFilter.Add(Filter.Demo, CInt(cbConcession.SelectedValue))
        End If
 
        If ckbPercent.Checked Then
            _dicFilter.Add(Filter.Percent, nudPercent.Value)
        End If
 
        FilterAndSortData(_dicFilter)
    End Sub
 
    Private Sub FilterAndSortData(filters As Dictionary(Of Filter, Decimal), Optional ByVal PropertyToSort As String = Nothing, Optional ByVal sortorder As SortOrder = Nothing)
        Dim data = (From d In Promo.DTO.DetailsDemo
                   Select Id = d.Id, Department = d.CodeDemo.Department, CodeDemo = d.CodeDemo, Percentage = d.Percentage, Description = d.Description, Note = d.Note, ListType = d.ListType).Concat(
                   From d In Promo.DTO.DetailsDepartment
                   Select Id = d.Id, Department = d.Department, CodeDemo = CType(Nothing, PROMO_DTO.CodeDemo), Percentage = d.Percentage, Description = d.Description, Note = d.Note, ListType = d.ListType)
 
        If Not IsNothing(filters) Then
            For Each key As Filter In filters.Keys
                Select Case key
                    Case Filter.Department
                        data = (From d In data
                                Where d.Department.Id = _dicFilter(key)
                                Select d)
                    Case Filter.Demo
                        data = (From d In data
                                Where d.CodeDemo.Id = _dicFilter(key)
                                Select d)
                    Case Filter.Percent
                        data = (From d In data
                                Where d.Percentage = _dicFilter(key)
                                Select d)
                End Select
            Next
        End If
 
 
        If Not IsNothing(PropertyToSort) Then
            If sortorder = Windows.Forms.SortOrder.Ascending Then
                Select Case PropertyToSort
                    Case "Department"
                        data = data.OrderBy(Function(x) x.Department.Code)
                    Case "CodeDemo"
                        data = data.OrderBy(Function(x) x.CodeDemo.Code)
                    Case "Percentage"
                        data = data.OrderBy(Function(x) x.Percentage)
                    Case "Description"
                        data = data.OrderBy(Function(x) x.Description)
                    Case "Note"
                        data = data.OrderBy(Function(x) x.Note)
                    Case "ListType"
                        data = data.OrderBy(Function(x) x.ListType)
                End Select
            ElseIf sortorder = Windows.Forms.SortOrder.Descending Then
                Select Case PropertyToSort
                    Case "Department"
                        data = data.OrderByDescending(Function(x) x.Department.Code)
                    Case "CodeDemo"
                        data = data.OrderByDescending(Function(x) x.CodeDemo.Code)
                    Case "Percentage"
                        data = data.OrderByDescending(Function(x) x.Percentage)
                    Case "Description"
                        data = data.OrderByDescending(Function(x) x.Description)
                    Case "Note"
                        data = data.OrderByDescending(Function(x) x.Note)
                    Case "ListType"
                        data = data.OrderByDescending(Function(x) x.ListType)
                End Select
            End If
        End If
 
        dgvDemo.DataSource = data.ToList
    End Sub
 
    Private Sub dgvDemo_ColumnHeaderMouseClick(sender As Object, e As DataGridViewCellMouseEventArgs) Handles dgvDemo.ColumnHeaderMouseClick
        Dim order As SortOrder = dgvDemo.Columns(e.ColumnIndex).HeaderCell.SortGlyphDirection
        If order = SortOrder.None OrElse order = SortOrder.Descending Then
            FilterAndSortData(_dicFilter, dgvDemo.Columns(e.ColumnIndex).DataPropertyName, SortOrder.Ascending)
            dgvDemo.Columns(e.ColumnIndex).HeaderCell.SortGlyphDirection = SortOrder.Ascending
        Else
            FilterAndSortData(_dicFilter, dgvDemo.Columns(e.ColumnIndex).DataPropertyName, SortOrder.Descending)
            dgvDemo.Columns(e.ColumnIndex).HeaderCell.SortGlyphDirection = SortOrder.Descending
        End If
    End Sub

[Pol63]

de toute façon tant qu'on reste dans du code trop concret on est obligé d'y rester (ca ne veut rien dire )