Déclenchement son sur événement

**jobar38** · 30/05/2013, 12h30

Bonjour,

je suis débutant et je me lance dans une petite interface en html qui est en local sur mon PC.

je souhaite déclencher une alarme sur présence d'un objet.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

IF (document.getElementById('Alarme').innerHTML = '!' ) {Alors je déclenche une alarme sonore!;}

Je ne veux pas faire apparaitre de lecteur. Certains disent que ce n'est pas possible ,d'autres que si!

Faut-il que je passe par un javascript exterieur?faut-il que je crée une fonction directement dans ma page?

Pouvez-vous m'aider car je suis perdu!

**hackoofr** · 31/05/2013, 11h18

ceci peut-être réalisé avec un HTA = HTML Application en utilisant la balise <bgsound> qui est compatible avec IE seulement
je n'ai sais pas s'il y a d'autres exemples plus pertinents

**hackoofr** · 31/05/2013, 12h30

Peut-être ceci vous donne une petite idée, peut-être non

ceci avec Vbscript dans un HTA : compatible seulement avec Internet Explorer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
<html>
<HTA:APPLICATION  
APPLICATIONNAME="Déclenchement son sur evenement"  
ICON="Explorer.exe"    
SELECTION="no"/> 
<title>Déclenchement son sur evenement</title>
<SCRIPT Language="VBScript">
Sub Window_onLoad
    Dim STRHTML,NomMachine,NomUtilisateur
    Set Ws = CreateObject("WScript.Shell")
    Set ProcessEnv = Ws.Environment("Process")
    NomMachine = ProcessEnv("COMPUTERNAME") 
    NomUtilisateur = ProcessEnv("USERNAME")
    STRHTML ="<br><br><font color=""Red""><b><H1>PC : "& NomMachine &" connecté en tant que " & NomUtilisateur &"</H1></b></font>"
    STRHTML = STRHTML & "<bgsound src="&ListMusic(1)&" loop=""infinite"">"
    MaMusic.InnerHTML = STRHTML
End Sub 
Sub ChargerMusic(X) 
    Dim STRHTML
    STRHTML ="<br>"
    STRHTML = STRHTML & "<bgsound src="&ListMusic(X)&" loop=""infinite"">"
    MaMusic.InnerHTML = STRHTML
End Sub 
 
Function ListMusic(Element)
    Dim URL(8)
    Dim Chemin
    Chemin = "e:\music\"
    URL(1) = Chemin & "Kalimba.mp3"
    URL(2) = Chemin & "Maid.mp3"
    URL(3) = Chemin & "Sleepy Away.mp3"
    URL(4) = Chemin & "Pitbull.mp3"
    URL(5) = Chemin & "mydream.mp3"
    URL(6) = Chemin & "Rihanna.mp3"
    URL(7) = Chemin & "feeling.mp3"
    URL(8) = Chemin & "lavie.mp3"
    ListMusic=qq(URL(Element))
'MsgBox ListMusic
End Function
 
Function qq(str)
    qq=Chr(34)& str &Chr(34)
End Function
 
Sub StopMusic()
    MaMusic.InnerHTML = ""
End Sub
</script>
<body><center>
<input type=Button  OnClick="ChargerMusic(1)" Value=" Kalimba ">
<input type=Button  OnClick="ChargerMusic(2)" Value="Maid">
<input type=Button  OnClick="ChargerMusic(3)" Value="Sleepy Away">
<input type=Button  OnClick="ChargerMusic(4)" Value="Pitbull">
<input type=Button  OnClick="ChargerMusic(5)" Value="Dream">
<input type=Button  OnClick="ChargerMusic(6)" Value="Rihanna ">
<input type=Button  OnClick="ChargerMusic(7)" Value=" Feeling">
<input type=Button  OnClick="ChargerMusic(8)" Value=" CLa Vie">
<span id ="MaMusic"></span><br><INPUT TYPE="Button" style="font-weight: bold" VALUE="Arrêter La Musique" ONCLICK="StopMusic"><br><br>
<div><img src="http://www.developpez.net/template/images/logo.png" style="cursor:hand;" alt="image" onmouseover='ChargerMusic(1)' onmouseout='StopMusic' ></div>
</body>
</html>

**nicosmash** · 31/05/2013, 14h43

Bonjour,

Vous pouvez également le faire en JS :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
function lireSon(numero)
{
	gestionSon=document.getElementById('gestionSon');
	gestionSon.type="audio/wave";
	soundfile=(libsoundWAV[numstyle])?libsoundWAV[numstyle]:"toto.wav"
	gestionSon.src="http://..."+soundfile;
	gestionSon.load();
	gestionSon.play();
}

