Problème avec XML particulier

**m.greg13** · 25/11/2013, 13h39

Bonjour a tous, voila j'ai sur un mon programme besoin de lire des fichiers XML dont la structure est fixe mais particulière

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
<test>
	<sec1>
		<info name="test" url="http://www.developpez.net" />
		<info2> d: </info2>
	</sec1>
</test>

Dans le cas d'une structure simple " <info2> d: </info2> " aucun problème pour lire l'information mais dans le cas de
la première ligne je ne trouve pas comment le lire d'autant que j'ai plusieurs information a lire ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Dim MonXML As XDocument = XDocument.Load("E:\test.xml")
 
        MsgBox(MonXML.<test>.<sec1>.<info2>.Value())
        MsgBox(MonXML.<test>.<sec1>.<info1>.Value())

Merci d'avance pour votre aide
Bye

**calagan99** · 25/11/2013, 14h21

Les "éléments" dont tu parles sont des attributs de tes noeuds.
Tu peux récupérer le contenu de ces attributs en utilisant la fonction Attributede ton XElement.

Plus d'infos sur le MSDN

**m.greg13** · 25/11/2013, 15h25

Salut, merci pour l'information

Par contre je comprend pas comment l'utiliser car j'ouvre avec XDocument j'ai donc tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim MonXML As XDocument = XDocument.Load("E:\xml.xml")
        MsgBox(MonXML.<test>.<sec1>.<info1>.Attributes("name"))

mais ça me repond :

L'argument 'Prompt' ne peut pas être converti en type 'String'.

J'ai essayer d'ouvrir mon fichier avec XElement mais ça ne marche pas non plus, j'ai essayer avec le "Dim att As XAttribute" de MSDN mais aucune resultat

**calagan99** · 25/11/2013, 17h34

Décris plus précisément ce que tu veux faire de ce XML:
- le parcourir pour stocker tous ces éléments dans une collection d'objets ?
- trouver un noeud en particulier ?

Sans cela, difficile de te répondre.

**m.greg13** · 25/11/2013, 21h36

Je connais d'avance la structure donc pas besoin de chercher, ce que je veut c'est juste lire les différente variable dans différent XML des fois entre <> </> ( qui ne pose pas de problème ) et d'autre < blabla="bla" /> ( qui eux prose problème ...

Les variables vont toute être stocké dans une structure de string être afficher dans une textbox et pourront être modifier par l'utilisateur ( l'l’écriture sera dans une autre Function ( on verra plus tard XD )

Mercii :>

**chrismonoye** · 26/11/2013, 10h57

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MonXML.<test>.<sec1>.<info1>.Attributes("name")

Retourne une collection filtrée des attributs de chaque élément de la collection source. Seuls les éléments avec un XName correspondant sont inclus dans la collection. (Dixit MSDN).
Une collection ne peut pas être convertie en type 'String', On peut accéder à ce qu'elle contient par un For Each :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
        '*** IEnumerable(Of XAttribute) de XElement qui contient la collection source.
        Dim attList As IEnumerable(Of XAttribute) = MonXML.<test>.<sec1>.<info1>.Attributes()
        For Each att In attList
            MsgBox(att)
        Next

Si il s'agit d'un élément bien précis, le plus simple est de suivre les conseils de calagan99, genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox(MonXML.<test>.<sec1>.<info1>.FirstOrDefault.Attribute("name"))

**m.greg13** · 27/11/2013, 13h21

Salut, merci beaucoup sa marche a merveille sur mon fichier de test mais pas sur mon XML ...

Donc plus simple mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim MonXML As XDocument = XDocument.Load("E:\container.xml")
MsgBox(MonXML.<container>.<rootfiles>.<rootfile>.FirstOrDefault.Attribute("full-path"))

et mon XML qui provient d'un Ebook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
<?xml version="1.0"?>
<container version="1.0" xmlns="urn:oasis:names:tc:opendocument:xmlns:container">
   <rootfiles>
      <rootfile full-path="content.opf" media-type="application/oebps-package+xml"/>
 
   </rootfiles>
</container>

il me renvoie :

Une exception non gérée du type 'System.NullReferenceException' s'est produite dans Simply Kobo transfert.exe

donc je comprend qu'il trouve pas mais ne comprend pas pourquoi il trouve pas.

