Discussion :

[Cybercope]

Bonjour,

J' aimerais écrire un VBS qui crée un dossier ou un fichier dans un endroit voulu.
J' imagine qu' il faut crée un objet. Mais je ne sais pas comment l' interpréter/l' utiliser pour cette fonction

Merci de votre aide !

Ind6x

[hackoofr]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Option Explicit
Dim FolderTest,Folder1,Folder2,Folder3,Folder4
Dim Fichier1,Fichier2,Fichier3,Fichier4,Fichier5,Fichier6,Fichier7,Fichier8,Fichier9,Fichier10
FolderTest = "C:\MonDossierTest"
Folder1 = "DossierTest1"
Folder2 = "DossierTest2"
Folder3 = "DossierTest3"
Folder4 = "DossierTest4"
Fichier1 = "FichierTest1.txt"
Fichier2 = "FichierTest2.doc"
Fichier3 = "FichierTest3.xls"
Fichier4 = "FichierTest4.ppt"
Fichier5 = "FichierTest5.mp3"
Fichier6 = "FichierTest6.jpg"
Fichier7 = "FichierTest7.gif"
Fichier8 = "FichierTest8.png"
Fichier9 = "FichierTest9.mpg"
Fichier10 = "FichierTest10.mp4"
'**************************Création des Dossiers tests*******************************************
Call SmartCreateFolder(FolderTest)
Call SmartCreateFolder(FolderTest & "\" & Folder1)
Call SmartCreateFolder(FolderTest & "\" & Folder2)
Call SmartCreateFolder(FolderTest & "\" & Folder3)
Call SmartCreateFolder(FolderTest & "\" & Folder4)
'**************************Création des fichiers tests*******************************************
Call SmartCreateFile(FolderTest & "\" & Fichier1)
Call SmartCreateFile(FolderTest & "\" & Fichier2)
Call SmartCreateFile(FolderTest & "\" & Fichier3)
Call SmartCreateFile(FolderTest & "\" & Fichier4)
Call SmartCreateFile(FolderTest & "\" & Fichier5)
Call SmartCreateFile(FolderTest & "\" & Fichier6)
Call SmartCreateFile(FolderTest & "\" & Fichier7)
Call SmartCreateFile(FolderTest & "\" & Fichier8)
Call SmartCreateFile(FolderTest & "\" & Fichier9)
Call SmartCreateFile(FolderTest & "\" & Fichier10)
'*************************************************************************************************
'Fonctions pour créer des dossiers et des fichiers
'*************************************************************************************************
Sub SmartCreateFolder(strFolder)
      Dim oFSO:Set oFSO = CreateObject("Scripting.FileSystemObject")
      If oFSO.FolderExists(strFolder) Then
          Exit Sub
      Else
          SmartCreateFolder(oFSO.GetParentFolderName(strFolder))
      End If
      oFSO.CreateFolder(strFolder)
      Set oFSO = Nothing    
  End Sub
  '*********************************************************************************
 Sub SmartCreateFile(File)
      Dim oFSO:Set oFSO = CreateObject("Scripting.FileSystemObject")
      If oFSO.FileExists(File) Then
          Exit Sub
      Else
      oFSO.CreateTextFile(File)
      Set oFSO = Nothing   
      End if
  End Sub
  '**********************************************************************************

[Cybercope]

Meci bc

[hackoofr]

Meci bc

Après 10 jours je vais vous répondre "pas de quoi"
Donc, si le problème est résolu, alors pensez à cliquer sur le bouton en bas et pour l'encouragement pensez à ce bouton +1
Cordialement !