Pensez à bien regarder si le format est supporté par tel ou tel navigateur et le type MIME :
http://www.w3schools.com/html/html5_audio.asp

**hackoofr** · 31/05/2013, 15h41

J'ai trouvé un vbscript Alarme.vbs dans le net qui fait une simulation d'alarme.
je l'ai modifié un peu et j'ai ajouté la balise <bgsound> à la ligne N° 66
vous pouvez par exemple télécharger Alarme.mp3 ici : http://soundjax.com/alarm-1.html et par la suite modifier la source ou se trouve le Alarm.mp3

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Titre = "Alarme"
Set ws = CreateObject("wscript.Shell")
alarmDansMin  = Trim ( InputBox( "Dans combien de minutes voulez-vous déclenchez l'alarme ?",Titre, "4") )
If alarmDansMin = ""  Then Wscript.Quit
If Not IsNumeric(alarmDansMin) or alarmDansMin <= 1 Then
    ws.Popup "Il faut Taper un Nombre strictement supérieur à 1 !","2",Titre,0+16 'Afficher un Popup durant 2 secondes puis quitte le script 
    Wscript.Quit
End if 
sMessage = "Reste " & alarmDansMin/2 & " minutes !"
alarmDansmmsec = alarmDansMin*60*1000 'en millisecondes
alaramSecondes = alarmDansMin*60 'en secondes
nMinutes = alarmDansMin/2
WScript.sleep  alarmDansmmsec/2
nSeconds = 0
sMessage = "<font color=red size=4><b>ALARME</b></font>"
' Open a chromeless window with message
with HTABox("lightBlue", 175, 450, 400,100)
    .document.title = "Notification"
    .msg.innerHTML = sMessage
    do until .done.value or (nMinutes + nSeconds < 1)
        .msg.innerHTML = sMessage & "<br>" & nMinutes & ":" & Right("0"&nSeconds, 2) _
        & " restantes <br>"
        wsh.sleep 1000 ' milliseconds
        nSeconds = nSeconds - 1
        if nSeconds < 0 then 
            if nMinutes > 0 then
                nMinutes = nMinutes - 1
                nSeconds = 59
            end if
        end if
    loop
    .done.value = true
    .close
end with
ws.Popup "C'est FINI !","5",Titre,0+64 'Afficher un Popup durant 5 secondes puis quitte le script
'wscript.echo "process goes here ..."
' script ends here
Function HTABox(sBgColor, h, w, l, t)
    Dim IE, HTA, sCmd, nRnd
    randomize : nRnd = Int(1000000 * rnd)
    sCmd = "mshta.exe ""javascript:{new " _
    & "ActiveXObject(""InternetExplorer.Application"")" _
    & ".PutProperty('" & nRnd & "',window);" _
    & "window.resizeTo(" & w & "," & h & ");" _
    & "window.moveTo(" & l & "," & t & ")}"""
    Set WshShell = WScript.CreateObject("WScript.Shell")
    with CreateObject("WScript.Shell")
        .Run sCmd, 1, False
        do until .AppActivate("javascript:{new ") : WSH.sleep 10 : loop
        end with  'WSHShell
        For Each IE In CreateObject("Shell.Application").windows
            If IsObject(IE.GetProperty(nRnd)) Then
                set HTABox = IE.GetProperty(nRnd)
                IE.Quit
                HTABox.document.title = "HTABox"
                HTABox.document.write _
                "<HTA:Application contextMenu=no border=thin " _
                & "minimizebutton=no maximizebutton=no sysmenu=no />" _
                & "<body scroll=no style='background-color:" _
                & sBgColor & ";font:normal 10pt Arial;" _
                & "border-Style:inset;border-Width:3px'" _
                & "onbeforeunload='vbscript:if not done.value then " _
                & "window.event.cancelBubble=true:" _
                & "window.event.returnValue=false:" _
                & "done.value=true:end if'>" _
                & "<bgsound src=""e:\music\ALARM.mp3"" loop=""infinite"">"_
                & "<input type=hidden id=done value=false>" _
                & "<center><span id=msg>&nbsp;</span><br>" _
                & "<input type=button id=btn1 value=' Arrêter ' "_
                & "onclick=done.value=true><center></body>"
                HTABox.btn1.focus
                Exit Function
            End If
        Next
        MsgBox "HTA window not found."
        wsh.quit
End Function

**Bovino** · 31/05/2013, 16h04

Si c'est du local sur ton PC, je ne vois pas l'utilité de faire des pages Web...
Comme le propose hackoofr, un HTA est plus adapté, faute de mieux...

Déclenchement son sur événement

JavaScript

Vue hybride

Discussions similaires

Partager

Partager