et le prochain XML plus simple ne marche pas non plus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
<package xmlns="http://www.idpf.org/2007/opf" version="2.0" unique-identifier="uuid_id">
	<metadata xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:opf="http://www.idpf.org/2007/opf" xmlns:dcterms="http://purl.org/dc/terms/" xmlns:calibre="http://calibre.kovidgoyal.net/2009/metadata" xmlns:dc="http://purl.org/dc/elements/1.1/">
		<dc:creator opf:role="aut" opf:file-as="Link, Charlotte">Link, Charlotte</dc:creator>
		<dc:publisher>Presses de la Cité</dc:publisher>
		<dc:description>&lt;div&gt;&lt;div&gt;Publié en France : 07/03/2013&lt;div&gt;&lt;br&gt;&lt;/div&gt;&lt;div&gt;&lt;div&gt;Gillian Ward mène une existence apparemment sans histoire avec sa famille. Une vie parfaite aux yeux de Samson Segal, un habitant du quartier. Obsédé par Gillian, ce marginal passe ses journées à la suivre et à épier ses moindres faits et gestes. Il l’aime de loin, mais avec une totale dévotion.&lt;/div&gt;&lt;div&gt;Au même moment, une série de meurtres inquiète les Londoniens. Les victimes, des femmes seules, sont sauvagement assassinées après avoir subi plusieurs semaines d’intimidation. La police ne tarde pas à porter ses soupçons sur Samson, le guetteur. Gillian est-elle en danger?&lt;/div&gt;&lt;/div&gt;&lt;/div&gt;&lt;div&gt;&lt;br&gt;&lt;/div&gt;&lt;/div&gt;</dc:description>
		<dc:title>Une femme surveillée</dc:title>
		<dc:date>2011-12-03T00:00:00+00:00</dc:date>
		<dc:contributor opf:role="bkp">calibre (0.9.30) [http://calibre-ebook.com]</dc:contributor>
		<dc:identifier opf:scheme="ISBN">9782258093430</dc:identifier>
		<dc:identifier id="uuid_id" opf:scheme="uuid">4c85bde4-6704-4737-8b49-6429821167a5</dc:identifier>
		<dc:subject>Policier</dc:subject>
		<dc:language>fr</dc:language>
		<dc:identifier opf:scheme="calibre">4c85bde4-6704-4737-8b49-6429821167a5</dc:identifier>
	</metadata>

J'ai fait une lecture simple mais sa ne marche pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Imports <xmlns:dc="http://purl.org/dc/elements/1.1/">
MsgBox(SecBookXML.<package>.<metadata>.<dc:title>.Value)

Par avance merci de votre aide car si ça continue je vais faire une lecture ligne a ligne avec des Mid et Instr lol

**Jabbal'H** · 27/11/2013, 14h33

Met plus de détail sur les erreurs que tu as ainsi que la ou les lignes posant problèmes et les traitements associés.

**m.greg13** · 27/11/2013, 18h15

Salut donc pour le premier fichier c'est déjà indiqué et sur le second j'ai pas d'erreur juste une réponse vide ...

Merci

**chrismonoye** · 27/11/2013, 22h41

Bonsoir,
à tester
pour le premier fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
        Dim containerXML As XDocument = XDocument.Load("container.xml")
        Dim aw As XNamespace = containerXML.Root.Name.Namespace
 
        MsgBox(containerXML.Descendants(aw + "rootfile").FirstOrDefault.Attribute("full-path").Value)

pour le second :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
        Dim SecBookXML As XDocument = XDocument.Load("package.xml")
        Dim np As XNamespace = SecBookXML.Root.Name.Namespace
 
        MsgBox(SecBookXML.Descendants(np + "metadata").Elements(GetXmlNamespace(dc) + "title").Value)

**m.greg13** · 28/11/2013, 08h33

Salut merci ta solution marche a merveille dans les deux cas

Si je comprend bien le code il cherche la première valeur qui correspond dans le sens descendant c'est ça ? si je renouvelle cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SecBookXML.Descendants(np + "metadata").Elements(GetXmlNamespace(dc) + "title").Value

il me donne le prochain ?

enfin en tout cas merci beaucoup

**chrismonoye** · 28/11/2013, 12h53

Oui c'est ça il prend le premier trouvé.
Pour les avoir tous je ferais plutôt une collection du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
        Dim CollectionBooks = From xElem In SecBookXML.Descendants(np + "metadata").Elements(GetXmlNamespace(dc) + "title") _
           Select xElem
 
        For Each bk In CollectionBooks
            MsgBox(bk.Value)
        Next

A voir.

**m.greg13** · 28/11/2013, 13h11

Merci beaucoup

**m.greg13** · 30/11/2013, 14h39

Voila mon code source qui marche parfaitement mais si vous voyez des optimisation a faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
        ' Définitions des variables
        Dim Path As String
        Dim ID As String
        Dim Result As Integer
        Dim SplitLine As String()
 
        ' Ouverture du premier fichier
        Dim containerXML As XDocument = XDocument.Load(TempDir & "META-INF\container.xml")
        Dim CX As XNamespace = containerXML.Root.Name.Namespace
 
        ' Récupération du lien du second fichier avec remplacement des / par des \ ( pour Windows )
        Path = Replace(containerXML.Descendants(CX + "rootfile").FirstOrDefault.Attribute("full-path").Value, "/", "\")
 
        ' Ouverture du second fichier
        Dim ContentOPF As XDocument = XDocument.Load(TempDir & Path)
        Dim CO As XNamespace = ContentOPF.Root.Name.Namespace
 
        'Lecture des informations sur le livre et ecriture dans les variables 
        Ebook.Titre = ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "title").Value
        Ebook.Auteur = ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "creator").Value
        Ebook.Editeur = ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "publisher").Value
        Ebook.DatePubliction = ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "date").Value
        Ebook.Langue = ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "language").Value
        Ebook.Description = ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "description").Value
 
        ' On cherche les 2 ID
        Dim Allidentifier = From xElem In ContentOPF.Descendants(CO + "metadata").Elements(GetXmlNamespace(dc) + "identifier") Select xElem
        For Each Identifier In Allidentifier
            ID = Identifier.Attribute(GetXmlNamespace(opf) + "scheme")
            If ID = "ISBN" Then
                Ebook.ISBN = Identifier.Value
            ElseIf ID = "uuid" Then
                Ebook.UUID = Identifier.Value
            End If
        Next
 
        Result = InStrRev(Path, "\") 'On recherche le dernier \
        If Result Then Path = Mid(Path, 1, Result) Else Path = ""
        ' Si on trouve on coupe la variable ( on enleve juste le nom du premier fichier et on recupere le(s) dossier(s)
        ' On lance la recherche de l'image de couverture du livre ( un vrai bordel ^^ )
        Dim AllManifestItem = From xElem In ContentOPF.Descendants(CO + "manifest").Elements(CO + "item") Select xElem
        For Each Item In AllManifestItem
            If Item.Attribute("id") = "cover" And Item.Attribute("media-type") = "image/jpeg" Then ' Si l'id = corver et le type de fichier = image = Jackpot
 
                Ebook.CouverturePath = Path & Replace(Item.Attribute("href").Value, "/", "\") ' On recupere le chemin de l'image
                Exit For ' et on quitte la boucle
 
            ElseIf Item.Attribute("id") = "cover" And Item.Attribute("media-type") = "application/xhtml+xml" Then
 
                Dim Html As String() = File.ReadAllLines(TempDir & Path & Item.Attribute("href").Value) ' Ouverture du fichier html
                For Each Line In Html    ' pour chaque ligne
                    If InStr(Line, "<img") Then ' si elle contient <img
                        SplitLine = Split(Line, """") 'on la coupe par les "
                        For boucle = 0 To SplitLine.Length - 1 'debut de la boucle
                            If InStr(SplitLine(boucle), "src=") Then ' si la ligne contient  "Str"
                                Ebook.CouverturePath = Path & SplitLine(boucle + 1) ' on recupere le nom du fichier est remplie la variable 
                                Exit For
                            End If
                        Next
                        Exit For
                    End If
                Next
                Exit For
 
            ElseIf Item.Attribute("media-type") = "image/jpeg" Then
 
                If IsNothing(Ebook.CouverturePath) Then Ebook.CouverturePath = Path & Replace(Item.Attribute("href").Value, "/", "\")
                If InStr(Item.Attribute("id"), "cover") <> 0 Then
                    Ebook.CouverturePath = Path & Replace(Item.Attribute("href").Value, "/", "\")
                    Exit For
                End If
 
            End If
        Next

D'avance merci a tous et encore merci pour l'aide que vous m'avez apporter

Problème avec XML particulier

VB.NET

Discussions similaires

Partager

Partager