copier un répertoire "inconnu"

**MIKKA** · 15/01/2014, 15h51

Bonjour,

J'aimerais savoir s'il est possible de copier un répertoire dont je ne connais pas le nom complet ?
Je sais que c'est un répertoire sous C:\ et qu'il commence par "Donnees"

En gros c'est C:\Donnees_machinTruc ou C:\Donnees2013, etc.

j'ai essayé en ligne de commande, en faisant un copy C:\Donnees* mais bien sur ça marche pas... j'ai essayé pleins de bidouilles mais comme je ne suis pas développeur je ne trouve pas comment faire !

y'a t'il une âme charitable pour m'orienter ? j'aimerais que ce soit un bat ou vbs, pour pouvoir le lancer automatiquement à l'ouverture de la session....

Merci d'avance

**l_autodidacte** · 18/01/2014, 15h24

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 Option Explicit
 Dim fso, Fold, subFold, NewLocation
 
 Set fso = CreateObject("Scripting.FileSystemObject")
 NewLocation = "D:\NewFolder\"
 Set Fold = fso.GetFolder("C:\")
	For Each subFold in Fold.SubFolders
	   If Left(subFold.Name, 7) ="Donnees" Then
		subFold.Copy NewLocation
	   End If
	Next
Set Fold = Nothing
Set fso = Nothing

**Menhir** · 20/01/2014, 12h48

Je ne connais pas VBScript mais en VBA, j'airais écrit un truc
Variable1 = Dir("C:\Données*")

Ensuite tu vérifie si le nom que tu as récupéré est bien un répertoire et non un fichier.
Et il ne te reste plus qu'à le copier.

S'il est possible qu'il y ait plusieurs répertoires commençant par "Données", tu peux mettre un Dir() dans une boucle Do Until pour les traiter tous.

**ProgElecT** · 20/01/2014, 13h27

Salut

Envoyé par Menhir

Je ne connais pas VBScript mais en VBA, j'airais écrit un truc
Variable1 = Dir("C:\Données*")...........

Pour un .bat Ok, mais VBScrit ne connait pas cette commande.

Envoyé par Menhir

S'il est possible qu'il y ait plusieurs répertoires commençant par "Données", tu peux mettre un Dir() dans une boucle Do Until pour les traiter tous. ...........

problème, la boucle Do ...n'est pas reconnu dans un .bat.

L'approche proposé par l_autodidacte me semble la plus judicieuse.

**MIKKA** · 23/01/2014, 16h41

Merci à vous pour vos réponses
j'ai testé le script vbs...il ne se passe rien...
j'ai portant remplacé avec mes valeurs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Option Explicit
 Dim fso, Fold, subFold, NewLocation
 
 Set fso = CreateObject("Scripting.FileSystemObject")
 NewLocation = "E:\SaveDonnees"
 Set Fold = fso.GetFolder("C:\")
	For Each subFold in Fold.SubFolders
	   If Left(subFold.Name, 7) ="Donnee*" Then
		subFold.Copy NewLocation
	   End If
	Next
Set Fold = Nothing
Set fso = Nothing

Par ailleurs en attendant vos réponses j'avais essayé un script dos :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
set liste_rep=liste_rep.txt
%systemdrive%
DIR /B /AD c:\Donnees* > %liste_rep%
FOR /F %%i in (%liste_rep%) do xcopy c:\%%i \\Serveur\partage\%username%\%%i /D /E /C /R /H /I /K /Y

Ça fonctionne pas mal sauf pour les fichiers contenant un espace...

Donc si vous savez pourquoi le vbs ne fonctionne pas, très bien
sinon peut être que vous avez la réponse pour mon .bat

Merci encore

**l_autodidacte** · 23/01/2014, 18h00

Salut,
Il faut faire attention au Copier/Coller :If Left(subFold.Name, 7) ="Donnee*" Then à remplacer par :
If Left(subFold.Name, 7) ="Donnees" Then car les caractères génériques ne sont pas reconnues dans ce code.
Si les noms des dossiers en question ne commencent pas par "Donnees", tu n'auras pas de traitement possible.

**MIKKA** · 24/01/2014, 10h48

Envoyé par l_autodidacte

Salut,
Il faut faire attention au Copier/Coller :If Left(subFold.Name, 7) ="Donnee*" Then à remplacer par :
If Left(subFold.Name, 7) ="Donnees" Then car les caractères génériques ne sont pas reconnues dans ce code.
Si les noms des dossiers en question ne commencent pas par "Donnees", tu n'auras pas de traitement possible.

super ça marche impec avec un chemin de destination statique

En revanche si je veux envoyer sur un lecteur réseau avec une variable windows
"\\serveur\migration\%username%\", comment faire ?

je crois qu'il faut utiliser oShell.ExpandEnvironmentStrings("%UserName%") mais je ne maitrise pas du tout...
si quelqu'un peut m'aider ça serait cool

merci

**MIKKA** · 24/01/2014, 17h09

J'ai réussi à passer le username en paramètre !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 Dim fso, Fold, subFold, NewLocation, WshNet, User
 
 Set WshNet = CreateObject("WScript.Network") 
 User = WshNet.Username
 Set fso = CreateObject("Scripting.FileSystemObject")
 NewLocation = "\\server\migration\" & User & "\"
 Set Fold = fso.GetFolder("C:\")
	For Each subFold in Fold.SubFolders
	   If Left(subFold.Name, 7) ="donnees" Then
		subFold.Copy NewLocation
	   End If
	Next
Set Fold = Nothing
Set fso = Nothing

Si je voulais mettre un caractère inconnu au début de "donnees", comment pourrait-on faire ?
par exemple si le répertoire s'appelle c:\A_donnees au lieu de c:\donnees

Merci

**l_autodidacte** · 24/01/2014, 23h41

La ligne 10 devient : If LCase(Mid(subFold.Name, 2,7)) ="donnees" Then dans le cas d'un seul caractère et/ou
If LCase(Mid(subFold.Name, 3,7)) ="donnees" Then pour 2 caractères ajoutés au début de "donnees".
Avec LCase, tu n'as pas le souci de la casse(Minuscule ou majuscule).

[EDIT]Il y a aussi cette possibilité sans avoir à préciser le nombre de caractères avant la séquence "donnees" :
If InStr(LCase(subFold.Name),"donnees") > 0 Then
A toi de choisir celle qui te convient.

**MIKKA** · 25/01/2014, 18h55

Envoyé par l_autodidacte

La ligne 10 devient : If LCase(Mid(subFold.Name, 2,7)) ="donnees" Then dans le cas d'un seul caractère et/ou
If LCase(Mid(subFold.Name, 3,7)) ="donnees" Then pour 2 caractères ajoutés au début de "donnees".
Avec LCase, tu n'as pas le souci de la casse(Minuscule ou majuscule).

[EDIT]Il y a aussi cette possibilité sans avoir à préciser le nombre de caractères avant la séquence "donnees" :
If InStr(LCase(subFold.Name),"donnees") > 0 Then
A toi de choisir celle qui te convient.

merci beaucoup ça marche super bien !

**MIKKA** · 25/01/2014, 19h24

une dernière question
comment faire pour ne pas recopier les fichiers s'ils sont déjà dans le répertoire de destination ?
si c'est possible simplement....

merci

**MIKKA** · 25/01/2014, 20h50

je me suis réjouie trop vite, ça marche sur Seven mais pas sur XP....
je le lance via une gpo et il ne se passe rien... la gpo s'arrête sur time out...
j'ai tenté de lancer le vbs dans un bat avec cscript, idem

**l_autodidacte** · 25/01/2014, 22h23

comment faire pour ne pas recopier les fichiers s'ils sont déjà dans le répertoire de destination ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 Dim fso, Fold, subFold, NewLocation, WshNet, User, FL, newFold 
 
 Set WshNet = CreateObject("WScript.Network") 
 User = WshNet.Username
 Set fso = CreateObject("Scripting.FileSystemObject")
 NewLocation = "\\server\migration\" & User & "\"
 
Set Fold = fso.GetFolder("C:\")
	For Each subFold in Fold.SubFolders
	   If InStr(LCase(subFold.Name), "donnees") > 0 Then
	      VerifDestFolder NewLocation & subFold.Name
		  For Each FL In subFold.Files ' on parcourt les fichiers dans chaque dossier
			 If Not fso.FileExists(NewLocation & subFold.Name & "\" & FL.Name) Then
			    FL.Copy NewLocation & subFold.Name & "\" & FL.Name
			 End If
		  Next	
	   End If
	Next
' ======== Vérification de l'existence du dossier sinon le créer =========
Sub VerifDestFolder(strFold)
    If Not fso.FolderExists(strFold) Then
	Set newFold = fso.CreateFolder(strFold)
    Else
        Exit Sub
    End If
End Sub

**MIKKA** · 26/01/2014, 11h23

génial merci pour la réponse un dimanche

je teste ce soir ou demain

**MIKKA** · 26/01/2014, 22h17

j'abuse encore un peu...
et si je voulais sauver 2 répertoires, comment faire ?

merci beaucoup

**l_autodidacte** · 26/01/2014, 22h26

et si je voulais sauver 2 répertoires, comment faire ?

Je ne vois pas ce que tu veux faire exactement.
Explique un peu.

**MIKKA** · 26/01/2014, 22h38

Envoyé par MIKKA

je me suis réjouie trop vite, ça marche sur Seven mais pas sur XP....
je le lance via une gpo et il ne se passe rien... la gpo s'arrête sur time out...
j'ai tenté de lancer le vbs dans un bat avec cscript, idem

j'ai rien dit

**MIKKA** · 26/01/2014, 22h45

Envoyé par l_autodidacte

Je ne vois pas ce que tu veux faire exactement.
Explique un peu.

et bien j'ai un répertoire c:\donnees et un autre c:\archives
j'aimerais sauvegarder les 2

**l_autodidacte** · 26/01/2014, 23h13

Pour C:\Donnees le Script précédent fera l'affaire sans rien modifier.
Pour C:\Archives, il suffit de remplacer dans le script précédent "donnees" par "archives"
Ou tout simplement tu peux remplacer la ligne 11 par :
If InStr(LCase(subFold.Name), "donnees") > 0 Or InStr(LCase(subFold.Name), "archives")> 0 Then.

Ce code reste valable si tu veux sauvegarder les 2 dossiers dans le même répertoire(sur le lecteur réseau).

**MIKKA** · 27/01/2014, 20h11

Envoyé par l_autodidacte

Pour C:\Donnees le Script précédent fera l'affaire sans rien modifier.
Pour C:\Archives, il suffit de remplacer dans le script précédent "donnees" par "archives"
Ou tout simplement tu peux remplacer la ligne 11 par :
If InStr(LCase(subFold.Name), "donnees") > 0 Or InStr(LCase(subFold.Name), "archives")> 0 Then.

Ce code reste valable si tu veux sauvegarder les 2 dossiers dans le même répertoire(sur le lecteur réseau).

me suis mal exprimé, je voudrais sauvegarder les 2 répertoires en même temps, dans le même script

copier un répertoire "inconnu"

VBScript

Partager

Partager